code.vuplus.com Git - vuplus_openembedded/blob - recipes/xorg-driver/xorg-driver-common.inc

   1 DESCRIPTION = "X driver"
   2 HOMEPAGE = "http://www.x.org"
   3 SECTION = "x11/drivers"
   4 LICENSE = "MIT-X"
   5 PR = "r9"
   6
   7 DEPENDS = "randrproto xorg-server xproto"
   8
   9 XORG_PN = "${PN}"
  10 SRC_URI = "${XORG_MIRROR}/individual/driver/${XORG_PN}-${PV}.tar.bz2"
  11
  12 S = "${WORKDIR}/${XORG_PN}-${PV}"
  13
  14 FILES_${PN} += " ${libdir}/xorg/modules"
  15 FILES_${PN}-dbg +=  "${libdir}/xorg/modules/*/.debug"
  16
  17 inherit autotools pkgconfig
  18
  19 TARGET_CPPFLAGS += "-I${STAGING_DIR_HOST}/usr/include/xorg"
  20
  21
  22 do_stage() {
  23         autotools_stage_all
  24 }
  25
  26 # Another sucky behavor from Xorg configure scripts.
  27 # They use AC_CHECK_FILE to check for DRI headers. Yuck!
  28 # Of course this will blow up when cross compiling.
  29
  30 do_configure_prepend() {
  31         incdir=${layout_includedir}/xorg
  32         for f in dri.h sarea.h dristruct.h exa.h damage.h xf86Module.h; do
  33                 path="$incdir/$f"
  34                 if [ -f "${STAGING_DIR_HOST}/$path" ]; then
  35                         p=`echo "$path" | sed 'y%*+%pp%;s%[^_[:alnum:]]%_%g'`
  36                         eval "export ac_cv_file_$p=yes"
  37                 fi
  38         done
  39 }
  40
  41 # FIXME: We don't want to include the libtool archives (*.la) from modules
  42 # directory, as they serve no useful purpose. Upstream should fix Makefile.am
  43 do_install_append() {
  44         find ${D}${libdir}/xorg/modules -regex ".*\.la$" | xargs rm -f --
  45 }
  46