code.vuplus.com Git - vuplus_openembedded/blob - recipes/ant/ant-native_1.7.1.bb

   1 DESCRIPTION = "Another Neat Tool - build system for Java"
   2 LICENSE = "AL2.0"
   3
   4 AUTHOR = "Apache Software Foundation"
   5 HOMEPAGE = "http://ant.apache.org"
   6
   7 SRC_URI = "\
   8     http://ftp.riken.jp/net/apache/ant/source/apache-ant-${PV}-src.tar.gz \
   9         file://ant \
  10         "
  11
  12 S = "${WORKDIR}/apache-ant-${PV}"
  13
  14 inherit java-library java-native
  15
  16 DEPENDS = "\
  17         fastjar-native \
  18         jsch-native bsf-native xalan-j-native xerces-j-native \
  19         xml-commons-resolver1.1-native gnumail-native gnujaf-native \
  20         bcel-native regexp-native log4j1.2-native antlr-native oro-native \
  21         junit-native jdepend-native commons-net-native commons-logging-native \
  22         "
  23
  24 do_removecruft() {
  25         # Removes thing that need proprietary Jar files or are otherwise problematic
  26         rm -rf ${S}/src/main/org/apache/tools/ant/taskdefs/optional/image
  27         rm -rf ${S}/src/main/org/apache/tools/ant/types/optional/image
  28         rm -rf ${S}/src/main/org/apache/tools/ant/taskdefs/optional/ejb
  29         rm -rf ${S}/src/main/org/apache/tools/ant/taskdefs/optional/scm
  30         rm -rf ${S}/src/main/org/apache/tools/ant/taskdefs/optional/starteam
  31         rm -rf ${S}/src/main/org/apache/tools/ant/taskdefs/optional/NetRexxC.java
  32 }
  33
  34 addtask removecruft before do_patch after do_unpack
  35
  36 do_compile() {
  37   mkdir -p build
  38
  39   oe_makeclasspath cp -s jsch bsf xalan2 xercesImpl resolver gnumail gnujaf bcel regexp log4j1.2 antlr oro junit jdepend commons-net commons-logging
  40   cp=build:$cp
  41
  42   find src/main -name "*.java" > java_files
  43
  44   javac -sourcepath src/main -cp $cp -d build @java_files
  45
  46   mkdir -p build/org/apache/tools/ant/types/conditions
  47
  48   cp -r src/resources/org build/
  49   (cd src/main && find . \( -name "*.properties" -or -name "*.xml" -or -name "*.mf" \) -exec cp {} ../../build/{} \;)
  50
  51   echo "VERSION=${PV}" > build/org/apache/tools/ant/version.txt
  52   echo "DATE=`date -R`" >> build/org/apache/tools/ant/version.txt
  53
  54   fastjar -C build -c -f ${JARFILENAME} .
  55
  56   oe_makeclasspath cp -s ecj-bootstrap jsch bsf xalan2 xercesImpl resolver gnumail gnujaf bcel regexp log4j1.2 antlr oro junit jdepend commons-net commons-logging
  57   cp=${STAGING_DATADIR_JAVA_NATIVE}/ant.jar:${STAGING_DATADIR}/classpath/tools.zip:$cp
  58   sed -i -e"s|@JAR_FILE@|$cp|" ${WORKDIR}/ant
  59 }
  60
  61 do_stage_append() {
  62         install -d ${bindir}
  63         install -m 0755 ${WORKDIR}/ant ${bindir}
  64 }