code.vuplus.com Git - vuplus_openembedded/blob - packages/base-files/base-files_3.0.14.bb

   1 DESCRIPTION = "Miscellaneous files for the base system."
   2 SECTION = "base"
   3 PRIORITY = "required"
   4 PR = "r82"
   5 LICENSE = "GPL"
   6
   7 SRC_URI = " \
   8            file://nsswitch.conf \
   9            file://motd \
  10            file://inputrc \
  11            file://host.conf \
  12            file://profile \
  13            file://fstab \
  14            file://filesystems \
  15            file://issue.net \
  16            file://issue \
  17            file://usbd \
  18            file://share/dot.bashrc \
  19            file://share/dot.profile \
  20            file://licenses/BSD \
  21            file://licenses/GPL-2 \
  22            file://licenses/GPL-3 \
  23            file://licenses/LGPL-2 \
  24            file://licenses/LGPL-2.1 \
  25            file://licenses/LGPL-3 \
  26            file://licenses/GFDL-1.2 \
  27            file://licenses/Artistic "
  28 S = "${WORKDIR}"
  29
  30 docdir_append = "/${P}"
  31 dirs1777 = "/tmp ${localstatedir}/volatile/lock ${localstatedir}/volatile/tmp"
  32 dirs2775 = "/home ${prefix}/src ${localstatedir}/local"
  33 dirs755 = "/bin /boot /dev ${sysconfdir} ${sysconfdir}/default \
  34            ${sysconfdir}/skel /lib /mnt /proc /home/root /sbin \
  35            ${prefix} ${bindir} ${docdir} /usr/games ${includedir} \
  36            ${libdir} ${sbindir} ${datadir} \
  37            ${datadir}/common-licenses ${datadir}/dict ${infodir} \
  38            ${mandir} ${datadir}/misc ${localstatedir} \
  39            ${localstatedir}/backups ${localstatedir}/lib \
  40            /sys ${localstatedir}/lib/misc ${localstatedir}/spool \
  41            ${localstatedir}/volatile ${localstatedir}/volatile/cache \
  42            ${localstatedir}/volatile/lock/subsys \
  43            ${localstatedir}/volatile/log \
  44            ${localstatedir}/volatile/run \
  45            /mnt /media /media/card /media/cf /media/net /media/ram \
  46            /media/union /media/realroot /media/hdd \
  47            /media/mmc1"
  48 volatiles = "cache run log lock tmp"
  49 conffiles = "${sysconfdir}/debian_version ${sysconfdir}/host.conf \
  50              ${sysconfdir}/inputrc ${sysconfdir}/issue /${sysconfdir}/issue.net \
  51              ${sysconfdir}/nsswitch.conf ${sysconfdir}/profile \
  52              ${sysconfdir}/default"
  53
  54 #
  55 # set standard hostname, might be a candidate for a DISTRO variable? :M:
  56 #
  57 hostname = "openembedded"
  58 hostname_slugos = "nslu2"
  59 hostname_mnci = "MNCI"
  60 hostname_rt3000 = "MNRT"
  61 hostname_jlime = "JLime"
  62
  63 do_install () {
  64         for d in ${dirs755}; do
  65                 install -m 0755 -d ${D}$d
  66         done
  67         for d in ${dirs1777}; do
  68                 install -m 1777 -d ${D}$d
  69         done
  70         for d in ${dirs2775}; do
  71                 install -m 2755 -d ${D}$d
  72         done
  73         for d in ${volatiles}; do
  74                 ln -sf volatile/$d ${D}/${localstatedir}/$d
  75         done
  76         for d in card cf net ram; do
  77                 ln -sf /media/$d ${D}/mnt/$d
  78         done
  79
  80         if [ -n "${MACHINE}" -a "${hostname}" = "openembedded" ]; then
  81                 echo ${MACHINE} > ${D}${sysconfdir}/hostname
  82         else
  83                 echo ${hostname} > ${D}${sysconfdir}/hostname
  84         fi
  85
  86         install -m 644 ${WORKDIR}/issue*  ${D}${sysconfdir}
  87
  88         if [ -n "${DISTRO_NAME}" ]; then
  89                 echo -n "${DISTRO_NAME} " >> ${D}${sysconfdir}/issue
  90                 echo -n "${DISTRO_NAME} " >> ${D}${sysconfdir}/issue.net
  91                 if [ -n "${DISTRO_VERSION}" ]; then
  92                         echo -n "${DISTRO_VERSION} " >> ${D}${sysconfdir}/issue
  93                         echo -n "${DISTRO_VERSION} " >> ${D}${sysconfdir}/issue.net
  94                 fi
  95                 echo "\n \l" >> ${D}${sysconfdir}/issue
  96                 echo >> ${D}${sysconfdir}/issue
  97                 echo "%h"    >> ${D}${sysconfdir}/issue.net
  98                 echo >> ${D}${sysconfdir}/issue.net
  99         else
 100                install -m 0644 ${WORKDIR}/issue ${D}${sysconfdir}/issue
 101                install -m 0644 ${WORKDIR}/issue.net ${D}${sysconfdir}/issue.net
 102         fi
 103
 104         install -m 0644 ${WORKDIR}/fstab ${D}${sysconfdir}/fstab
 105         install -m 0644 ${WORKDIR}/filesystems ${D}${sysconfdir}/filesystems
 106         install -m 0644 ${WORKDIR}/usbd ${D}${sysconfdir}/default/usbd
 107         install -m 0644 ${WORKDIR}/profile ${D}${sysconfdir}/profile
 108         install -m 0755 ${WORKDIR}/share/dot.profile ${D}${sysconfdir}/skel/.profile
 109         install -m 0755 ${WORKDIR}/share/dot.bashrc ${D}${sysconfdir}/skel/.bashrc
 110         install -m 0644 ${WORKDIR}/inputrc ${D}${sysconfdir}/inputrc
 111         install -m 0644 ${WORKDIR}/nsswitch.conf ${D}${sysconfdir}/nsswitch.conf
 112         install -m 0644 ${WORKDIR}/host.conf ${D}${sysconfdir}/host.conf
 113         install -m 0644 ${WORKDIR}/motd ${D}${sysconfdir}/motd
 114
 115         for license in BSD GPL-2 LGPL-2 LGPL-2.1 Artistic GPL-3 LGPL-3 GFDL-1.2; do
 116                 install -m 0644 ${WORKDIR}/licenses/$license ${D}${datadir}/common-licenses/
 117         done
 118
 119         ln -sf /proc/mounts ${D}${sysconfdir}/mtab
 120 }
 121
 122
 123 do_install_append_mnci () {
 124         rmdir ${D}/tmp
 125         ln -s var/tmp ${D}/tmp
 126 }
 127
 128 do_install_append_nylon() {
 129         printf "" "" >${D}${sysconfdir}/resolv.conf
 130         rm -r ${D}/mnt/*
 131         rm -r ${D}/media
 132         rm -rf ${D}/tmp
 133         ln -sf /var/tmp ${D}/tmp
 134 }
 135
 136 do_install_append_slugos() {
 137         printf "" "" >${D}${sysconfdir}/resolv.conf
 138         rm -r ${D}/mnt/*
 139         rmdir ${D}/home/root
 140         install -m 0755 -d ${D}/root
 141         ln -s ../root ${D}/home/root
 142 }
 143
 144 do_install_append_netbook-pro () {
 145         mkdir -p ${D}/initrd
 146 }
 147
 148 do_install_append_opendreambox() {
 149         > ${D}/${sysconfdir}/resolv.conf
 150         rm -rf ${D}/mnt
 151         rm -rf ${D}/hdd
 152         ln -sf media/hdd ${D}/hdd
 153         ln -sf media ${D}/mnt
 154 }
 155
 156 PACKAGES = "${PN}-dbg ${PN}-doc ${PN}"
 157 FILES_${PN} = "/*"
 158 FILES_${PN}-doc = "${docdir} ${datadir}/common-licenses"
 159
 160 # M&N specific packaging
 161 PACKAGE_ARCH_mnci = "mnci"
 162 PACKAGE_ARCH_rt3000 = "rt3000"
 163
 164 PACKAGE_ARCH = "${MACHINE_ARCH}"
 165
 166 # Unslung distribution specific packaging
 167
 168 PACKAGES_unslung = "${PN}-unslung"
 169 PACKAGE_ARCH_${PN}-unslung = "nslu2"
 170 RDEPENDS_${PN}-unslung = "nslu2-linksys-ramdisk"
 171 RPROVIDES_${PN}-unslung = "${PN}"
 172
 173 FILES_${PN}-unslung = ""
 174
 175 CONFFILES_${PN} = "${sysconfdir}/fstab ${sysconfdir}/hostname"
 176 CONFFILES_${PN}_nylon = "${sysconfdir}/resolv.conf ${sysconfdir}/fstab ${sysconfdir}/hostname"
 177 CONFFILES_${PN}_slugos = "${sysconfdir}/resolv.conf ${sysconfdir}/fstab ${sysconfdir}/hostname"
 178