code.vuplus.com Git - vuplus_webkit/blob - Tools/WebKitTestRunner/qt/WebKitTestRunner.pro

   1 TARGET = WebKitTestRunner
   2 CONFIG -= app_bundle
   3
   4 BASEDIR = $$PWD/../
   5 isEmpty(OUTPUT_DIR): OUTPUT_DIR = ../../..
   6 GENERATED_SOURCES_DIR = ../generated
   7
   8
   9 include(../../../Source/WebKit.pri)
  10
  11 DEFINES += USE_SYSTEM_MALLOC=1
  12 DEFINES -= QT_ASCII_CAST_WARNINGS
  13
  14 INCLUDEPATH += \
  15     $$BASEDIR \
  16     $$BASEDIR/../../Source/JavaScriptCore \
  17     $$BASEDIR/../../Source/WebKit2 \
  18     $$BASEDIR/../../Source/WebKit2/Shared \
  19     $$BASEDIR/../../Source/WebKit2/UIProcess/API/qt \
  20     $$BASEDIR/../../Source/WebKit2/UIProcess/API/cpp/qt \
  21     $$GENERATED_SOURCES_DIR
  22
  23 INCLUDEPATH += \
  24     $$OUTPUT_DIR/include \
  25
  26
  27 DESTDIR = $$OUTPUT_DIR/bin
  28
  29 unix:!mac:!symbian:!embedded {
  30     CONFIG += link_pkgconfig
  31     PKGCONFIG += fontconfig
  32 }
  33
  34 QT = core gui network declarative
  35
  36 HEADERS = \
  37     $$BASEDIR/PlatformWebView.h \
  38     $$BASEDIR/StringFunctions.h \
  39     $$BASEDIR/TestController.h \
  40     $$BASEDIR/TestInvocation.h
  41
  42 SOURCES = \
  43     main.cpp \
  44     PlatformWebViewQt.cpp \
  45     TestControllerQt.cpp \
  46     TestInvocationQt.cpp \
  47     $$BASEDIR/TestController.cpp \
  48     $$BASEDIR/TestInvocation.cpp \
  49
  50 PREFIX_HEADER = $$BASEDIR/WebKitTestRunnerPrefix.h
  51 *-g++*:QMAKE_CXXFLAGS += "-include $$PREFIX_HEADER"
  52
  53 linux-* {
  54     # From Creator's src/rpath.pri:
  55     # Do the rpath by hand since it's not possible to use ORIGIN in QMAKE_RPATHDIR
  56     # this expands to $ORIGIN (after qmake and make), it does NOT read a qmake var.
  57     QMAKE_RPATHDIR = \$\$ORIGIN/../lib $$QMAKE_RPATHDIR
  58     MY_RPATH = $$join(QMAKE_RPATHDIR, ":")
  59
  60     QMAKE_LFLAGS += -Wl,-z,origin \'-Wl,-rpath,$${MY_RPATH}\' -Wl,--no-undefined
  61     QMAKE_RPATHDIR =
  62 } else {
  63     QMAKE_RPATHDIR = $$OUTPUT_DIR/lib $$QMAKE_RPATHDIR
  64 }
  65
  66 include(../../../Source/JavaScriptCore/JavaScriptCore.pri)
  67 prependJavaScriptCoreLib(../../JavaScriptCore)