code.vuplus.com Git - vuplus_openembedded/blob - classes/rootfs_ipk.bbclass

   1 #
   2 # Creates a root filesystem out of IPKs
   3 #
   4 # This rootfs can be mounted via root-nfs or it can be put into an cramfs/jffs etc.
   5 # See image.bbclass for a usage of this.
   6 #
   7
   8 do_rootfs[depends] += "opkg-native:do_populate_staging"
   9
  10 IPKG_ARGS = "-f ${IPKGCONF_TARGET} -o ${IMAGE_ROOTFS} ${@base_conditional("PACKAGE_INSTALL_NO_DEPS", "1", "-nodeps", "", d)}"
  11
  12 PACKAGE_INSTALL_NO_DEPS ?= "0"
  13
  14 # What support to provide for online management of packages at run time?
  15 #  full -> traditional system, opkg is installed with all metadata
  16 #  add -> opkg is installed with basic conf files but no status database; can add new packages at runtime but not modify existing ones
  17 #  none -> opkg not installed at all, no metadata or config files provided
  18 ONLINE_PACKAGE_MANAGEMENT ?= "full"
  19
  20 # Which packages to not install on the basis of a recommendation
  21 BAD_RECOMMENDATIONS ?= ""
  22
  23 IPKG_VARIANT ?= "opkg"
  24
  25 RDEPENDS_append = " ${@base_conditional("ONLINE_PACKAGE_MANAGEMENT", "none", "", "${IPKG_VARIANT} opkg-collateral", d)}"
  26 PACKAGE_INSTALL_append = " ${@base_conditional("ONLINE_PACKAGE_MANAGEMENT", "none", "", "${IPKG_VARIANT} opkg-collateral", d)}"
  27
  28 fakeroot rootfs_ipk_do_rootfs () {
  29         set -x
  30
  31         package_generate_ipkg_conf
  32
  33         mkdir -p ${T}
  34         mkdir -p ${IMAGE_ROOTFS}${libdir}/opkg/
  35
  36         STATUS=${IMAGE_ROOTFS}${libdir}/opkg/status
  37         # prime the status file with bits that we don't want
  38         for i in ${BAD_RECOMMENDATIONS}; do
  39                 echo "Package: $i" >> $STATUS
  40                 echo "Architecture: ${TARGET_ARCH}" >> $STATUS
  41                 echo "Status: deinstall ok not-installed" >> $STATUS
  42                 echo >> $STATUS
  43         done
  44
  45         opkg-cl ${IPKG_ARGS} update
  46
  47         # Uclibc builds don't provide this stuff...
  48         if [ x${TARGET_OS} = "xlinux" ] || [ x${TARGET_OS} = "xlinux-gnueabi" ] ; then
  49                 if [ ! -z "${LINGUAS_INSTALL}" ]; then
  50                         opkg-cl ${IPKG_ARGS} install glibc-localedata-i18n
  51                         for i in ${LINGUAS_INSTALL}; do
  52                                 opkg-cl ${IPKG_ARGS} install $i
  53                         done
  54                 fi
  55         fi
  56         if [ ! -z "${PACKAGE_INSTALL}" ]; then
  57                 opkg-cl ${IPKG_ARGS} install ${PACKAGE_INSTALL}
  58         fi
  59
  60         export D=${IMAGE_ROOTFS}
  61         export OFFLINE_ROOT=${IMAGE_ROOTFS}
  62         export IPKG_OFFLINE_ROOT=${IMAGE_ROOTFS}
  63         export OPKG_OFFLINE_ROOT=${IPKG_OFFLINE_ROOT}
  64
  65         if [ "${ONLINE_PACKAGE_MANAGEMENT}" != "none" ]; then
  66                 mkdir -p ${IMAGE_ROOTFS}${sysconfdir}/opkg/
  67                 grep "^arch" ${IPKGCONF_TARGET} >${IMAGE_ROOTFS}${sysconfdir}/opkg/arch.conf
  68         fi
  69
  70         for i in ${IMAGE_ROOTFS}${libdir}/opkg/info/*.preinst; do
  71                 if [ -f $i ] && ! sh $i; then
  72                         opkg-cl ${IPKG_ARGS} flag unpacked `basename $i .preinst`
  73                 fi
  74         done
  75         for i in ${IMAGE_ROOTFS}${libdir}/opkg/info/*.postinst; do
  76                 if [ -f $i ] && ! sh $i configure; then
  77                         opkg-cl ${IPKG_ARGS} flag unpacked `basename $i .postinst`
  78                 fi
  79         done
  80
  81         install -d ${IMAGE_ROOTFS}/${sysconfdir}
  82         echo ${BUILDNAME} > ${IMAGE_ROOTFS}/${sysconfdir}/version
  83
  84         if [ "${ONLINE_PACKAGE_MANAGEMENT}" != "none" ]; then
  85                 if [ "${ONLINE_PACKAGE_MANAGEMENT}" == "add" ]; then
  86                         rm -f ${IMAGE_ROOTFS}${libdir}/opkg/status
  87                         rm -f ${IMAGE_ROOTFS}${libdir}/opkg/*/*
  88                 else
  89                         rm -f ${IMAGE_ROOTFS}${libdir}/opkg/lists/*
  90                 fi
  91
  92                 # Keep these lines until package manager selection is implemented
  93                 ln -s opkg ${IMAGE_ROOTFS}${sysconfdir}/ipkg
  94                 ln -s opkg ${IMAGE_ROOTFS}${libdir}/ipkg
  95         else
  96                 rm -rf ${IMAGE_ROOTFS}${libdir}/opkg
  97                 rm -rf ${IMAGE_ROOTFS}/usr/lib/opkg
  98         fi
  99
 100         ${ROOTFS_POSTPROCESS_COMMAND}
 101
 102         log_check rootfs
 103 }
 104
 105 rootfs_ipk_log_check() {
 106         target="$1"
 107         lf_path="$2"
 108
 109         lf_txt="`cat $lf_path`"
 110         for keyword_die in "Cannot find package" "Cannot satisfy the following dependencies" \
 111             "exit 1" ERR Fail
 112         do
 113                 if (echo "$lf_txt" | grep -v log_check | grep -w "$keyword_die") >/dev/null 2>&1
 114                 then
 115                         echo "log_check: There were error messages in the logfile"
 116                         printf "log_check: Matched keyword: [$keyword_die]\n"
 117                         echo "$lf_txt" | grep -v log_check | grep -i "$keyword_die" -C1
 118                         echo ""
 119                         do_exit=1
 120                 fi
 121         done
 122         test "$do_exit" = 1 && exit 1
 123         true
 124 }
 125
 126 remove_packaging_data_files() {
 127         rm -rf ${IMAGE_ROOTFS}${libdir}/opkg/
 128 }