code.vuplus.com Git - vuplus_webkit/blob - Tools/DumpRenderTree/qt/TestNetscapePlugin/TestNetscapePlugin.pro

   1 TEMPLATE = lib
   2 TARGET = TestNetscapePlugIn
   3
   4 VPATH = ../../unix/TestNetscapePlugin ../../TestNetscapePlugIn
   5 isEmpty(OUTPUT_DIR): OUTPUT_DIR = ../../../..
   6 include(../../../../Source/WebKit.pri)
   7
   8 DESTDIR = $$OUTPUT_DIR/lib/plugins
   9
  10 mac {
  11     CONFIG += plugin
  12     CONFIG += plugin_bundle
  13     QMAKE_INFO_PLIST = ../../TestNetscapePlugIn/mac/Info.plist
  14     QMAKE_PLUGIN_BUNDLE_NAME = $$TARGET
  15     QMAKE_BUNDLE_LOCATION += "Contents/MacOS"
  16
  17     !build_pass:CONFIG += build_all
  18     debug_and_release:TARGET = $$qtLibraryTarget($$TARGET)
  19 }
  20
  21 INCLUDEPATH += ../../../../Source/JavaScriptCore \
  22                ../../unix/TestNetscapePlugin/ForwardingHeaders \
  23                ../../unix/TestNetscapePlugin/ForwardingHeaders/WebKit \
  24                ../../../../Source/WebCore \
  25                ../../../../Source/WebCore/bridge \
  26                ../../TestNetscapePlugIn
  27
  28 SOURCES = PluginObject.cpp \
  29           PluginTest.cpp \
  30           TestObject.cpp \
  31           main.cpp \
  32           Tests/DocumentOpenInDestroyStream.cpp \
  33           Tests/EvaluateJSAfterRemovingPluginElement.cpp \
  34           Tests/FormValue.cpp \
  35           Tests/GetURLNotifyWithURLThatFailsToLoad.cpp \
  36           Tests/GetURLWithJavaScriptURL.cpp \
  37           Tests/GetURLWithJavaScriptURLDestroyingPlugin.cpp \
  38           Tests/GetUserAgentWithNullNPPFromNPPNew.cpp \
  39           Tests/NPDeallocateCalledBeforeNPShutdown.cpp \
  40           Tests/NPPSetWindowCalledDuringDestruction.cpp \
  41           Tests/NPRuntimeObjectFromDestroyedPlugin.cpp \
  42           Tests/NPRuntimeRemoveProperty.cpp \
  43           Tests/NullNPPGetValuePointer.cpp \
  44           Tests/PassDifferentNPPStruct.cpp \
  45           Tests/PluginScriptableNPObjectInvokeDefault.cpp \
  46           Tests/PrivateBrowsing.cpp
  47
  48 mac {
  49     OBJECTIVE_SOURCES += PluginObjectMac.mm
  50     LIBS += -framework Carbon -framework Cocoa -framework QuartzCore
  51 }
  52
  53 DEFINES -= QT_ASCII_CAST_WARNINGS
  54
  55 !win32:!embedded:!mac:!symbian {
  56     LIBS += -lX11
  57     DEFINES += XP_UNIX
  58 }