code.vuplus.com Git - vuplus_openembedded/blob - recipes/sysvinit/sysvinit_2.86.bb

   1 DESCRIPTION = "System-V like init."
   2 SECTION = "base"
   3 LICENSE = "GPL"
   4 HOMEPAGE = "http://freshmeat.net/projects/sysvinit/"
   5 PR = "r58"
   6
   7 # USE_VT and SERIAL_CONSOLE are generally defined by the MACHINE .conf.
   8 # Set PACKAGE_ARCH appropriately.
   9 PACKAGE_ARCH_${PN}-inittab = "${MACHINE_ARCH}"
  10
  11 RDEPENDS_${PN} = "${PN}-inittab"
  12
  13 PACKAGES =+ "bootlogd ${PN}-inittab"
  14 FILES_bootlogd = "/etc/init.d/bootlogd /etc/init.d/stop-bootlogd /etc/rc?.d/S*bootlogd /sbin/bootlogd"
  15 FILES_${PN}-inittab = "${sysconfdir}/inittab"
  16 CONFFILES_${PN}-inittab = "${sysconfdir}/inittab"
  17
  18 USE_VT ?= "1"
  19 SYSVINIT_ENABLED_GETTYS ?= "1"
  20
  21 SRC_URI = "ftp://ftp.cistron.nl/pub/people/miquels/sysvinit/sysvinit-${PV}.tar.gz \
  22            file://install.patch;patch=1 \
  23            file://need \
  24            file://provide \
  25            file://inittab \
  26            file://rcS-default \
  27            file://rc \
  28            file://rcS \
  29            file://bootlogd.init"
  30
  31 S = "${WORKDIR}/sysvinit-${PV}"
  32 B = "${S}/src"
  33
  34 inherit update-alternatives
  35
  36 ALTERNATIVE_NAME = "init"
  37 ALTERNATIVE_LINK = "${base_sbindir}/init"
  38 ALTERNATIVE_PATH = "${base_sbindir}/init.sysvinit"
  39 ALTERNATIVE_PRIORITY = "60"
  40
  41 PACKAGES =+ "sysvinit-utils sysvinit-pidof sysvinit-sulogin"
  42 FILES_${PN} += "${base_sbindir}/* ${base_bindir}/*"
  43 FILES_sysvinit-pidof = "${base_bindir}/pidof.sysvinit"
  44 FILES_sysvinit-sulogin = "${base_sbindir}/sulogin"
  45 FILES_sysvinit-utils = "${bindir}/last.${PN} ${bindir}/mesg.${PN} ${bindir}/wall.${PN} ${base_sbindir}/shutdown.${PN} ${bindir}/lastb ${bindir}/utmpdump ${base_sbindir}/runlevel"
  46 RRECOMMENDS_${PN} = "sysvinit-utils"
  47 RRECOMMENDS_${PN}_micro = ""
  48
  49 CFLAGS_prepend = "-D_GNU_SOURCE "
  50 export LCRYPT = "-lcrypt"
  51 EXTRA_OEMAKE += "'INSTALL=install' \
  52                  'bindir=${base_bindir}' \
  53                  'sbindir=${base_sbindir}' \
  54                  'usrbindir=${bindir}' \
  55                  'usrsbindir=${sbindir}' \
  56                  'includedir=${includedir}' \
  57                  'mandir=${mandir}' \
  58                  DISTRO=''"
  59
  60 do_install () {
  61         oe_runmake 'ROOT=${D}' install
  62         install -d ${D}${sysconfdir}
  63         install -d ${D}${sysconfdir}/default
  64         install -d ${D}${sysconfdir}/init.d
  65         install -m 0644 ${WORKDIR}/inittab ${D}${sysconfdir}/inittab
  66         if [ ! -z "${SERIAL_CONSOLE}" ]; then
  67                 echo "S:2345:respawn:${base_sbindir}/getty ${SERIAL_CONSOLE}" >> ${D}${sysconfdir}/inittab
  68         fi
  69         if [ "${USE_VT}" = "1" ]; then
  70                 cat <<EOF >>${D}${sysconfdir}/inittab
  71 # ${base_sbindir}/getty invocations for the runlevels.
  72 #
  73 # The "id" field MUST be the same as the last
  74 # characters of the device (after "tty").
  75 #
  76 # Format:
  77 #  <id>:<runlevels>:<action>:<process>
  78 #
  79
  80 EOF
  81
  82                 for n in ${SYSVINIT_ENABLED_GETTYS}
  83                 do
  84                         echo "$n:2345:respawn:${base_sbindir}/getty 38400 tty$n" >> ${D}${sysconfdir}/inittab
  85                 done
  86                 echo "" >> ${D}${sysconfdir}/inittab
  87         fi
  88         install -m 0644    ${WORKDIR}/rcS-default       ${D}${sysconfdir}/default/rcS
  89         install -m 0755    ${WORKDIR}/rc                ${D}${sysconfdir}/init.d
  90         install -m 0755    ${WORKDIR}/rcS               ${D}${sysconfdir}/init.d
  91         install -m 0755    ${WORKDIR}/bootlogd.init     ${D}${sysconfdir}/init.d/bootlogd
  92         ln -sf bootlogd ${D}${sysconfdir}/init.d/stop-bootlogd
  93         install -d ${D}${sysconfdir}/rcS.d
  94         ln -sf ../init.d/bootlogd ${D}${sysconfdir}/rcS.d/S07bootlogd
  95         for level in 2 3 4 5; do
  96                 install -d ${D}${sysconfdir}/rc$level.d
  97                 ln -sf ../init.d/stop-bootlogd ${D}${sysconfdir}/rc$level.d/S99stop-bootlogd
  98         done
  99         mv                 ${D}${base_sbindir}/init               ${D}${base_sbindir}/init.${PN}
 100         mv ${D}${base_bindir}/pidof ${D}${base_bindir}/pidof.${PN}
 101         mv ${D}${base_sbindir}/halt ${D}${base_sbindir}/halt.${PN}
 102         mv ${D}${base_sbindir}/reboot ${D}${base_sbindir}/reboot.${PN}
 103         mv ${D}${base_sbindir}/shutdown ${D}${base_sbindir}/shutdown.${PN}
 104         mv ${D}${base_sbindir}/poweroff ${D}${base_sbindir}/poweroff.${PN}
 105         mv ${D}${bindir}/last ${D}${bindir}/last.${PN}
 106         mv ${D}${bindir}/mesg ${D}${bindir}/mesg.${PN}
 107         mv ${D}${bindir}/wall ${D}${bindir}/wall.${PN}
 108 }
 109
 110 do_install_append_opendreambox () {
 111         cat <<EOF >>${D}/etc/inittab
 112 # enigma
 113 gui:2:respawn:/usr/bin/enigma.sh
 114 # enigma2
 115 e2:3:respawn:/usr/bin/enigma2.sh
 116 EOF
 117 }
 118
 119 do_install_append_vuplus () {
 120         cat <<EOF >>${D}/etc/inittab
 121 # enigma
 122 gui:2:respawn:/usr/bin/enigma.sh
 123 # enigma2
 124 e2:3:respawn:/usr/bin/enigma2.sh
 125 EOF
 126 }
 127
 128 pkg_postinst_${PN} () {
 129 #!/bin/sh
 130 update-alternatives --install ${base_sbindir}/halt halt halt.${PN} 200
 131 update-alternatives --install ${base_sbindir}/reboot reboot reboot.${PN} 200
 132 update-alternatives --install ${base_sbindir}/poweroff poweroff poweroff.${PN} 200
 133 }
 134
 135 pkg_postinst_sysvinit-utils () {
 136 #!/bin/sh
 137 update-alternatives --install ${bindir}/last last last.${PN} 200
 138 update-alternatives --install ${bindir}/mesg mesg mesg.${PN} 200
 139 update-alternatives --install ${bindir}/wall wall wall.${PN} 200
 140 update-alternatives --install ${base_sbindir}/shutdown shutdown shutdown.${PN} 200
 141 }
 142
 143 pkg_prerm_${PN} () {
 144 #!/bin/sh
 145 update-alternatives --remove halt halt.${PN}
 146 update-alternatives --remove reboot reboot.${PN}
 147 }
 148
 149 pkg_prerm_sysvinit-utils () {
 150 #!/bin/sh
 151 update-alternatives --remove last last.${PN}
 152 update-alternatives --remove mesg mesg.${PN}
 153 update-alternatives --remove wall wall.${PN}
 154 update-alternatives --remove shutdown shutdown.${PN}
 155 }
 156
 157 pkg_postinst_sysvinit-pidof () {
 158 #!/bin/sh
 159 update-alternatives --install ${base_bindir}/pidof pidof pidof.${PN} 200
 160 }
 161
 162 pkg_prerm_sysvinit-pidof () {
 163 #!/bin/sh
 164 update-alternatives --remove pidof pidof.${PN}
 165 }