code.vuplus.com Git - vuplus_openembedded/blob - recipes/gtk+/gtk+_2.8.16.bb

   1 LICENSE = "LGPL"
   2 DESCRIPTION = "GTK+ is a multi-platform toolkit for creating graphical user interfaces. Offering a complete \
   3 set of widgets, GTK+ is suitable for projects ranging from small one-off projects to complete application suites."
   4 HOMEPAGE = "http://www.gtk.org"
   5 SECTION = "libs"
   6 PRIORITY = "optional"
   7 DEPENDS = "glib-2.0 pango atk jpeg libpng libxext libxcursor gtk-doc libgcrypt cairo"
   8 PR = "r5"
   9
  10 DEFAULT_PREFERENCE = "-1"
  11
  12 SRC_URI = "ftp://ftp.gtk.org/pub/gtk/v2.8/gtk+-${PV}.tar.bz2 \
  13            file://no-xwc.patch;patch=1 \
  14            file://automake-lossage.patch;patch=1 \
  15            file://spinbutton.patch;patch=1 \
  16            file://hardcoded_libtool.patch;patch=1 \
  17            file://disable-tooltips.patch;patch=1 \
  18            file://gtklabel-resize-patch;patch=1 \
  19            file://gtktreeview-316689.patch;patch=1 \
  20            file://menu-deactivate.patch;patch=1 \
  21            file://xsettings.patch;patch=1 \
  22            file://scroll-timings.patch;patch=1 \
  23            file://small-gtkfilesel.patch;patch=1 \
  24            file://migration.patch;patch=1;pnum=0 \
  25            file://no-demos.patch;patch=1 \
  26            file://gtk+-handhelds.patch;patch=1 \
  27            file://single-click.patch;patch=1"
  28
  29 inherit autotools pkgconfig
  30
  31 CFLAGS += " -lz "
  32
  33 FILES_${PN} = "${bindir}/gdk-pixbuf-query-loaders \
  34         ${bindir}/gtk-query-immodules-2.0 \
  35         ${bindir}/gtk-update-icon-cache \
  36         ${libdir}/lib*.so.* \
  37         ${datadir}/themes ${sysconfdir} \
  38         ${libdir}/gtk-2.0/${LIBV}/engines/libpixmap.so"
  39 FILES_${PN}-dev += " \
  40         ${datadir}/gtk-2.0/include \
  41         ${libdir}/gtk-2.0/include \
  42         ${libdir}/gtk-2.0/${LIBV}/loaders/*.la \
  43         ${libdir}/gtk-2.0/${LIBV}/immodules/*.la \
  44         ${libdir}/gtk-2.0/${LIBV}/engines/*.la \
  45         ${bindir}/gdk-pixbuf-csource"
  46 FILES_${PN}-dbg += " \
  47         ${libdir}/gtk-2.0/${LIBV}/loaders/.debug/* \
  48         ${libdir}/gtk-2.0/${LIBV}/immodules/.debug/* \
  49         ${libdir}/gtk-2.0/${LIBV}/engines/.debug/*"
  50
  51 RRECOMMENDS_${PN} = "glibc-gconv-iso8859-1 ttf-dejavu-sans"
  52
  53 EXTRA_OECONF = "--without-libtiff --disable-xkb --disable-glibtest --enable-display-migration"
  54 # --disable-cruft
  55
  56 LIBV = "2.4.0"
  57
  58 do_stage () {
  59         oe_libinstall -so -C gtk libgtk-x11-2.0 ${STAGING_LIBDIR}
  60         oe_libinstall -so -C gdk libgdk-x11-2.0 ${STAGING_LIBDIR}
  61         oe_libinstall -so -C contrib/gdk-pixbuf-xlib libgdk_pixbuf_xlib-2.0 ${STAGING_LIBDIR}
  62         oe_libinstall -so -C gdk-pixbuf libgdk_pixbuf-2.0 ${STAGING_LIBDIR}
  63
  64         autotools_stage_includes
  65
  66         mkdir -p ${STAGING_LIBDIR}/gtk-2.0/include
  67         install -m 0644 gdk/gdkconfig.h ${STAGING_LIBDIR}/gtk-2.0/include/gdkconfig.h
  68
  69         install -m 0644 m4macros/gtk-2.0.m4 ${STAGING_DATADIR}/aclocal/
  70 }
  71
  72 do_install_append () {
  73         install -d ${D}${sysconfdir}/gtk-2.0
  74 }
  75
  76 postinst_prologue() {
  77 if [ "x$D" != "x" ]; then
  78   exit 1
  79 fi
  80
  81 }
  82
  83 PACKAGES_DYNAMIC = "gdk-pixbuf-loader-* gtk-immodule-*"
  84
  85 python populate_packages_prepend () {
  86         import os.path
  87
  88         prologue = bb.data.getVar("postinst_prologue", d, 1)
  89
  90         gtk_libdir = bb.data.expand('${libdir}/gtk-2.0/${LIBV}', d)
  91         loaders_root = os.path.join(gtk_libdir, 'loaders')
  92         immodules_root = os.path.join(gtk_libdir, 'immodules')
  93
  94         do_split_packages(d, loaders_root, '^libpixbufloader-(.*)\.so$', 'gdk-pixbuf-loader-%s', 'GDK pixbuf loader for %s', prologue + 'gdk-pixbuf-query-loaders > /etc/gtk-2.0/gdk-pixbuf.loaders')
  95         do_split_packages(d, immodules_root, '^im-(.*)\.so$', 'gtk-immodule-%s', 'GTK input module for %s', prologue + 'gtk-query-immodules-2.0 > /etc/gtk-2.0/gtk.immodules')
  96
  97         if (bb.data.getVar('DEBIAN_NAMES', d, 1)):
  98                 bb.data.setVar('PKG_${PN}', 'libgtk-2.0', d)
  99 }