code.vuplus.com Git - vuplus_openembedded/blob - recipes/conserver/conserver.inc

   1 DESCRIPTION = "Conserver provides remote access to serial port \
   2 consoles and logs all data to a central host."
   3 HOMEPAGE = "http://www.conserver.com/"
   4 SECTION = "console/network"
   5 LICENSE = "BSD"
   6
   7 SRC_URI = "http://www.conserver.com/conserver-${PV}.tar.gz \
   8            file://conserver.init \
   9            file://conserver.default"
  10
  11 inherit autotools update-rc.d
  12
  13 # Stop install being called with -s so it doesn't try and run the host strip command
  14 EXTRA_OEMAKE = " INSTALL_PROGRAM=install"
  15
  16 # Include the init script and default settings in the package
  17 do_install_append () {
  18         install -m 0755 -d ${D}${sysconfdir}/default ${D}${sysconfdir}/init.d
  19         install -m 0644 ${WORKDIR}/conserver.default ${D}${sysconfdir}/default/conserver
  20         install -m 0755 ${WORKDIR}/conserver.init ${D}${sysconfdir}/init.d/conserver
  21 }
  22
  23 # Include the examples in the documentation package
  24 FILES_${PN}-doc += "${datadir}/examples/conserver"
  25
  26 # Make sure .debug files end up in the correct place
  27 FILES_${PN} = "${sysconfdir} ${bindir}/* ${libdir}/${PN}/* ${sbindir}/*"
  28 FILES_${PN}-dbg += "${bindir}/.debug ${sbindir}/.debug ${libdir}/${PN}/.debug"
  29
  30 # Indicate that the default file is a configuation file
  31 CONFFILES_${PN} = "${sysconfdir}/default/conserver"
  32
  33 # Settings for the initscript
  34 INITSCRIPT_NAME = "conserver"
  35 INITSCRIPT_PARAMS = "defaults 98 2"