code.vuplus.com Git - vuplus_openembedded/blob - recipes/xqt2/xqt2_20060509.bb

   1 DESCRIPTION = "Xqt2 is an X-Server than runs within the Opie environment"
   2 HOMEPAGE = "http://xqt.sourceforge.jp"
   3 DEPENDS = "freetype libxi xmu flex-native virtual/libqte2 libqpe-opie"
   4 LICENSE = "GPL"
   5 SECTION = "opie/applications"
   6 APPTYPE = "binary"
   7 APPNAME = "Xqt"
   8 PR = "r4"
   9
  10 inherit palmtop
  11
  12 SRC_URI = "cvs://anonymous@cvs.sourceforge.jp/cvsroot/xqt;module=xqt2;method=pserver;date=${PV} \
  13         ftp://ftp.xfree86.org/pub/XFree86/4.3.0/source/X430src-1.tgz \
  14         ftp://ftp.xfree86.org/pub/XFree86/4.3.0/source/X430src-2.tgz \
  15         ftp://ftp.xfree86.org/pub/XFree86/4.3.0/source/X430src-3.tgz \
  16         ftp://ftp.xfree86.org/pub/XFree86/4.3.0/source/X430src-4.tgz \
  17         ftp://ftp.xfree86.org/pub/XFree86/4.3.0/source/X430src-5.tgz \
  18         file://KeyMap.patch;patch=1 \
  19         file://moc_call.patch;patch=1 \
  20         file://imake-staging.patch;patch=1 \
  21         file://cross.patch;patch=1 \
  22         file://fephack.patch;patch=1 \
  23         file://xchar2b.patch;patch=1 \
  24         file://xqt-make.patch;patch=1 \
  25         file://fix_qtscreen_HACK.patch;patch=1 \
  26         file://fix_seqfault_qtscreen.patch;patch=1 "
  27 S = "${WORKDIR}/xc"
  28
  29 QT_LIBRARY = '${@base_conditional("PALMTOP_USE_MULTITHREADED_QT", "yes", "qte-mt", "qte",d)}'
  30 QT_LIBRARY_append_c7x0 = " -laticore"
  31
  32 do_configure() {
  33         #general config
  34         echo "#define BuildServersOnly YES" > config/cf/host.def
  35         echo "#define ProjectRoot /usr" >> config/cf/host.def
  36
  37         # do not build these XServers
  38         echo "#define XnestServer NO"  >> config/cf/host.def
  39         echo "#define XdmxServer NO"  >> config/cf/host.def
  40
  41         # build commands
  42         echo "#define CcCmd ${CC}" >> config/cf/host.def
  43         echo "#define CplusplusCmd ${CXX}" >> config/cf/host.def
  44         echo "#define LdCmd ${LD}" >> config/cf/host.def
  45
  46         # Qt defines
  47         echo "#define QtCmnDefs -fno-exceptions -fno-rtti" >> config/cf/host.def
  48         echo "#define QtDir ${QTDIR}" >> config/cf/host.def
  49         echo "#define QtLibs -lqpe -l${QT_LIBRARY} -lm -lpng -ljpeg -lts -lsupc++" >> config/cf/host.def
  50         echo "#define MocBin ${STAGING_BINDIR_NATIVE}/moc" >> config/cf/host.def
  51         echo "#define QtDefs -DQWS -DOPIE_NEW_MALLOC -DOPIE_NO_ERASE_RECT_HACKFIX  QtCmnDefs" >> config/cf/host.def
  52
  53         # Build these XServers
  54         echo "#define XqtXServer  YES" >> config/cf/host.def
  55         echo "#define XF86Server  NO"  >> config/cf/host.def
  56         echo "#define TinyXServer YES" >> config/cf/host.def
  57         echo "#define KDriveXServer YES" >> config/cf/host.def
  58         echo "#define KdriveServerExtraDefines -DDDXOSFATALERROR -DDDXOSVERRORF" >> config/cf/host.def
  59
  60         # General Config
  61         echo "#define SystemUsrIncDir ${STAGING_INCDIR}" >> config/cf/host.def
  62         echo "#define IncRoot ${STAGING_INCDIR}" >> config/cf/host.def
  63         echo "#define LdPostLib -L${STAGING_LIBDIR}" >> config/cf/host.def
  64
  65         echo "#undef BuildRandR " >> config/cf/host.def
  66         echo "#define BuildRandR YES" >> config/cf/host.def
  67         echo "#define BuildLBX YES" >> config/cf/host.def
  68
  69         # change standard defines
  70         if [ ${TARGET_ARCH} == "arm" ]; then
  71                 echo "#define StandardDefines -Dlinux -D__arm__ -D_POSIX_SOURCE -D_BSD_SOURCE -D_GNU_SOURCE" >> config/cf/host.def
  72                 echo "#define Arm32Architecture" >> config/cf/host.def
  73         fi
  74         echo "" > config/cf/date.def
  75 }
  76
  77 do_compile() {
  78     export TOPDIR=${TOPDIR}
  79     mkdir -p programs/Xserver/hw/xqt
  80     #cp -R ../xqt-driver/* programs/Xserver/hw/xqt
  81     (cd programs/Xserver/hw/xqt && ln -s ../../../../../xqt2/xfree86/xqt-driver/* .)
  82         unset CC
  83         make -C config/imake -f Makefile.ini CC="${BUILD_CC}" BOOTSTRAPCFLAGS="${BUILD_CFLAGS}" clean imake
  84         make CC="${BUILD_CC}" xmakefile
  85         make Makefiles
  86         make clean
  87         #make depend
  88         make includes CC="${BUILD_CC}"
  89         make -C config/util CC="${BUILD_CC}"
  90         for l in font xtrans Xdmcp Xau lbxutil; do make -C lib/$l CC="${CC}" LD="${LD}" CC_STAGING="-I${STAGING_INCDIR}" LD_STAGING="-L${STAGING_LIBDIR}"; done
  91         make -C programs/Xserver CC="${CC}" LD="${LD}" CC_STAGING="-I${STAGING_INCDIR}" LD_STAGING="-L${STAGING_LIBDIR}" INSTALLED_LIBS=""
  92 }
  93
  94 do_stage() {
  95         install -d ${STAGING_INCDIR}/xserver-xqt
  96         install -m 0644 programs/Xserver/hw/xfree86/common/fourcc.h ${STAGING_INCDIR}/xserver-xqt
  97 }
  98
  99 do_install() {
 100         oe_runmake -C programs/Xserver DESTDIR="${D}" CC="${CC}" LD="${LD}" \
 101                    CC_STAGING="-I${STAGING_INCDIR}" LD_STAGING="-L${STAGING_LIBDIR}" INSTALLED_LIBS="" install
 102         oe_runmake -C lib/font DESTDIR="${D}" CC="${CC}" LD="${LD}" \
 103                    CC_STAGING="-I${STAGING_INCDIR}" LD_STAGING="-L${STAGING_LIBDIR}" INSTALLED_LIBS="" install
 104
 105         install -d ${D}${palmtopdir}/apps/Applications/
 106         install -m 0644 ${WORKDIR}/xqt2/xfree86/files/Xqt.desktop ${D}${palmtopdir}/apps/Applications
 107         install -d ${D}${palmtopdir}/pics
 108         install -m 0644 programs/Xserver/hw/xqt/Xqt.png ${D}${palmtopdir}/pics
 109 }
 110
 111 PACKAGE_ARCH_c7x0 = "${MACHINE_ARCH}"