code.vuplus.com Git - vuplus_openembedded/blob - recipes/glibc/glibc_2.6.1.bb

   1 require glibc.inc
   2 PR = "${INC_PR}.0"
   3
   4 PACKAGES_DYNAMIC = "libc6*"
   5 RPROVIDES_${PN}-dev = "libc6-dev virtual-libc-dev"
   6
   7 # the -isystem in bitbake.conf screws up glibc do_stage
   8 BUILD_CPPFLAGS = "-I${STAGING_INCDIR_NATIVE}"
   9 TARGET_CPPFLAGS = "-I${STAGING_DIR_TARGET}${layout_includedir}"
  10
  11
  12 FILESDIR = "${@os.path.dirname(bb.data.getVar('FILE',d,1))}/glibc-2.4"
  13
  14 GLIBC_ADDONS ?= "ports,nptl,libidn"
  15
  16 GLIBC_BROKEN_LOCALES = " _ER _ET so_ET yn_ER sid_ET tr_TR mn_MN gez_ET gez_ER bn_BD te_IN"
  17
  18 #
  19 # For now, we will skip building of a gcc package if it is a uclibc one
  20 # and our build is not a uclibc one, and we skip a glibc one if our build
  21 # is a uclibc build.
  22 #
  23 # See the note in gcc/gcc_3.4.0.oe
  24 #
  25
  26 python __anonymous () {
  27     import bb, re
  28     uc_os = (re.match('.*uclibc$', bb.data.getVar('TARGET_OS', d, 1)) != None)
  29     if uc_os:
  30         raise bb.parse.SkipPackage("incompatible with target %s" %
  31                                    bb.data.getVar('TARGET_OS', d, 1))
  32 }
  33
  34 RDEPENDS_${PN}-dev = "linux-libc-headers-dev"
  35
  36 SRC_URI = "\
  37   ftp://ftp.gnu.org/pub/gnu/glibc/glibc-${PV}.tar.bz2 \
  38   ftp://ftp.gnu.org/pub/gnu/glibc/glibc-ports-${PV}.tar.bz2 \
  39   ftp://ftp.gnu.org/pub/gnu/glibc/glibc-libidn-${PV}.tar.bz2 \
  40   file://arm-memcpy.patch;patch=1 \
  41   file://arm-longlong.patch;patch=1 \
  42   file://fhs-linux-paths.patch;patch=1 \
  43   file://dl-cache-libcmp.patch;patch=1 \
  44   file://nptl-crosscompile.patch;patch=1 \
  45   file://glibc-2.5-local-dynamic-resolvconf.patch;patch=1;pnum=0 \
  46   file://glibc-check_pf.patch;patch=1;pnum=0 \
  47   file://zecke-sane-readelf.patch;patch=1 \
  48   file://ldd-unbash.patch;patch=1 \
  49   file://generic-bits_select.h \
  50   file://generic-bits_types.h \
  51   file://generic-bits_typesizes.h \
  52   file://generic-bits_time.h \
  53   file://etc/ld.so.conf \
  54   file://generate-supported.mk \
  55   file://glibc-2.6.1-RTLD_SINGLE_THREAD_P-1.patch;patch=1 \
  56   file://glibc-2.6.1-use-short-for-fnstsw.patch;patch=1 \
  57   file://glibc-use-isystem-include-fixed.patch;patch=1 \
  58   file://glibc-arm-no-asm-page.patch;patch=1 \
  59   file://armv4t-interworking.patch;patch=1 \
  60   file://march-i686.patch;patch=1;pnum=0 \
  61 "
  62
  63 SRC_URI_append_ep9312 = "\
  64   file://glibc-crunch-endian-littleword-littlebyte.patch;patch=1 \
  65   file://glibc-crunch-eabi-setjmp_longjmp.patch;patch=1 \
  66   file://glibc-crunch-eabi-unwind.patch;patch=1 \
  67   file://glibc-crunch-eabi.patch;patch=1 \
  68   file://glibc-crunch-eabi-force.patch;patch=1 \
  69   file://glibc-crunch-eabi-fraiseexcpt.patch;patch=1 \
  70 "
  71
  72 # Build fails on sh3 and sh4 without additional patches
  73 SRC_URI_append_sh3 = " file://no-z-defs.patch;patch=1"
  74 SRC_URI_append_sh4 = " file://no-z-defs.patch;patch=1"
  75
  76 # PowerPC Patches to add support for soft-float
  77 SRC_URI_append_powerpc = "\
  78   file://powerpc-sqrt-hack.diff;patch=1 \
  79   file://glibc-2.6.1-powerpc-nofpu.patch;patch=1 \
  80 "
  81
  82 S = "${WORKDIR}/glibc-${PV}"
  83 B = "${WORKDIR}/build-${TARGET_SYS}"
  84
  85 EXTRA_OECONF = "\
  86   --enable-kernel=${OLDEST_KERNEL} \
  87   --without-cvs --disable-profile --disable-debug --without-gd \
  88   --enable-clocale=gnu \
  89   --enable-add-ons=${GLIBC_ADDONS} \
  90   --with-headers=${STAGING_INCDIR} \
  91   --without-selinux \
  92   ${GLIBC_EXTRA_OECONF} \
  93 "
  94
  95 EXTRA_OECONF += "${@get_glibc_fpu_setting(bb, d)}"
  96
  97 do_munge() {
  98         # Integrate ports and libidn into tree
  99         mv ${WORKDIR}/glibc-ports-${PV} ${S}/ports
 100         mv ${WORKDIR}/glibc-libidn-${PV} ${S}/libidn
 101
 102         # Ports isn't really working... Fix it
 103         # Some of this is rather dirty, but it seems to be the only
 104         # quick way to get this cruft to compile
 105         rm -rf ${S}/ports/sysdeps/unix/sysv/linux/arm/linuxthreads
 106         ln -s nptl ${S}/ports/sysdeps/unix/sysv/linux/arm/linuxthreads
 107         cp ${S}/nptl/sysdeps/pthread/bits/sigthread.h ${S}/ports/sysdeps/unix/sysv/linux/arm/bits/
 108         cp ${S}/sysdeps/unix/sysv/linux/i386/bits/wchar.h ${S}/ports/sysdeps/unix/sysv/linux/arm/bits/
 109         cp ${S}/sysdeps/wordsize-32/bits/wordsize.h ${S}/ports/sysdeps/unix/sysv/linux/arm/bits/
 110         cp ${WORKDIR}/generic-bits_select.h ${S}/ports/sysdeps/unix/sysv/linux/arm/bits/select.h
 111         cp ${WORKDIR}/generic-bits_types.h ${S}/ports/sysdeps/unix/sysv/linux/arm/bits/types.h
 112         cp ${WORKDIR}/generic-bits_typesizes.h ${S}/ports/sysdeps/unix/sysv/linux/arm/bits/typesizes.h
 113         cp ${WORKDIR}/generic-bits_time.h ${S}/ports/sysdeps/unix/sysv/linux/arm/bits/time.h
 114         # Copy in generic stuff for not yet implemented headers
 115         for i in ${S}/bits/*.h; do
 116                 F=`basename $i`
 117                 [ "$F" = "local_lim.h" ] && continue
 118                 [ "$F" = "errno.h" ] && continue
 119                 test -e ${S}/ports/sysdeps/unix/sysv/linux/arm/bits/$F || test -e ${S}/ports/sysdeps/arm/bits/$F || test -e ${S}/sysdeps/unix/sysv/linux/bits/$F || test -e ${S}/sysdeps/ieee754/bits/$F || cp $i ${S}/ports/sysdeps/unix/sysv/linux/arm/bits/
 120         done
 121         # This is harmful; we need to get the one from nptl/sysdeps/pthreads
 122         rm -f ${S}/ports/sysdeps/unix/sysv/linux/arm/bits/libc-lock.h
 123         # Obsoleted by sysdeps/arm/{fpu,eabi}/bits/fenv.h
 124         rm -f ${S}/ports/sysdeps/unix/sysv/linux/arm/bits/fenv.h
 125         # Obsoleted by sysdeps/gnu/bits/utmp.h
 126         rm -f ${S}/ports/sysdeps/unix/sysv/linux/arm/bits/utmp.h
 127 }
 128
 129 addtask munge before do_patch after do_unpack
 130
 131
 132 do_configure () {
 133 # override this function to avoid the autoconf/automake/aclocal/autoheader
 134 # calls for now
 135 # don't pass CPPFLAGS into configure, since it upsets the kernel-headers
 136 # version check and doesn't really help with anything
 137         if [ -z "`which rpcgen`" ]; then
 138                 echo "rpcgen not found.  Install glibc-devel."
 139                 exit 1
 140         fi
 141         (cd ${S} && gnu-configize) || die "failure in running gnu-configize"
 142         CPPFLAGS="" oe_runconf
 143 }
 144
 145 rpcsvc = "bootparam_prot.x nlm_prot.x rstat.x \
 146           yppasswd.x klm_prot.x rex.x sm_inter.x mount.x \
 147           rusers.x spray.x nfs_prot.x rquota.x key_prot.x"
 148
 149 do_compile () {
 150         # -Wl,-rpath-link <staging>/lib in LDFLAGS can cause breakage if another glibc is in staging
 151         unset LDFLAGS
 152         base_do_compile
 153         (
 154                 cd ${S}/sunrpc/rpcsvc
 155                 for r in ${rpcsvc}; do
 156                         h=`echo $r|sed -e's,\.x$,.h,'`
 157                         rpcgen -h $r -o $h || oewarn "unable to generate header for $r"
 158                 done
 159         )
 160 }
 161
 162 require glibc-stage.inc
 163
 164 require glibc-package.inc