code.vuplus.com Git - vuplus_openembedded/blob - recipes/distcc/distcc_2.18.3.bb

   1 DESCRIPTION = "distcc is a parallel build system that distributes \
   2 compilation of C/C++/ObjC code across machines on a network."
   3 SECTION = "devel"
   4 LICENSE = "GPLv2"
   5 PR = "r4"
   6
   7 DEPENDS = "avahi gtk+"
   8 RRECOMMENDS = "avahi-daemon"
   9
  10 SRC_URI = "http://distcc.samba.org/ftp/distcc/distcc-${PV}.tar.bz2 \
  11            file://distcc-avahi.patch;patch=1 \
  12            file://no-man.patch;patch=1 \
  13            file://default \
  14            file://distccmon-gnome.desktop \
  15            file://distcc"
  16
  17 inherit autotools pkgconfig update-rc.d
  18
  19 INITSCRIPT_NAME = "distcc"
  20
  21 EXTRA_OECONF = " --with-gtk "
  22
  23 do_install_append() {
  24     install -d ${D}${sysconfdir}/init.d/
  25     install -d ${D}${sysconfdir}/default
  26     install -d ${D}${sysconfdir}/distcc
  27     install -m 0755 ${WORKDIR}/distcc ${D}${sysconfdir}/init.d/
  28     install -m 0755 ${WORKDIR}/default ${D}${sysconfdir}/default/distcc
  29     install -m 0644 ${WORKDIR}/distccmon-gnome.desktop ${D}${datadir}/distcc/
  30     echo "+zeroconf" > ${D}${sysconfdir}/distcc/hosts
  31 }
  32
  33 PACKAGES += "distcc-distmon-gnome"
  34
  35 FILES_${PN} = " ${sysconfdir} \
  36                 ${bindir}/distcc \
  37                 ${bindir}/distccd \
  38                 ${bindir}/distccmon-text"
  39
  40 CONFFILES_${PN} += "${sysconfdir}/default/distcc \
  41                     ${sysconfdir}/distcc/hosts \
  42                     ${sysconfdir}/init.d/distcc \
  43                    "
  44
  45 FILES_distcc-distmon-gnome = "  ${bindir}/distccmon-gnome \
  46                                 ${datadir}/distcc"