code.vuplus.com Git - vuplus_webkit/blob - Tools/QtTestBrowser/QtTestBrowser.pro

   1 TEMPLATE = app
   2
   3 SOURCES += \
   4     locationedit.cpp \
   5     launcherwindow.cpp \
   6     main.cpp \
   7     mainwindow.cpp \
   8     urlloader.cpp \
   9     utils.cpp \
  10     webpage.cpp \
  11     webview.cpp \
  12     fpstimer.cpp \
  13     cookiejar.cpp
  14
  15 HEADERS += \
  16     locationedit.h \
  17     launcherwindow.h \
  18     mainwindow.h \
  19     urlloader.h \
  20     utils.h \
  21     webinspector.h \
  22     webpage.h \
  23     webview.h \
  24     fpstimer.h \
  25     cookiejar.h
  26
  27 !isEqual(QT_ARCH,sh4): CONFIG += uitools
  28
  29 isEmpty(OUTPUT_DIR): OUTPUT_DIR = ../..
  30 include(../../Source/WebKit.pri)
  31 INCLUDEPATH += ../../Source/WebKit/qt/WebCoreSupport
  32
  33 DESTDIR = $$OUTPUT_DIR/bin
  34 !CONFIG(standalone_package): CONFIG -= app_bundle
  35
  36 QT += network
  37 macx:QT+=xml
  38
  39 unix:!mac:!symbian:!embedded {
  40     CONFIG += link_pkgconfig
  41     PKGCONFIG += fontconfig
  42 }
  43
  44 linux-* {
  45     # From Creator's src/rpath.pri:
  46     # Do the rpath by hand since it's not possible to use ORIGIN in QMAKE_RPATHDIR
  47     # this expands to $ORIGIN (after qmake and make), it does NOT read a qmake var.
  48     QMAKE_RPATHDIR = \$\$ORIGIN/../lib $$QMAKE_RPATHDIR
  49     MY_RPATH = $$join(QMAKE_RPATHDIR, ":")
  50
  51     QMAKE_LFLAGS += -Wl,-z,origin \'-Wl,-rpath,$${MY_RPATH}\'
  52     QMAKE_RPATHDIR =
  53 } else {
  54     QMAKE_RPATHDIR = $$OUTPUT_DIR/lib $$QMAKE_RPATHDIR
  55 }
  56
  57 symbian {
  58     TARGET.UID3 = 0xA000E543
  59     TARGET.CAPABILITY = ReadUserData WriteUserData NetworkServices Location
  60     MMP_RULES *= pageddata
  61 }
  62
  63 contains(QT_CONFIG, opengl) {
  64     QT += opengl
  65     DEFINES += QT_CONFIGURED_WITH_OPENGL
  66 }
  67
  68 DEFINES -= QT_ASCII_CAST_WARNINGS
  69
  70 RESOURCES += \
  71     QtTestBrowser.qrc