code.vuplus.com Git - vuplus_openembedded/blob - recipes/enigma2/enigma2.bb

   1 DESCRIPTION = "Enigma2 is an experimental, but useful framebuffer-based frontend for DVB functions"
   2 MAINTAINER = "Felix Domke <tmbinc@elitedvb.net>"
   3 DEPENDS = "jpeg libungif libmad libpng libsigc++-1.2 gettext-native \
   4         dreambox-dvbincludes freetype libdvbsi++ python swig-native \
   5         libfribidi libxmlccwrap libdreamdvd gstreamer gst-plugin-dvbmediasink \
   6         gst-plugins-bad gst-plugins-good gst-plugins-ugly python-wifi"
   7 RDEPENDS = "python-codecs python-core python-lang python-re python-threading \
   8         python-xml python-fcntl gst-plugin-decodebin gst-plugin-decodebin2 python-stringold \
   9         python-pickle gst-plugin-app \
  10         gst-plugin-id3demux gst-plugin-mad gst-plugin-ogg gst-plugin-playbin \
  11         gst-plugin-typefindfunctions gst-plugin-audioconvert gst-plugin-audioresample \
  12         gst-plugin-wavparse python-netclient gst-plugin-mpegstream \
  13         gst-plugin-flac gst-plugin-dvbmediasink gst-plugin-mpegdemux gst-plugin-dvdsub \
  14         gst-plugin-souphttpsrc gst-plugin-mpegaudioparse gst-plugin-subparse \
  15         gst-plugin-apetag gst-plugin-icydemux gst-plugin-autodetect \
  16         glibc-gconv-iso8859-15 ethtool"
  17
  18 GST_RTSP_RDEPENDS = "gst-plugin-udp gst-plugin-rtsp gst-plugin-rtp gst-plugin-rtpmanager"
  19 GST_ALSA_RDEPENDS = "gst-plugin-alsa alsa-conf"
  20 GST_MISC_RDEPENDS = "gst-plugin-matroska gst-plugin-qtdemux gst-plugin-vorbis gst-plugin-audioparsersbad"
  21 GST_DVD_RDEPENDS = "gst-plugin-cdxaparse gst-plugin-cdio gst-plugin-vcdsrc"
  22 GST_BASE_RDEPENDS = "${GST_ALSA_RDEPENDS} ${GST_MISC_RDEPENDS} ${GST_RTSP_RDEPENDS}"
  23
  24 RDEPENDS_append_dm7020 = " gst-plugin-ossaudio gst-plugin-ivorbisdec"
  25 RDEPENDS_append_dm7025 = " ${GST_ALSA_RDEPENDS} gst-plugin-ivorbisdec"
  26 RDEPENDS_append_dm800 = " ${GST_BASE_RDEPENDS} gst-plugin-ivorbisdec"
  27 RDEPENDS_append_dm8000 = " ${GST_BASE_RDEPENDS} ${GST_DVD_RDEPENDS} gst-plugin-avi"
  28 RDEPENDS_append_dm500hd = " ${GST_BASE_RDEPENDS} ${GST_DVD_RDEPENDS} gst-plugin-avi"
  29 RDEPENDS_append_dm800se = " ${GST_BASE_RDEPENDS} ${GST_DVD_RDEPENDS} gst-plugin-avi"
  30 RDEPENDS_append_dm7020hd = " ${GST_BASE_RDEPENDS} ${GST_DVD_RDEPENDS} gst-plugin-avi"
  31
  32 # 'forward depends' - no two providers can have the same PACKAGES_DYNAMIC, however both
  33 # enigma2 and enigma2-plugins produce enigma2-plugin-*.
  34 #DEPENDS += "enigma2-plugins"
  35 #PACKAGES_DYNAMIC = "enigma2-plugin-*"
  36
  37 DESCRIPTION_append_enigma2-plugin-extensions-cutlisteditor = "enables you to cut your movies."
  38 RDEPENDS_enigma2-plugin-extensions-cutlisteditor = "aio-grab"
  39 DESCRIPTION_append_enigma2-plugin-extensions-graphmultiepg = "shows a graphical timeline EPG."
  40 DESCRIPTION_append_enigma2-plugin-extensions-pictureplayer = "displays photos on the TV."
  41 DESCRIPTION_append_enigma2-plugin-systemplugins-frontprocessorupdate = "keeps your frontprocessor up to date."
  42 DESCRIPTION_append_enigma2-plugin-systemplugins-positionersetup = "helps you installing a motorized dish."
  43 DESCRIPTION_append_enigma2-plugin-systemplugins-satelliteequipmentcontrol = "allows you to fine-tune DiSEqC-settings."
  44 DESCRIPTION_append_enigma2-plugin-systemplugins-satfinder = "helps you to align your dish."
  45 DESCRIPTION_append_enigma2-plugin-systemplugins-skinselector = "shows a menu with selectable skins."
  46 DESCRIPTION_append_enigma2-plugin-systemplugins-videomode = "selects advanced video modes"
  47 RDEPENDS_enigma2-plugin-extensions-dvdplayer = "libdreamdvd0"
  48 RDEPENDS_enigma2-plugin-systemplugins-nfiflash = "twisted-web"
  49 RDEPENDS_enigma2-plugin-systemplugins-softwaremanager = "twisted-web"
  50 RCONFLICTS_enigma2-plugin-systemplugins-softwaremanager = "enigma2-plugin-systemplugins-configurationbackup enigma2-plugin-systemplugins-softwareupdate"
  51 RREPLACES_enigma2-plugin-systemplugins-softwaremanager = "enigma2-plugin-systemplugins-configurationbackup enigma2-plugin-systemplugins-softwareupdate"
  52 DESCRIPTION_append_enigma2-plugin-systemplugins-crashlogautosubmit = "automatically send crashlogs to Dream Multimedia"
  53 RDEPENDS_enigma2-plugin-systemplugins-crashlogautosubmit = "twisted-mail twisted-names python-compression python-mime python-email"
  54 DESCRIPTION_append_enigma2-plugin-systemplugins-cleanupwizard = "informs you on low internal memory on system startup."
  55 DESCRIPTION_append_enigma2-plugin-extenstions-modem = "opens a menu to connect to internet via builtin modem."
  56 RDEPENDS_enigma2-plugin-extensions-modem = "dreambox-modem-ppp-scripts ppp"
  57 DESCRIPTION_append_enigma2-plugin-systemplugins-wirelesslan = "helps you configuring your wireless lan"
  58 RDEPENDS_enigma2-plugin-systemplugins-wirelesslan = "wpa-supplicant wireless-tools python-wifi"
  59 DESCRIPTION_append_enigma2-plugin-systemplugins-networkwizard = "provides easy step by step network configuration"
  60
  61 PN = "enigma2"
  62 PR = "r0"
  63
  64 SRCDATE = "20110217"
  65 SRCREV = "5e19a3f8a5e8ce8a4e2cb2b601a1b8ef3554e4be"
  66 #SRCDATE is NOT used by git to checkout a specific revision
  67 #but we need it to build a ipk package version
  68 #when you like to checkout a specific revision of e2 you need
  69 #have to specify a commit id or a tag name in SRCREV
  70
  71 # if you want experimental use
  72 ####################################################
  73 BRANCH = "experimental"
  74 PV = "experimental-git${SRCDATE}"
  75 #SRCREV = ""
  76 ####################################################
  77
  78 SRC_URI = "git://git.opendreambox.org/git/enigma2.git;protocol=git;branch=${BRANCH};tag=${SRCREV}"
  79 SRC_URI_append_dm7025 = " file://7025_pvr_device_compatibility.diff;patch=1;pnum=1"
  80
  81 S = "${WORKDIR}/git"
  82
  83 FILES_${PN} += "${datadir}/fonts ${datadir}/keymaps"
  84 FILES_${PN}-meta = "${datadir}/meta"
  85 PACKAGES += "${PN}-meta"
  86 PACKAGE_ARCH = "${MACHINE_ARCH}"
  87
  88 inherit autotools pkgconfig
  89
  90 EXTRA_OECONF = " \
  91         BUILD_SYS=${BUILD_SYS} \
  92         HOST_SYS=${HOST_SYS} \
  93         STAGING_INCDIR=${STAGING_INCDIR} \
  94         STAGING_LIBDIR=${STAGING_LIBDIR} \
  95 "
  96
  97 python populate_packages_prepend () {
  98         enigma2_plugindir = bb.data.expand('${libdir}/enigma2/python/Plugins', d)
  99
 100         do_split_packages(d, enigma2_plugindir, '(.*?/.*?)/.*', 'enigma2-plugin-%s', '%s ', recursive=True, match_path=True, prepend=True)
 101 }
 102
 103 RCONFLICTS_${PN} = "dreambox-keymaps"
 104 RREPLACES_${PN} = "dreambox-keymaps tuxbox-tuxtxt-32bpp (<= 0.0+cvs20090130-r1)"
 105
 106 # workaround for opkg <= 0.1.7+svnr455-r19.1
 107 pkg_preinst_${PN} () {
 108         if [ "x$D" != "x" ]; then
 109                 exit 1
 110         fi
 111         if [ -f ${datadir}/fonts/tuxtxt.ttf ]; then
 112                 cp -a ${datadir}/fonts/tuxtxt.ttf /tmp/tuxtxt.ttf
 113         fi
 114 }
 115 pkg_postinst_${PN} () {
 116         if [ "x$D" != "x" ]; then
 117                 exit 1
 118         fi
 119         if [ -f /tmp/tuxtxt.ttf -a ! -f ${datadir}/fonts/tuxtxt.ttf ]; then
 120                 mv /tmp/tuxtxt.ttf ${datadir}/fonts/tuxtxt.ttf
 121         fi
 122 }