code.vuplus.com Git - vuplus_openembedded/blob - recipes/guile/guile.inc

   1 DESCRIPTION = "Guile is an interpreter for the Scheme programming language, \
   2 packaged as a library which can be incorporated into your programs."
   3 HOMEPAGE = "http://www.gnu.org/software/guile/guile.html"
   4 SECTION = "devel/scheme"
   5 DEPENDS = "guile-native gmp libtool"
   6 LICENSE = "GPL"
   7 PACKAGES =+ "${PN}-el"
   8 FILES_${PN}-el = "${datadir}/emacs"
   9 DESCRIPTION_${PN}-el = "Emacs lisp files for Guile"
  10
  11 inherit autotools
  12
  13 acpaths = "-I ${S}/guile-config"
  14
  15 EXTRA_OECONF = " \
  16                 --without-threads \
  17                 --without-included-ltdl \
  18                "
  19
  20 do_compile() {
  21         for i in $(find ${S} -name "Makefile") ; do
  22                 sed -i -e s:-Werror::g $i
  23         done
  24
  25         (cd libguile; oe_runmake CC="${BUILD_CC}" CFLAGS="${BUILD_CFLAGS}" LDFLAGS="${BUILD_LDFLAGS}" guile_filter_doc_snarfage)
  26         oe_runmake preinstguile="`which guile`"
  27
  28         sed -i -e s:${STAGING_DIR_TARGET}::g \
  29                -e s:/${TARGET_SYS}::g \
  30                -e s:-L/usr/lib::g \
  31                -e s:-isystem/usr/include::g \
  32                -e s:,/usr/lib:,\$\{libdir\}:g \
  33                   guile-1.8.pc
  34 }
  35
  36 do_stage() {
  37         autotools_stage_all
  38         # Create guile-config returning target values instead of native values
  39         install -d ${STAGING_BINDIR_CROSS}
  40         echo '#!'`which guile`$' \\\n-e main -s\n!#\n(define %guile-build-info '\'\( >guile-config.cross
  41         sed -n $'s:-isystem[^ ]* ::;s:-Wl,-rpath-link,[^ ]* ::;s:^[ \t]*{[ \t]*":  (:;s:",[ \t]*": . ":;s:" *}, *\\\\:"):;/^  (/p' <libguile/libpath.h >>guile-config.cross
  42         echo '))' >>guile-config.cross
  43         cat guile-config/guile-config >>guile-config.cross
  44         install guile-config.cross ${STAGING_BINDIR_CROSS}/guile-config
  45 }