code.vuplus.com Git - vuplus_openembedded/blob - recipes/u-boot/u-boot-openmoko.inc

   1 DESCRIPTION = "U-boot bootloader w/ Neo1973 (GTA01) and Neo FreeRunner (GTA02) support"
   2 AUTHOR = "Harald Welte <laforge@openmoko.org> et. al."
   3 LICENSE = "GPL"
   4 SECTION = "bootloader"
   5 PRIORITY = "optional"
   6 PROVIDES = "virtual/bootloader"
   7 LOCALVERSION = "+gitr${SRCREV}"
   8 PV = "1.3.1${LOCALVERSION}"
   9 PR = "r1"
  10
  11 UBOOT_MACHINES = "gta01bv2 gta01bv3 gta01bv4 gta02v2 gta02v4 gta02v5"
  12
  13 EXTRA_OEMAKE = "CROSS_COMPILE=${TARGET_PREFIX}"
  14 TARGET_LDFLAGS = ""
  15
  16 do_svnrev() {
  17         mv -f tools/setlocalversion tools/setlocalversion.old
  18         echo "echo ${LOCALVERSION}" >>tools/setlocalversion
  19 }
  20
  21 do_compile () {
  22         chmod +x board/neo1973/gta*/split_by_variant.sh
  23         for mach in ${UBOOT_MACHINES}
  24         do
  25                 oe_runmake ${mach}_config
  26                 oe_runmake clean
  27                 find board -name lowlevel_foo.bin -exec rm '{}' \;
  28                 oe_runmake all
  29                 oe_runmake u-boot.udfu
  30                 if [ -f u-boot.udfu ]; then
  31                         mv u-boot.udfu u-boot_${mach}.bin
  32                 else
  33                         mv u-boot.bin u-boot_${mach}.bin
  34                 fi
  35                 if [ -f board/${mach}/lowlevel_foo.bin ]; then
  36                         mv board/${mach}/lowlevel_foo.bin lowlevel_foo_${mach}.bin
  37                 else
  38                         find board -name lowlevel_foo.bin -exec mv '{}' lowlevel_foo_${mach}.bin \;
  39                 fi
  40         done
  41 }
  42
  43 do_deploy () {
  44         install -d ${DEPLOY_DIR_IMAGE}
  45         for mach in ${UBOOT_MACHINES}
  46         do
  47                 install -m 0644 ${S}/u-boot_${mach}.bin ${DEPLOY_DIR_IMAGE}/u-boot-${mach}-${PV}-${PR}.bin
  48                 ln -sf ${DEPLOY_DIR_IMAGE}/u-boot-${mach}-${PV}-${PR}.bin ${DEPLOY_DIR_IMAGE}/uboot-${mach}-latest.bin
  49                 if [ -f ${S}/lowlevel_foo_${mach}.bin ]; then
  50                         install -m 0644 ${S}/lowlevel_foo_${mach}.bin ${DEPLOY_DIR_IMAGE}/lowlevel_foo-${mach}-${PV}-${PR}.bin
  51                         ln -sf ${DEPLOY_DIR_IMAGE}/lowlevel_foo-${mach}-${PV}-${PR}.bin ${DEPLOY_DIR_IMAGE}/lowlevel-foo-${mach}-latest.bin
  52                 fi
  53         done
  54         install -m 0755 tools/mkimage ${STAGING_BINDIR_NATIVE}/uboot-mkimage
  55 }
  56
  57 do_deploy[dirs] = "${S}"
  58 addtask deploy before do_package after do_install
  59 addtask quilt before do_patch after do_unpack
  60 addtask svnrev before do_patch after do_quilt