code.vuplus.com Git - vuplus_openembedded/blob - classes/kernel.oeclass

   1 PROVIDES += "virtual/kernel"
   2 DEPENDS += "modutils-cross virtual/${TARGET_PREFIX}gcc${KERNEL_CCSUFFIX} update-modules"
   3
   4 export ARCH = "${TARGET_ARCH}"
   5 export OS = "${TARGET_OS}"
   6 export CROSS_COMPILE = "${TARGET_PREFIX}"
   7 KERNEL_IMAGETYPE = "zImage"
   8
   9 KERNEL_PRIORITY = "${@oe.data.getVar('PV',d,1).split('-')[0].split('.')[-1]}"
  10
  11 KERNEL_CCSUFFIX ?= ""
  12 KERNEL_LDSUFFIX ?= ""
  13
  14 KERNEL_CC = "${CCACHE}${HOST_PREFIX}gcc${KERNEL_CCSUFFIX}"
  15 KERNEL_LD = "${LD}${KERNEL_LDSUFFIX}"
  16
  17 KERNEL_OUTPUT = "arch/${ARCH}/boot/${KERNEL_IMAGETYPE}"
  18 KERNEL_IMAGEDEST = "boot"
  19
  20 #
  21 # configuration
  22 #
  23 export CMDLINE_CONSOLE = "console=${@oe.data.getVar("KERNEL_CONSOLE",d,1) or "ttyS0"}"
  24
  25 # parse kernel ABI version out of <linux/version.h>
  26 def get_kernelversion(p):
  27         import re
  28         try:
  29                 f = open(p, 'r')
  30         except IOError:
  31                 return None
  32         l = f.readlines()
  33         f.close()
  34         r = re.compile("#define UTS_RELEASE \"(.*)\"")
  35         for s in l:
  36                 m = r.match(s)
  37                 if m:
  38                         return m.group(1)
  39         return None
  40
  41 KERNEL_VERSION = "${@get_kernelversion('${S}/include/linux/version.h')}"
  42
  43 kernel_do_compile() {
  44         unset CFLAGS CPPFLAGS CXXFLAGS LDFLAGS
  45         oe_runmake include/linux/version.h CC="${KERNEL_CC}" LD="${KERNEL_LD}"
  46         oe_runmake dep CC="${KERNEL_CC}" LD="${KERNEL_LD}"
  47         oe_runmake ${KERNEL_IMAGETYPE} CC="${KERNEL_CC}" LD="${KERNEL_LD}"
  48         if (grep -q -i -e '^CONFIG_MODULES=y$' .config); then
  49                 oe_runmake modules  CC="${KERNEL_CC}" LD="${KERNEL_LD}"
  50         else
  51                 oenote "no modules to compile"
  52         fi
  53 }
  54
  55 kernel_do_stage() {
  56         install -d ${STAGING_KERNEL_DIR}/include/{asm,asm-generic,linux,net,pcmcia}
  57         cp -fR include/linux/* ${STAGING_KERNEL_DIR}/include/linux/
  58         cp -fR include/asm/* ${STAGING_KERNEL_DIR}/include/asm/
  59         cp -fR include/asm-generic/* ${STAGING_KERNEL_DIR}/include/asm-generic/
  60         cp -fR include/net/* ${STAGING_KERNEL_DIR}/include/net/
  61         cp -fR include/pcmcia/* ${STAGING_KERNEL_DIR}/include/pcmcia/
  62         install -m 0644 .config ${STAGING_KERNEL_DIR}/config-${PV}
  63         ln -sf config-${PV} ${STAGING_KERNEL_DIR}/.config
  64         ln -sf config-${PV} ${STAGING_KERNEL_DIR}/kernel-config
  65         echo "${KERNEL_VERSION}" >${STAGING_KERNEL_DIR}/kernel-abiversion
  66         echo "${S}" >${STAGING_KERNEL_DIR}/kernel-source
  67         echo "${KERNEL_CCSUFFIX}" >${STAGING_KERNEL_DIR}/kernel-ccsuffix
  68         echo "${KERNEL_LDSUFFIX}" >${STAGING_KERNEL_DIR}/kernel-ldsuffix
  69         [ -e Rules.make ] && install -m 0644 Rules.make ${STAGING_KERNEL_DIR}/
  70         [ -e Makefile ] && install -m 0644 Makefile ${STAGING_KERNEL_DIR}/
  71
  72         # Check if arch/${ARCH}/Makefile exists and install it
  73         if [ -e arch/${ARCH}/Makefile ]; then
  74                 install -d ${STAGING_KERNEL_DIR}/arch/${ARCH}
  75                 install -m 0644 arch/${ARCH}/Makefile ${STAGING_KERNEL_DIR}/arch/${ARCH}
  76         fi
  77         cp -fR scripts ${STAGING_KERNEL_DIR}/
  78         cp -fR include/config* ${STAGING_KERNEL_DIR}/include/
  79         install -m 0644 ${KERNEL_OUTPUT} ${STAGING_KERNEL_DIR}/${KERNEL_IMAGETYPE}
  80 }
  81
  82 kernel_do_install() {
  83         unset CFLAGS CPPFLAGS CXXFLAGS LDFLAGS
  84         if (grep -q -i -e '^CONFIG_MODULES=y$' .config); then
  85                 oe_runmake DEPMOD=echo INSTALL_MOD_PATH="${D}" modules_install
  86         else
  87                 oenote "no modules to install"
  88         fi
  89
  90         install -d ${D}/${KERNEL_IMAGEDEST}
  91         install -d ${D}/boot
  92         install -m 0644 ${KERNEL_OUTPUT} ${D}/${KERNEL_IMAGEDEST}/${KERNEL_IMAGETYPE}-${PV}
  93         install -m 0644 System.map ${D}/boot/System.map-${PV}
  94         install -m 0644 .config ${D}/boot/config-${PV}
  95         install -d ${D}/etc/modutils
  96 }
  97
  98 kernel_do_configure() {
  99         yes '' | oe_runmake oldconfig
 100 }
 101
 102 pkg_postinst_kernel () {
 103         update-alternatives --install /${KERNEL_IMAGEDEST}/zImage zImage /${KERNEL_IMAGEDEST}/zImage-${PV} ${KERNEL_PRIORITY} || true
 104 }
 105
 106 pkg_postrm_kernel () {
 107         update-alternatives --remove zImage /${KERNEL_IMAGEDEST}/zImage-${PV} || true
 108 }
 109
 110 inherit cml1
 111
 112 EXPORT_FUNCTIONS do_compile do_install do_stage do_configure
 113
 114 PACKAGES = "kernel"
 115 FILES = ""
 116 FILES_kernel = "/boot"
 117
 118 pkg_postinst_modules () {
 119 if [ -n "$D" ]; then
 120         ${HOST_PREFIX}depmod -A -b $D -F $D/boot/System.map-${PV} ${KERNEL_VERSION}
 121 else
 122         depmod -A
 123         update-modules || true
 124 fi
 125 }
 126
 127 pkg_postrm_modules () {
 128 update-modules || true
 129 }
 130
 131 autoload_postinst_fragment() {
 132 if [ x"$D" = "x" ]; then
 133         modprobe %s
 134 fi
 135 }
 136
 137 # defaults
 138 module_autoload_ipv6 = "ipv6"
 139 module_autoload_ipsec = "ipsec"
 140 module_conf_bluez = "alias net-pf-31 bluez"
 141 module_conf_l2cap = "alias bt-proto-0 l2cap"
 142 module_conf_sco = "alias bt-proto-2 sco"
 143 module_conf_rfcomm = "alias bt-proto-3 rfcomm"
 144 module_conf_bnep = "alias bt-proto-4 bnep"
 145 module_conf_hci_uart = "alias tty-ldisc-15 hci_uart"
 146
 147 python populate_packages_prepend () {
 148         def extract_modinfo(file):
 149                 import os, re
 150                 tmpfile = os.tmpnam()
 151                 cmd = "PATH=\"%s\" %sobjcopy -j .modinfo -O binary %s %s" % (oe.data.getVar("PATH", d, 1), oe.data.getVar("HOST_PREFIX", d, 1) or "", file, tmpfile)
 152                 os.system(cmd)
 153                 f = open(tmpfile)
 154                 l = f.read().split("\000")
 155                 f.close()
 156                 os.unlink(tmpfile)
 157                 exp = re.compile("([^=]+)=(.*)")
 158                 vals = {}
 159                 for i in l:
 160                         m = exp.match(i)
 161                         if not m:
 162                                 continue
 163                         vals[m.group(1)] = m.group(2)
 164                 return vals
 165
 166         def parse_depmod():
 167                 import os, re
 168
 169                 dvar = oe.data.getVar('D', d, 1)
 170                 if not dvar:
 171                         oe.error("D not defined")
 172                         return
 173
 174                 kernelver = oe.data.getVar('PV', d, 1)
 175                 kernelver_stripped = kernelver
 176                 m = re.match('^(.*-hh.*)\..*$', kernelver)
 177                 if m:
 178                         kernelver_stripped = m.group(1)
 179                 path = oe.data.getVar("PATH", d, 1)
 180                 host_prefix = oe.data.getVar("HOST_PREFIX", d, 1) or ""
 181
 182                 cmd = "PATH=\"%s\" %sdepmod -n -a -r -b %s -F %s/boot/System.map-%s %s" % (path, host_prefix, dvar, dvar, kernelver, kernelver_stripped)
 183                 f = os.popen(cmd, 'r')
 184
 185                 deps = {}
 186                 pattern0 = "^(.*\.o):..*$"
 187                 pattern1 = "^(.*\.o):\t(.*\.o)$"
 188                 pattern2 = "^(.*\.o):\t(.*\.o) \\\$"
 189                 pattern3 = "^\t(.*\.o) \\\$"
 190                 pattern4 = "^\t(.*\.o)$"
 191
 192                 line = f.readline()
 193                 while line:
 194                         if not re.match(pattern0, line):
 195                                 line = f.readline()
 196                                 continue
 197                         m1 = re.match(pattern1, line)
 198                         if m1:
 199                                 deps[m1.group(1)] = [m1.group(2)]
 200                         else:
 201                                 m2 = re.match(pattern2, line)
 202                                 if m2:
 203                                         deps[m2.group(1)] = [m2.group(2)]
 204                                         line = f.readline()
 205                                         m3 = re.match(pattern3, line)
 206                                         while m3:
 207                                                 deps[m2.group(1)].append(m3.group(1))
 208                                                 line = f.readline()
 209                                                 m3 = re.match(pattern3, line)
 210                                         m4 = re.match(pattern4, line)
 211                                         deps[m2.group(1)].append(m4.group(1))
 212                         line = f.readline()
 213                 f.close()
 214                 return deps
 215
 216         def get_dependencies(file, pattern, format):
 217                 file = file.replace(oe.data.getVar('D', d, 1) or '', '', 1)
 218
 219                 if module_deps.has_key(file):
 220                         import os.path, re
 221                         dependencies = []
 222                         for i in module_deps[file]:
 223                                 m = re.match(pattern, os.path.basename(i))
 224                                 if not m:
 225                                         continue
 226                                 on = legitimize_package_name(m.group(1))
 227                                 dependencies.append(format % on)
 228                         return dependencies
 229                 return []
 230
 231         def frob_metadata(file, pkg, pattern, format, basename):
 232                 import re
 233                 vals = extract_modinfo(file)
 234
 235                 dvar = oe.data.getVar('D', d, 1)
 236
 237                 # If autoloading is requested, output /etc/modutils/<name> and append
 238                 # appropriate modprobe commands to the postinst
 239                 autoload = oe.data.getVar('module_autoload_%s' % basename, d, 1)
 240                 if autoload:
 241                         name = '%s/etc/modutils/%s' % (dvar, basename)
 242                         f = open(name, 'w')
 243                         for m in autoload.split():
 244                                 f.write('%s\n' % m)
 245                         f.close()
 246                         postinst = oe.data.getVar('pkg_postinst_%s' % pkg, d, 1)
 247                         if not postinst:
 248                                 oe.fatal("pkg_postinst_%s not defined" % pkg)
 249                         postinst += oe.data.getVar('autoload_postinst_fragment', d, 1) % autoload
 250                         oe.data.setVar('pkg_postinst_%s' % pkg, postinst, d)
 251
 252                 # Write out any modconf fragment
 253                 modconf = oe.data.getVar('module_conf_%s' % basename, d, 1)
 254                 if modconf:
 255                         name = '%s/etc/modutils/%s.conf' % (dvar, basename)
 256                         f = open(name, 'w')
 257                         f.write("%s\n" % modconf)
 258                         f.close()
 259
 260                 files = oe.data.getVar('FILES_%s' % pkg, d, 1)
 261                 files = "%s /etc/modutils/%s /etc/modutils/%s.conf" % (files, basename, basename)
 262                 oe.data.setVar('FILES_%s' % pkg, files, d)
 263
 264                 if vals.has_key("description"):
 265                         old_desc = oe.data.getVar('DESCRIPTION_' + pkg, d, 1) or ""
 266                         oe.data.setVar('DESCRIPTION_' + pkg, old_desc + "; " + vals["description"], d)
 267
 268                 rdepends_str = oe.data.getVar('RDEPENDS_' + pkg, d, 1)
 269                 if rdepends_str:
 270                         rdepends = rdepends_str.split()
 271                 else:
 272                         rdepends = []
 273                 rdepends.extend(get_dependencies(file, pattern, format))
 274                 oe.data.setVar('RDEPENDS_' + pkg, ' '.join(rdepends), d)
 275
 276         module_deps = parse_depmod()
 277         module_regex = '^(.*)\.k?o$'
 278         module_pattern = 'kernel-module-%s'
 279
 280         postinst = oe.data.getVar('pkg_postinst_modules', d, 1)
 281         postrm = oe.data.getVar('pkg_postrm_modules', d, 1)
 282         do_split_packages(d, root='/lib/modules', file_regex=module_regex, output_pattern=module_pattern, description='%s kernel module', postinst=postinst, postrm=postrm, recursive=True, hook=frob_metadata, extra_depends='update-modules')
 283
 284         import re, os
 285         metapkg = "kernel-modules"
 286         oe.data.setVar('ALLOW_EMPTY_' + metapkg, "1", d)
 287         oe.data.setVar('FILES_' + metapkg, "", d)
 288         blacklist = []
 289         for l in module_deps.values():
 290                 for i in l:
 291                         pkg = module_pattern % legitimize_package_name(re.match(module_regex, os.path.basename(i)).group(1))
 292                         blacklist.append(pkg)
 293         metapkg_rdepends = []
 294         packages = oe.data.getVar('PACKAGES', d, 1).split()
 295         for pkg in packages[1:]:
 296                 if not pkg in blacklist and not pkg in metapkg_rdepends:
 297                         metapkg_rdepends.append(pkg)
 298         oe.data.setVar('RDEPENDS_' + metapkg, ' '.join(metapkg_rdepends), d)
 299         oe.data.setVar('DESCRIPTION_' + metapkg, 'Kernel modules meta package', d)
 300         packages.append(metapkg)
 301         oe.data.setVar('PACKAGES', ' '.join(packages), d)
 302 }