code.vuplus.com Git - vuplus_openembedded/blob - recipes/xscreensaver/xscreensaver.inc

   1 # xscreensaver OE build file
   2 # Copyright (C) 2004, Advanced Micro Devices, Inc.  All Rights Reserved
   3 # Released under the MIT license (see packages/COPYING)
   4
   5 DESCRIPTION = "*The* screensaver package for X11"
   6 HOMEPAGE = "http://www.jwz.org/xscreensaver/"
   7 SECTION = "x11-misc"
   8 LICENSE = "BSD"
   9 DEPENDS = "intltool virtual/libgl freeglut virtual/libx11 gtk+ libxml2 libglade"
  10
  11 # xscreensaver-demo is a glade app
  12 LDFLAGS_append = " -Wl,--export-dynamic"
  13 TARGET_CC_ARCH += "${LDFLAGS}"
  14
  15 INC_PR = "r4"
  16
  17 inherit autotools
  18
  19 export INTLTOOL_PERL="/usr/bin/env perl"
  20
  21 EXTRA_OECONF=" --with-xml \
  22                --with-gtk \
  23                --disable-locking \
  24                --without-pixbuf \
  25                --with-jpeg \
  26                --with-xpm \
  27                --with-randr-ext \
  28                --with-gl \
  29                --without-gle \
  30                --with-xshm-ext \
  31                --with-setuid-hacks \
  32 "
  33
  34 PACKAGES =+  " xscreensaver-demo xscreensaver-extra"
  35
  36 FILES_${PN}= "${bindir}/xscreensaver ${bindir}/xscreensaver-text ${bindir}/xscreensaver-command ${datadir}/applications \
  37         ${libdir}/X11/"
  38
  39 FILES_${PN}-dbg += "${libexecdir}/xscreensaver/.debug"
  40
  41 FILES_xscreensaver-demo="${bindir}/xscreensaver-demo ${datadir}/xscreensaver \
  42         ${datadir}/pixmaps/"
  43
  44 FILES_xscreensaver-extra="${bindir}/xscreensaver-getimage*"
  45
  46 do_configure_prepend() {
  47         sed -i 's:GTK_DATADIR="$GTK_DATADIR/share":GTK_DATADIR="${datadir}":' ${S}/configure.in
  48
  49         export includedir="/lib"
  50         sed -i -e s:AC_PROG_CC:AC_PROG_CXX:g configure.in
  51         echo AC_PROG_CXX >> configure.in
  52         export CC="${CXX}"
  53 }
  54
  55 do_compile() {
  56         oe_runmake CC="${CC}" LD="${CXX}" CC_HACK="${CXX}" GNOME_DATADIR=${datadir} all
  57 }
  58
  59 fakeroot do_install() {
  60         unset KDEDIR
  61         oe_runmake -C ${S}/driver GNOME_DATADIR=${datadir} \
  62         install_prefix=${D} install
  63
  64         oe_runmake -C ${S}/hacks install_prefix=${D} install-program
  65
  66         # Install the defaults file
  67         install -d ${D}/${libdir}/X11/app-defaults
  68         install -m 0644 ${WORKDIR}/XScreenSaver ${D}/${libdir}/X11/app-defaults
  69 }
  70
  71 PACKAGES_DYNAMIC = "xscreensaver-hack-*"
  72
  73 python populate_packages_prepend () {
  74         hackdir = bb.data.expand('${libexecdir}/xscreensaver', d)
  75         do_split_packages(d, hackdir, '^(.*)', 'xscreensaver-hack-%s', 'XScreensaver hack %s')
  76         metapkg = "xscreensaver-hacks"
  77         bb.data.setVar('ALLOW_EMPTY_' + metapkg, "1", d)
  78         bb.data.setVar('FILES_' + metapkg, "", d)
  79         blacklist = [ 'xscreensaver-locale', 'xscreensaver-dev', 'xscreensaver-dbg', 'xscreensaver-doc', 'xscreensaver-extra' ]
  80         metapkg_rdepends = []
  81         packages = bb.data.getVar('PACKAGES', d, 1).split()
  82         for pkg in packages[1:]:
  83                 if not pkg in blacklist and not pkg in metapkg_rdepends:
  84                         metapkg_rdepends.append(pkg)
  85         bb.data.setVar('RDEPENDS_' + metapkg, ' '.join(metapkg_rdepends), d)
  86         bb.data.setVar('DESCRIPTION_' + metapkg, 'Xscreensaver hacks meta package', d)
  87         packages.append(metapkg)
  88         bb.data.setVar('PACKAGES', ' '.join(packages), d)
  89 }
  90