code.vuplus.com Git - vuplus_openembedded/blob - recipes/abiword/abiword-plugins_2.6.4.bb

   1 DESCRIPTION = "AbiWord is a free word processing program similar to Microsoft(r) Word"
   2 HOMEPAGE = "http://www.abiword.org"
   3 SECTION = "x11/office"
   4 LICENSE = "GPLv2"
   5 DEPENDS = "asio boost loudmouth libwpd librsvg goffice poppler libglade"
   6 RDEPENDS = "abiword"
   7
   8 PR = "r1"
   9
  10 SRC_URI = "http://www.abiword.org/downloads/abiword/${PV}/source/abiword-plugins-${PV}.tar.gz \
  11            http://www.abiword.org/downloads/abiword/${PV}/source/abiword-${PV}.tar.gz \
  12 #           file://abiword-cxx-for-ld-fix.patch;patch=1 \
  13            "
  14
  15 DEFAULT_PREFERENCE = "2"
  16
  17 inherit autotools
  18
  19 PARALLEL_MAKE=""
  20
  21 #export LDFLAGS += " -lstdc++ "
  22
  23 EXTRA_OECONF = " --enable-shared=yes \
  24                  --enable-static \
  25                  --without-libwmf \
  26                  --without-inter7eps \
  27                  --with-abiword=${WORKDIR}/abiword-${PV} \
  28                  --with-boost=${STAGING_DIR_HOST} \
  29                  --with-boost-thread=boost_thread-mt \
  30                "
  31
  32 PACKAGES_DYNAMIC = "abiword-plugin-*"
  33
  34 python populate_packages_prepend () {
  35         abiword_libdir    = bb.data.expand('${libdir}/abiword-2.6/plugins', d)
  36         do_split_packages(d, abiword_libdir, '^libAbi(.*)\.so$', 'abiword-plugin-%s', 'Abiword plugin for %s', extra_depends='')
  37         do_split_packages(d, abiword_libdir, '^libAbi(.*)\.la$', 'abiword-plugin-%s-dev', 'Abiword plugin for %s', extra_depends='')
  38
  39         metapkg = "abiword-plugins"
  40         bb.data.setVar('ALLOW_EMPTY_' + metapkg, "1", d)
  41         bb.data.setVar('FILES_' + metapkg, "", d)
  42         blacklist = [ 'abiword-plugins-dbg', 'abiword-plugins', 'abiword-plugins-doc', 'abiword-plugins-dev', 'abiword-plugins-locale' ]
  43         metapkg_rdepends = []
  44         packages = bb.data.getVar('PACKAGES', d, 1).split()
  45         for pkg in packages[1:]:
  46                 if not pkg in blacklist and not pkg in metapkg_rdepends:
  47                         print "Modifying ", pkg
  48                         metapkg_rdepends.append(pkg)
  49         bb.data.setVar('RDEPENDS_' + metapkg, ' '.join(metapkg_rdepends), d)
  50         bb.data.setVar('DESCRIPTION_' + metapkg, 'abiword-plugin meta package', d)
  51         packages.append(metapkg)
  52         bb.data.setVar('PACKAGES', ' '.join(packages), d)
  53 }
  54
  55
  56 PACKAGES =+ "abiword-plugin-collab-glade"
  57
  58 FILES_abiword-plugin-collab-glade += "${datadir}"
  59 RDEPENDS_abiword-plugin-collab-glade = "abiword-plugin-collab"
  60
  61 FILES_${PN}-dbg += "${libdir}/abiword-2.6/plugins/.debug"
  62