code.vuplus.com Git - vuplus_openembedded/blob - linux/linux-mtx-1_2.4.27.oe

   1 DESCRIPTION = "Linux kernel for MTX-1 (MeshCube)"
   2 MAINTAINER = "Bruno Randolf <bruno.randolf@4g-systems.biz>"
   3 LICENSE = "GPL"
   4 KV = "${PV}"
   5 PR = "r1"
   6 PACKAGE_ARCH = "mtx-1"
   7 RDEPENDS = "mtd"
   8
   9 SRC_URI = "cvs://cvs@ftp.linux-mips.org/home/cvs;module=linux;tag=linux_2_4_27 \
  10         file://01-mtd-2004-01-27.diff;patch=1 \
  11         file://02-mtd-mtx-1-map.diff;patch=1 \
  12         file://03-mtd-erase-compiler-bug.diff;patch=1 \
  13         file://04-mtx-1-board-reset.diff;patch=1 \
  14         file://05-mtx-1-pci-irq.diff;patch=1 \
  15         file://06-zboot-2.4.26.patch;patch=1 \
  16         file://07-zboot-zimage-flash-bin.diff;patch=1 \
  17         file://08-usb-nonpci-2.4.24.patch;patch=1 \
  18         file://09-au1000-eth-vlan.diff;patch=1 \
  19         file://10-iw-max-spy-32.diff;patch=1 \
  20         file://11-mtd-proc-partition-rw.diff;patch=1 \
  21         file://12-openswan-2.2.0-nat-t.diff;patch=1 \
  22         file://13-openswan-2.2.0.patch;patch=1 \
  23         file://14-au1000-eth-link-beat.diff;patch=1 \
  24         file://defconfig-mtx-1"
  25
  26 S = "${WORKDIR}/linux"
  27
  28 inherit kernel
  29
  30 ARCH = "mips"
  31 KERNEL_OUTPUT = "arch/mips/zboot/images/mtx-1.flash.bin"
  32 KERNEL_IMAGETYPE = "zImage.flash"
  33 KERNEL_IMAGEDEST = "tmp"
  34
  35 do_configure_prepend() {
  36         install -m 0644 ${WORKDIR}/defconfig-mtx-1 ${S}/.config
  37 }
  38
  39 pkg_postinst_kernel() {
  40 if test "x$D" != "x"; then
  41         exit 1
  42 else
  43         if test -e /tmp/zImage.flash-${KV}; then
  44                 echo "*** flashing kernel ***"
  45                 flashcp -v /tmp/zImage.flash-${KV} /dev/mtd/2
  46                 echo "*** done. please reboot ***"
  47         fi
  48 fi
  49 }
  50
  51 FILES_kernel += " /tmp"
  52
  53 do_deploy() {
  54         install -d ${DEPLOY_DIR}/images
  55         install -m 0644 arch/mips/zboot/images/mtx-1.flash.bin ${DEPLOY_DIR}/images/${MACHINE}-${KV}-${DATETIME}.flash.bin
  56         install -m 0644 arch/mips/zboot/images/mtx-1.flash.srec ${DEPLOY_DIR}/images/${MACHINE}-${KV}-${DATETIME}.flash.srec
  57         install -m 0644 arch/mips/zboot/images/mtx-1.srec ${DEPLOY_DIR}/images/${MACHINE}-${KV}-${DATETIME}.ram.srec
  58 }
  59
  60 do_deploy[dirs] = "${S}"
  61
  62 addtask deploy before do_build after do_compile