code.vuplus.com Git - vuplus_openembedded/blob - recipes/owfs/owfs_2.7p28.bb

   1 DESCRIPTION = "1-Wire file system"
   2 HOMEPAGE = "http://www.owfs.org/"
   3 SECTION = "console/network"
   4 PRIORITY = "optional"
   5 LICENSE = "GPLv2"
   6 DEPENDS += "fuse virtual/libusb0"
   7
   8 PR = "r0"
   9
  10 SRC_URI = "${SOURCEFORGE_MIRROR}/owfs/owfs-${PV}.tar.gz \
  11            file://owhttpd \
  12            file://owserver "
  13
  14 inherit autotools update-rc.d
  15
  16 EXTRA_OECONF = " \
  17                  --enable-owhttpd \
  18                  --enable-cache \
  19                  --enable-mt \
  20                  --disable-swig \
  21                  "
  22
  23 do_install_prepend() {
  24         install -d ${D}${sysconfdir}/default/
  25         install -d ${D}${sysconfdir}/init.d/
  26         install -m 0755 ${WORKDIR}/owhttpd ${D}${sysconfdir}/init.d/owhttpd
  27         install -m 0755 ${WORKDIR}/owserver ${D}${sysconfdir}/init.d/owserver
  28 }
  29 do_stage() {
  30         autotools_stage_all
  31 }
  32
  33 PACKAGES =+ "owftpd owhttpd owserver owshell libowcapi libow libownet owmon owtap"
  34
  35 DESCRIPTION_owftpd = "Anoymous FTP server for 1-wire access"
  36 DESCRIPTION_owhttpd = "Tiny webserver for 1-wire control"
  37 DESCRIPTION_owserver = "Backend server (daemon) for 1-wire control"
  38 DESCRIPTION_owshell = "owdir owread owwrite owpresent owget - lightweight owserver access"
  39 DESCRIPTION_libowcapi = "easy C-language 1-wire interface "
  40 DESCRIPTION_libow = "easy C-language 1-wire interface to the owserver protocol"
  41 DESCRIPTION_libownet = "easy C-language 1-wire interface to the owserver protocol"
  42 DESCRIPTION_owmon = "Monitor for owserver settings and statistics"
  43 DESCRIPTION_owtap = "Packet sniffer for the owserver protocol"
  44
  45 FILES_owftpd = "${bindir}/owftpd"
  46 FILES_owhttpd = "${bindir}/owhttpd ${sysconfdir}/init.d/owhttpd"
  47 FILES_owserver = "${bindir}/owserver ${sysconfdir}/init.d/owserver"
  48 FILES_owshell = "${bindir}/owread ${bindir}/owwrite \
  49                  ${bindir}/owdir ${bindir}/owpresent \
  50                  ${bindir}/owget ${bindir}/owside"
  51 FILES_owmon = "${bindir}/owmon"
  52 FILES_owtap = "${bindir}/owtap"
  53 FILES_libowcapi = "${libdir}/libowcapi-*"
  54 FILES_libow = "${libdir}/libow-*"
  55 FILES_libownet = "${libdir}/libownet-*"
  56
  57 INITSCRIPT_PACKAGES = "owhttpd owserver"
  58 INITSCRIPT_NAME_owserver = "owserver"
  59 INITSCRIPT_NAME_owhttpd = "owhttpd"
  60 INITSCRIPT_PARAMS_owserver = "defaults 20"
  61 INITSCRIPT_PARAMS_owhttpd = "defaults 21"