code.vuplus.com Git - vuplus_openembedded/blob - recipes/glibc/glibc_2.5.bb

   1 require glibc.inc
   2 PR = "${INC_PR}.0"
   3
   4 ARM_INSTRUCTION_SET = "arm"
   5
   6 PACKAGES_DYNAMIC = "libc6*"
   7 RPROVIDES_${PN}-dev = "libc6-dev virtual-libc-dev"
   8
   9 # the -isystem in bitbake.conf screws up glibc do_stage
  10 BUILD_CPPFLAGS = "-I${STAGING_INCDIR_NATIVE}"
  11 TARGET_CPPFLAGS = "-I${STAGING_DIR_TARGET}${layout_includedir}"
  12
  13 FILESDIR = "${@os.path.dirname(bb.data.getVar('FILE',d,1))}/glibc-2.4"
  14
  15 GLIBC_ADDONS ?= "ports,nptl,libidn"
  16
  17 GLIBC_BROKEN_LOCALES = "sid_ET tr_TR mn_MN gez_ET gez_ER bn_BD te_IN"
  18
  19 #
  20 # For now, we will skip building of a gcc package if it is a uclibc one
  21 # and our build is not a uclibc one, and we skip a glibc one if our build
  22 # is a uclibc build.
  23 #
  24 # See the note in gcc/gcc_3.4.0.oe
  25 #
  26
  27 python __anonymous () {
  28     import bb, re
  29     uc_os = (re.match('.*uclibc$', bb.data.getVar('TARGET_OS', d, 1)) != None)
  30     if uc_os:
  31         raise bb.parse.SkipPackage("incompatible with target %s" %
  32                                    bb.data.getVar('TARGET_OS', d, 1))
  33 }
  34
  35 RDEPENDS_${PN}-dev = "linux-libc-headers-dev"
  36
  37 SRC_URI = "\
  38   ftp://ftp.gnu.org/pub/gnu/glibc/glibc-${PV}.tar.bz2 \
  39   ftp://ftp.gnu.org/pub/gnu/glibc/glibc-ports-${PV}.tar.bz2 \
  40   ftp://ftp.gnu.org/pub/gnu/glibc/glibc-libidn-${PV}.tar.bz2 \
  41   file://arm-memcpy.patch;patch=1 \
  42   file://arm-longlong.patch;patch=1 \
  43   file://fhs-linux-paths.patch;patch=1 \
  44   file://dl-cache-libcmp.patch;patch=1 \
  45   file://ldsocache-varrun.patch;patch=1 \
  46   file://nptl-crosscompile.patch;patch=1 \
  47   file://glibc-2.5-local-dynamic-resolvconf.patch;patch=1;pnum=0 \
  48   file://glibc-check_pf.patch;patch=1;pnum=0 \
  49   file://zecke-sane-readelf.patch;patch=1 \
  50   file://ldd-unbash.patch;patch=1 \
  51   file://glibc-2.6.1-use-short-for-fnstsw.patch;patch=1 \
  52   file://generic-bits_select.h \
  53   file://generic-bits_types.h \
  54   file://generic-bits_typesizes.h \
  55   file://generic-bits_time.h \
  56   file://etc/ld.so.conf \
  57   file://generate-supported.mk \
  58 "
  59
  60 # Build fails on sh3 and sh4 without additional patches
  61 SRC_URI_append_sh3 = " file://no-z-defs.patch;patch=1"
  62 SRC_URI_append_sh4 = " file://no-z-defs.patch;patch=1"
  63
  64 # Powerpc patches to add support for soft-float
  65 SRC_URI_append_powerpc = " file://ppc-sfp-machine.patch;patch=1 \
  66                            file://ppc-soft-fp-20070115.patch;patch=1 \
  67                            file://ppc-ld-nofpu-20070104.patch;patch=1 \
  68                            file://ppc-ports-ld-nofpu-20070114.patch;patch=1 \
  69                            file://powerpc-sqrt-hack.diff;patch=1 \
  70                            file://glibc-2.5-soft-fp-separate-strong-alias.patch;patch=1"
  71
  72 S = "${WORKDIR}/glibc-${PV}"
  73 B = "${WORKDIR}/build-${TARGET_SYS}"
  74
  75 EXTRA_OECONF = "\
  76   --enable-kernel=${OLDEST_KERNEL} \
  77   --without-cvs --disable-profile --disable-debug --without-gd \
  78   --enable-clocale=gnu \
  79   --enable-add-ons=${GLIBC_ADDONS} \
  80   --with-headers=${STAGING_INCDIR} \
  81   --without-selinux \
  82   ${GLIBC_EXTRA_OECONF} \
  83 "
  84
  85 EXTRA_OECONF += "${@get_glibc_fpu_setting(bb, d)}"
  86
  87 do_munge() {
  88         # Integrate ports and libidn into tree
  89         mv ${WORKDIR}/glibc-ports-${PV} ${S}/ports
  90         mv ${WORKDIR}/glibc-libidn-${PV} ${S}/libidn
  91
  92         # Ports isn't really working... Fix it
  93         # Some of this is rather dirty, but it seems to be the only
  94         # quick way to get this cruft to compile
  95         rm -rf ${S}/ports/sysdeps/unix/sysv/linux/arm/linuxthreads
  96         ln -s nptl ${S}/ports/sysdeps/unix/sysv/linux/arm/linuxthreads
  97         cp ${S}/nptl/sysdeps/pthread/bits/sigthread.h ${S}/ports/sysdeps/unix/sysv/linux/arm/bits/
  98         cp ${S}/sysdeps/unix/sysv/linux/i386/bits/wchar.h ${S}/ports/sysdeps/unix/sysv/linux/arm/bits/
  99         cp ${S}/sysdeps/wordsize-32/bits/wordsize.h ${S}/ports/sysdeps/unix/sysv/linux/arm/bits/
 100         cp ${WORKDIR}/generic-bits_select.h ${S}/ports/sysdeps/unix/sysv/linux/arm/bits/select.h
 101         cp ${WORKDIR}/generic-bits_types.h ${S}/ports/sysdeps/unix/sysv/linux/arm/bits/types.h
 102         cp ${WORKDIR}/generic-bits_typesizes.h ${S}/ports/sysdeps/unix/sysv/linux/arm/bits/typesizes.h
 103         cp ${WORKDIR}/generic-bits_time.h ${S}/ports/sysdeps/unix/sysv/linux/arm/bits/time.h
 104         # Copy in generic stuff for not yet implemented headers
 105         for i in ${S}/bits/*.h; do
 106                 F=`basename $i`
 107                 [ "$F" = "local_lim.h" ] && continue
 108                 [ "$F" = "errno.h" ] && continue
 109                 test -e ${S}/ports/sysdeps/unix/sysv/linux/arm/bits/$F || test -e ${S}/ports/sysdeps/arm/bits/$F || test -e ${S}/sysdeps/unix/sysv/linux/bits/$F || test -e ${S}/sysdeps/ieee754/bits/$F || cp $i ${S}/ports/sysdeps/unix/sysv/linux/arm/bits/
 110         done
 111         # This is harmful; we need to get the one from nptl/sysdeps/pthreads
 112         rm -f ${S}/ports/sysdeps/unix/sysv/linux/arm/bits/libc-lock.h
 113         # Obsoleted by sysdeps/arm/{fpu,eabi}/bits/fenv.h
 114         rm -f ${S}/ports/sysdeps/unix/sysv/linux/arm/bits/fenv.h
 115         # Obsoleted by sysdeps/gnu/bits/utmp.h
 116         rm -f ${S}/ports/sysdeps/unix/sysv/linux/arm/bits/utmp.h
 117 }
 118
 119 addtask munge before do_patch after do_unpack
 120
 121
 122 do_configure () {
 123 # override this function to avoid the autoconf/automake/aclocal/autoheader
 124 # calls for now
 125 # don't pass CPPFLAGS into configure, since it upsets the kernel-headers
 126 # version check and doesn't really help with anything
 127         if [ -z "`which rpcgen`" ]; then
 128                 echo "rpcgen not found.  Install glibc-devel."
 129                 exit 1
 130         fi
 131         (cd ${S} && gnu-configize) || die "failure in running gnu-configize"
 132         CPPFLAGS="" oe_runconf
 133 }
 134
 135 rpcsvc = "bootparam_prot.x nlm_prot.x rstat.x \
 136           yppasswd.x klm_prot.x rex.x sm_inter.x mount.x \
 137           rusers.x spray.x nfs_prot.x rquota.x key_prot.x"
 138
 139 do_compile () {
 140         # -Wl,-rpath-link <staging>/lib in LDFLAGS can cause breakage if another glibc is in staging
 141         unset LDFLAGS
 142         base_do_compile
 143         (
 144                 cd ${S}/sunrpc/rpcsvc
 145                 for r in ${rpcsvc}; do
 146                         h=`echo $r|sed -e's,\.x$,.h,'`
 147                         rpcgen -h $r -o $h || oewarn "unable to generate header for $r"
 148                 done
 149         )
 150 }
 151
 152 require glibc-stage.inc
 153
 154 require glibc-package.inc