code.vuplus.com Git - vuplus_openembedded/blob - packages/ppp/ppp_2.4.3.bb

   1 SECTION = "console/network"
   2 DESCRIPTION = "Point-to-Point Protocol (PPP) daemon"
   3 HOMEPAGE = "http://samba.org/ppp/"
   4 DEPENDS = "libpcap"
   5 LICENSE = "BSD GPLv2"
   6 PR = "r4"
   7
   8 SRC_URI = "http://ppp.samba.org/ftp/ppp/ppp-${PV}.tar.gz \
   9         file://ppp-2.4.3-mppe-mppc-1.1.patch;patch=1 \
  10         file://makefile.patch;patch=1 \
  11         file://cifdefroute.patch;patch=1 \
  12         file://pppd-resolv-varrun.patch;patch=1 \
  13         file://plugins-fix-CC.patch;patch=1 \
  14         file://pppoatm-makefile.patch;patch=1 \
  15         file://enable-ipv6.patch;patch=1 \
  16         file://makefile-remove-hard-usr-reference.patch;patch=1 \
  17         file://pon \
  18         file://poff \
  19         file://init \
  20         file://ip-up \
  21         file://ip-down \
  22         file://08setupdns \
  23         file://92removedns"
  24
  25 SRC_URI_append_nylon = " file://ppp-tdbread.patch;patch=1"
  26
  27 inherit autotools
  28
  29 EXTRA_OEMAKE = "STRIPPROG=${STRIP} MANDIR=${D}${datadir}/man/man8 INCDIR=${D}/usr/include LIBDIR=${D}/usr/lib/pppd/${PV} BINDIR=${D}/usr/sbin"
  30 EXTRA_OECONF = "--disable-strip"
  31
  32 do_stage () {
  33          make INCDIR=${STAGING_INCDIR} install-devel
  34 }
  35
  36 do_install_append () {
  37         make install-etcppp ETCDIR=${D}/${sysconfdir}/ppp
  38         mkdir -p ${D}${bindir}/ ${D}${sysconfdir}/init.d
  39         mkdir -p ${D}${sysconfdir}/ppp/ip-up.d/
  40         mkdir -p ${D}${sysconfdir}/ppp/ip-down.d/
  41         install -m 0755 ${WORKDIR}/pon ${D}${bindir}/pon
  42         install -m 0755 ${WORKDIR}/poff ${D}${bindir}/poff
  43         install -m 0755 ${WORKDIR}/init ${D}${sysconfdir}/init.d/ppp
  44         install -m 0755 ${WORKDIR}/ip-up ${D}${sysconfdir}/ppp/
  45         install -m 0755 ${WORKDIR}/ip-down ${D}${sysconfdir}/ppp/
  46         install -m 0755 ${WORKDIR}/08setupdns ${D}${sysconfdir}/ppp/ip-up.d/
  47         install -m 0755 ${WORKDIR}/92removedns ${D}${sysconfdir}/ppp/ip-down.d/
  48         rm -rf ${D}/${mandir}/man8/man8
  49         if [ ${DISTRO} = "opendreambox" ]; then
  50                 for i in pap-secrets options; do
  51                         rm ${D}/etc/ppp/$i
  52                 done
  53         fi
  54 }
  55
  56 CONFFILES_${PN} = "${sysconfdir}/ppp/pap-secrets ${sysconfdir}/ppp/chap-secrets ${sysconfdir}/ppp/options"
  57 CONFFILES_${PN}_opendreambox = "${sysconfdir}/ppp/chap-secrets"
  58 PACKAGES += "ppp-oa ppp-oe ppp-radius ppp-winbind ppp-minconn ppp-password ppp-tools"
  59 FILES_${PN}        = "/etc /usr/bin /usr/sbin/chat /usr/sbin/pppd"
  60 FILES_${PN}_nylon  = "/etc /usr/bin /usr/sbin/chat /usr/sbin/pppd /usr/sbin/tdbread"
  61 FILES_${PN}-dbg += "${libdir}/pppd/2.4.3/.debug"
  62 FILES_ppp-oa       = "/usr/lib/pppd/2.4.3/pppoatm.so"
  63 FILES_ppp-oe       = "/usr/sbin/pppoe-discovery /usr/lib/pppd/2.4.3/rp-pppoe.so"
  64 FILES_ppp-radius   = "/usr/lib/pppd/2.4.3/radius.so /usr/lib/pppd/2.4.3/radattr.so /usr/lib/pppd/2.4.3/radrealms.so"
  65 FILES_ppp-winbind  = "/usr/lib/pppd/2.4.3/winbind.so"
  66 FILES_ppp-minconn  = "/usr/lib/pppd/2.4.3/minconn.so"
  67 FILES_ppp-password = "/usr/lib/pppd/2.4.3/pass*.so"
  68 FILES_ppp-tools    = "/usr/sbin/pppstats /usr/sbin/pppdump"
  69 DESCRIPTION_ppp-oa       = "Plugin for PPP needed for PPP-over-ATM"
  70 DESCRIPTION_ppp-oe       = "Plugin for PPP needed for PPP-over-Ethernet"
  71 DESCRIPTION_ppp-radius   = "Plugin for PPP that are related to RADIUS"
  72 DESCRIPTION_ppp-winbind  = "Plugin for PPP to authenticate against Samba or Windows"
  73 DESCRIPTION_ppp-minconn  = "Plugin for PPP to specify a minimum connect time before the idle timeout applies"
  74 DESCRIPTION_ppp-password = "Plugin for PPP to get passwords via a pipe"
  75 DESCRIPTION_ppp-tools    = "The pppdump and pppstats utitilities"
  76 RDEPENDS_ppp_minconn    += "libpcap0.8"
  77
  78 pkg_postinst_${PN}() {
  79 if test "x$D" != "x"; then
  80         exit 1
  81 else
  82         chmod u+s ${sbindir}/pppd
  83 fi
  84 }