code.vuplus.com Git - vuplus_openembedded/blob - recipes/opie-reader/opie-reader.inc

   1 DESCRIPTION = "E-Book reader"
   2 SECTION = "opie/applications"
   3 PRIORITY = "optional"
   4 LICENSE = "GPL"
   5 APPNAME = "opie-reader"
   6 APPTYPE = "binary"
   7 DEPENDS = "flite"
   8 RRECOMMENDS_PN = "opie-reader-filter-htmlfilter, opie-reader-codec-weasel, opie-reader-codec-reb, \
   9   opie-reader-codec-isilo, opie-reader-codec-aportis, opie-reader-codec-ppms, opie-reader-codec-chm, \
  10   opie-reader-codec-plucker, opie-reader-codec-arrierego"
  11 RSUGGESTS_PN = "opie-reader-output-flitedyn16, opie-reader-output-flitecmd, opie-reader-output-flitedyn"
  12 INC_PR = "r3"
  13
  14 SRC_URI = "${HANDHELDS_CVS};tag=${TAG};module=opie/noncore/apps/opie-reader \
  15            ${HANDHELDS_CVS};tag=${TAG};module=opie/pics \
  16            ${HANDHELDS_CVS};tag=${TAG};module=opie/apps"
  17 S = "${WORKDIR}/opie-reader"
  18
  19 EXTRA_QMAKEVARS_POST += "LIBS+=-L${S}"
  20 PARALLEL_MAKE = ""
  21
  22 inherit opie
  23
  24 EXTRA_QMAKEVARS_POST += " SUBDIRS+=FliteDyn SUBDIRS+=FliteDyn16 INCLUDEPATH+=${STAGING_INCDIR}/flite"
  25
  26 do_install() {
  27                 install -d ${D}${palmtopdir}/pics/${APPNAME}/
  28                 install -d ${D}${palmtopdir}/lib/
  29                 install -d ${D}${palmtopdir}/plugins/reader/data/
  30                 install -d ${D}${palmtopdir}/plugins/reader/filters/
  31                 install -d ${D}${palmtopdir}/plugins/reader/support/
  32                 install -d ${D}${palmtopdir}/plugins/reader/outcodecs/
  33                 install -d ${D}${palmtopdir}/plugins/reader/codecs/
  34                 install -m 0644 ${WORKDIR}/pics/${APPNAME}/*.png ${D}${palmtopdir}/pics/${APPNAME}/
  35
  36                 for f in libAportis libCHM libPlucker libReb libWeasel libiSilo libppms libArriereGo
  37                 do
  38                         install -m 644 ${S}/$f.so ${D}${palmtopdir}/plugins/reader/codecs/
  39                 done
  40
  41                 for f in libreader_codec libreader_pdb libreader_pluckerbase pluckerdecompress
  42                 do
  43                         oe_libinstall -so -C ${S}/ $f ${D}${palmtopdir}/lib/
  44                 done
  45
  46                 install -m 644 ${S}/libHTMLfilter.so ${D}${palmtopdir}/plugins/reader/filters/
  47                 install -m 644 ${S}/libpluckerdecompress.so ${D}${palmtopdir}/plugins/reader/support/
  48
  49                 for f in libflitecmd libflitedyn libflitedyn16
  50                 do
  51                    install -m 644 ${S}/$f.so ${D}${palmtopdir}/plugins/reader/outcodecs
  52                 done
  53
  54                 install -m 0644 ${S}/HTMLentities ${D}${palmtopdir}/plugins/reader/data/
  55 }
  56
  57 python populate_packages_prepend () {
  58         print "opie-reader:", bb.data.getVar( 'RDEPENDS_opie-reader', d )
  59         plugindir = bb.data.expand('${palmtopdir}/plugins/reader', d)
  60         for dir, type in [ ( 'codecs', 'codec' ), ( 'filters', 'filter' ), ( 'outcodecs', 'output' ) ]:
  61             dir = plugindir + '/' + dir
  62             do_split_packages(d, dir,
  63                               '^lib(.*)\.so$', 'opie-reader-' + type + '-%s',
  64                               'Opie reader %s ' + type,
  65                               prepend=True)
  66
  67 }