code.vuplus.com Git - vuplus_openembedded/blob - recipes/emacs/emacs_cvs.bb

   1 DESCRIPTION = "Emacs"
   2 HOMEPAGE = "http://www.gnu.org/software/emacs/"
   3 LICENSE = "GPLv2"
   4 SECTION = "editor"
   5 # and it needs to run some generated binaries..
   6 DEPENDS += "qemu-native"
   7 #NOTE: I have found that this only works with qemu-0.8.0. If I use 0.8.1 or 0.8.2
   8 # the build gets hung up on compiling certain .el files
   9
  10 PV = "22.0.50+cvs${SRCDATE}"
  11 PE = "1"
  12 PR = "r9"
  13
  14 DEFAULT_PREFERENCE = "-1"
  15
  16 SRC_URI = "cvs://anoncvs:anonymous@cvs.savannah.gnu.org/sources/emacs;module=emacs \
  17            file://use-qemu.patch;patch=1"
  18 S = "${WORKDIR}/emacs"
  19
  20 inherit autotools
  21
  22 PACKAGES =+ "${PN}-el"
  23
  24 FILES_${PN}-el = "${datadir}/emacs/*/*/*.el.gz \
  25                   ${datadir}/emacs/*/*/*/*.el.gz"
  26
  27 FILES_${PN} += "${datadir}/emacs"
  28
  29 QEMU = "qemu-${TARGET_ARCH} -L ${STAGING_DIR_TARGET}"
  30 LDFLAGS += "-L${CROSS_DIR}/${TARGET_SYS}/lib"
  31
  32 EXTRA_OECONF = "--without-sound --without-x"
  33
  34 do_bootstrap() {
  35     cp "${CROSS_DIR}/${TARGET_SYS}/lib/libgcc_s.so.1" "${S}"
  36     export LD_LIBRARY_PATH="$LD_LIBRARY_PATH:${S}"
  37     export QEMU="${QEMU}"
  38
  39     sed -i 's:/usr/lib:${STAGING_LIBDIR}:g' ${S}/src/s/gnu-linux.h
  40     find "${S}" -name Makefile | xargs sed -i 's:/usr/lib:${STAGING_LIBDIR}:g'
  41
  42     cd "${S}"
  43     make bootstrap
  44 }
  45
  46 addtask bootstrap before do_compile after do_configure
  47
  48 do_compile_prepend() {
  49     cp "${CROSS_DIR}/${TARGET_SYS}/lib/libgcc_s.so.1" "${S}"
  50     export LD_LIBRARY_PATH="$LD_LIBRARY_PATH:${S}"
  51     export QEMU="${QEMU}"
  52 }