code.vuplus.com Git - vuplus_webkit/blob - Source/WebKit/mac/Misc/WebNSObjectExtras.mm

   1 /*
   2  * Copyright (C) 2008, 2009 Apple Inc. All rights reserved.
   3  *
   4  * Redistribution and use in source and binary forms, with or without
   5  * modification, are permitted provided that the following conditions
   6  * are met:
   7  *
   8  * 1.  Redistributions of source code must retain the above copyright
   9  *     notice, this list of conditions and the following disclaimer.
  10  * 2.  Redistributions in binary form must reproduce the above copyright
  11  *     notice, this list of conditions and the following disclaimer in the
  12  *     documentation and/or other materials provided with the distribution.
  13  * 3.  Neither the name of Apple Computer, Inc. ("Apple") nor the names of
  14  *     its contributors may be used to endorse or promote products derived
  15  *     from this software without specific prior written permission.
  16  *
  17  * THIS SOFTWARE IS PROVIDED BY APPLE AND ITS CONTRIBUTORS "AS IS" AND ANY
  18  * EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
  19  * WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE
  20  * DISCLAIMED. IN NO EVENT SHALL APPLE OR ITS CONTRIBUTORS BE LIABLE FOR ANY
  21  * DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
  22  * (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
  23  * LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND
  24  * ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  25  * (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
  26  * THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  27  */
  28
  29 #import "WebNSObjectExtras.h"
  30
  31 #import <wtf/Assertions.h>
  32
  33 @interface WebMainThreadInvoker : NSProxy
  34 {
  35     id target;
  36     id exception;
  37 }
  38 @end
  39
  40 static bool returnTypeIsObject(NSInvocation *invocation)
  41 {
  42     // Could use either _C_ID or NSObjCObjectType, but it seems that neither is
  43     // both available and non-deprecated on all versions of Mac OS X we support.
  44     return strchr([[invocation methodSignature] methodReturnType], '@');
  45 }
  46
  47 @implementation WebMainThreadInvoker
  48
  49 - (id)initWithTarget:(id)passedTarget
  50 {
  51     target = passedTarget;
  52     return self;
  53 }
  54
  55 - (void)forwardInvocation:(NSInvocation *)invocation
  56 {
  57     [invocation setTarget:target];
  58     [invocation performSelectorOnMainThread:@selector(_webkit_invokeAndHandleException:) withObject:self waitUntilDone:YES];
  59     if (exception) {
  60         id exceptionToThrow = [exception autorelease];
  61         exception = nil;
  62         @throw exceptionToThrow;
  63     } else if (returnTypeIsObject(invocation)) {
  64         // _webkit_invokeAndHandleException retained the return value on the main thread.
  65         // Now autorelease it on the calling thread.
  66         id returnValue;
  67         [invocation getReturnValue:&returnValue];
  68         [returnValue autorelease];
  69     }
  70 }
  71
  72 - (NSMethodSignature *)methodSignatureForSelector:(SEL)selector
  73 {
  74     return [target methodSignatureForSelector:selector];
  75 }
  76
  77 - (void)handleException:(id)passedException
  78 {
  79     ASSERT(!exception);
  80     exception = [passedException retain];
  81 }
  82
  83 @end
  84
  85 @implementation NSInvocation (WebMainThreadInvoker)
  86
  87 - (void)_webkit_invokeAndHandleException:(WebMainThreadInvoker *)exceptionHandler
  88 {
  89     @try {
  90         [self invoke];
  91     } @catch (id exception) {
  92         [exceptionHandler handleException:exception];
  93         return;
  94     }
  95     if (returnTypeIsObject(self)) {
  96         // Retain the return value on the main thread.
  97         // -[WebMainThreadInvoker forwardInvocation:] will autorelease it on the calling thread.
  98         id value;
  99         [self getReturnValue:&value];
 100         [value retain];
 101     }
 102 }
 103
 104 @end
 105
 106 @implementation NSObject (WebNSObjectExtras)
 107
 108 + (id)_webkit_invokeOnMainThread
 109 {
 110     return [[[WebMainThreadInvoker alloc] initWithTarget:self] autorelease];
 111 }
 112
 113 - (id)_webkit_invokeOnMainThread
 114 {
 115     return [[[WebMainThreadInvoker alloc] initWithTarget:self] autorelease];
 116 }
 117
 118 @end