code.vuplus.com Git - vuplus_openembedded/blob - packages/sysvinit/sysvinit_2.86.bb

   1 DESCRIPTION = "System-V like init."
   2 SECTION = "base"
   3 LICENSE = "GPL"
   4 HOMEPAGE = "http://freshmeat.net/projects/sysvinit/"
   5 FILE_PR = "r42"
   6
   7 # USE_VT and SERIAL_CONSOLE are generally defined by the MACHINE .conf.
   8 # Set PACKAGE_ARCH appropriately.
   9 PACKAGE_ARCH_${PN}-inittab = "${MACHINE_ARCH}"
  10
  11 RDEPENDS_${PN} = "${PN}-inittab"
  12
  13 PACKAGES =+ "bootlogd ${PN}-inittab"
  14 FILES_bootlogd = "/etc/init.d/bootlogd /etc/init.d/stop-bootlogd /etc/rc?.d/S*bootlogd /sbin/bootlogd"
  15 FILES_${PN}-inittab = "${sysconfdir}/inittab"
  16 CONFFILES_${PN}-inittab = "${sysconfdir}/inittab"
  17
  18 USE_VT ?= "1"
  19 SYSVINIT_ENABLED_GETTYS ?= "1"
  20
  21 SRC_URI = "ftp://ftp.cistron.nl/pub/people/miquels/sysvinit/sysvinit-${PV}.tar.gz \
  22            file://install.patch;patch=1 \
  23            file://need \
  24            file://provide \
  25            file://inittab \
  26            file://rcS-default \
  27            file://rc \
  28            file://rcS \
  29            file://bootlogd.init"
  30
  31 S = "${WORKDIR}/sysvinit-${PV}"
  32 B = "${S}/src"
  33
  34 inherit update-alternatives
  35
  36 ALTERNATIVE_NAME = "init"
  37 ALTERNATIVE_LINK = "${base_sbindir}/init"
  38 ALTERNATIVE_PATH = "${base_sbindir}/init.sysvinit"
  39 ALTERNATIVE_PRIORITY = "50"
  40
  41 PACKAGES =+ "sysvinit-pidof sysvinit-sulogin"
  42 FILES_${PN} += "${base_sbindir} ${base_bindir}"
  43 FILES_sysvinit-pidof = "${base_bindir}/pidof.sysvinit"
  44 FILES_sysvinit-sulogin = "${base_sbindir}/sulogin"
  45
  46 CFLAGS_prepend = "-D_GNU_SOURCE "
  47 export LCRYPT = "-lcrypt"
  48 EXTRA_OEMAKE += "'INSTALL=install' \
  49                  'bindir=${base_bindir}' \
  50                  'sbindir=${base_sbindir}' \
  51                  'usrbindir=${bindir}' \
  52                  'usrsbindir=${sbindir}' \
  53                  'includedir=${includedir}' \
  54                  'mandir=${mandir}' \
  55                  DISTRO=''"
  56
  57 do_install () {
  58         oe_runmake 'ROOT=${D}' install
  59         install -d ${D}${sysconfdir}
  60         install -d ${D}${sysconfdir}/default
  61         install -d ${D}${sysconfdir}/init.d
  62         install -m 0644 ${WORKDIR}/inittab ${D}${sysconfdir}/inittab
  63         if [ ! -z "${SERIAL_CONSOLE}" ]; then
  64                 echo "S:2345:respawn:${base_sbindir}/getty ${SERIAL_CONSOLE}" >> ${D}${sysconfdir}/inittab
  65         fi
  66         if [ "${USE_VT}" = "1" ]; then
  67                 cat <<EOF >>${D}${sysconfdir}/inittab
  68 # ${base_sbindir}/getty invocations for the runlevels.
  69 #
  70 # The "id" field MUST be the same as the last
  71 # characters of the device (after "tty").
  72 #
  73 # Format:
  74 #  <id>:<runlevels>:<action>:<process>
  75 #
  76
  77 EOF
  78
  79                 for n in ${SYSVINIT_ENABLED_GETTYS}
  80                 do
  81                         echo "$n:2345:respawn:${base_sbindir}/getty 38400 tty$n" >> ${D}${sysconfdir}/inittab
  82                 done
  83                 echo "" >> ${D}${sysconfdir}/inittab
  84         fi
  85         install -m 0644    ${WORKDIR}/rcS-default       ${D}${sysconfdir}/default/rcS
  86         install -m 0755    ${WORKDIR}/rc                ${D}${sysconfdir}/init.d
  87         install -m 0755    ${WORKDIR}/rcS               ${D}${sysconfdir}/init.d
  88         install -m 0755    ${WORKDIR}/bootlogd.init     ${D}${sysconfdir}/init.d/bootlogd
  89         ln -sf bootlogd ${D}${sysconfdir}/init.d/stop-bootlogd
  90         install -d ${D}${sysconfdir}/rcS.d
  91         ln -sf ../init.d/bootlogd ${D}${sysconfdir}/rcS.d/S07bootlogd
  92         for level in 2 3 4 5; do
  93                 install -d ${D}${sysconfdir}/rc$level.d
  94                 ln -sf ../init.d/stop-bootlogd ${D}${sysconfdir}/rc$level.d/S99stop-bootlogd
  95         done
  96         mv                 ${D}${base_sbindir}/init               ${D}${base_sbindir}/init.${PN}
  97         mv ${D}${base_bindir}/pidof ${D}${base_bindir}/pidof.${PN}
  98         mv ${D}${base_sbindir}/halt ${D}${base_sbindir}/halt.${PN}
  99         mv ${D}${base_sbindir}/reboot ${D}${base_sbindir}/reboot.${PN}
 100         mv ${D}${base_sbindir}/shutdown ${D}${base_sbindir}/shutdown.${PN}
 101         mv ${D}${base_sbindir}/poweroff ${D}${base_sbindir}/poweroff.${PN}
 102         mv ${D}${bindir}/last ${D}${bindir}/last.${PN}
 103         mv ${D}${bindir}/mesg ${D}${bindir}/mesg.${PN}
 104         mv ${D}${bindir}/wall ${D}${bindir}/wall.${PN}
 105 }
 106
 107 do_install_append_opendreambox () {
 108         cat <<EOF >>${D}/etc/inittab
 109 # enigma
 110 gui:2:respawn:/usr/bin/enigma.sh
 111 # enigma2
 112 e2:3:respawn:/usr/bin/enigma2.sh
 113 EOF
 114 }
 115
 116 pkg_postinst_${PN} () {
 117 #!/bin/sh
 118 update-alternatives --install ${base_sbindir}/halt halt halt.${PN} 200
 119 update-alternatives --install ${base_sbindir}/reboot reboot reboot.${PN} 200
 120 update-alternatives --install ${base_sbindir}/shutdown shutdown shutdown.${PN} 200
 121 update-alternatives --install ${base_sbindir}/poweroff poweroff poweroff.${PN} 200
 122 update-alternatives --install ${bindir}/last last last.${PN} 200
 123 update-alternatives --install ${bindir}/mesg mesg mesg.${PN} 200
 124 update-alternatives --install ${bindir}/wall wall wall.${PN} 200
 125 }
 126
 127 pkg_prerm_${PN} () {
 128 #!/bin/sh
 129 update-alternatives --remove halt halt.${PN}
 130 update-alternatives --remove reboot reboot.${PN}
 131 update-alternatives --remove shutdown shutdown.${PN}
 132 update-alternatives --remove last last.${PN}
 133 update-alternatives --remove mesg mesg.${PN}
 134 update-alternatives --remove wall wall.${PN}
 135 }
 136
 137 pkg_postinst_sysvinit-pidof () {
 138 #!/bin/sh
 139 update-alternatives --install ${base_bindir}/pidof pidof pidof.${PN} 200
 140 }
 141
 142 pkg_prerm_sysvinit-pidof () {
 143 #!/bin/sh
 144 update-alternatives --remove pidof pidof.${PN}
 145 }