code.vuplus.com Git - vuplus_webkit/blob - Source/ThirdParty/gtest/configure.ac

   1 m4_include(m4/acx_pthread.m4)
   2
   3 # At this point, the Xcode project assumes the version string will be three
   4 # integers separated by periods and surrounded by square brackets (e.g.
   5 # "[1.0.1]"). It also asumes that there won't be any closing parenthesis
   6 # between "AC_INIT(" and the closing ")" including comments and strings.
   7 AC_INIT([Google C++ Testing Framework],
   8         [1.5.0],
   9         [googletestframework@googlegroups.com],
  10         [gtest])
  11
  12 # Provide various options to initialize the Autoconf and configure processes.
  13 AC_PREREQ([2.59])
  14 AC_CONFIG_SRCDIR([./COPYING])
  15 AC_CONFIG_AUX_DIR([build-aux])
  16 AC_CONFIG_HEADERS([build-aux/config.h])
  17 AC_CONFIG_FILES([Makefile])
  18 AC_CONFIG_FILES([scripts/gtest-config], [chmod +x scripts/gtest-config])
  19
  20 # Initialize Automake with various options. We require at least v1.9, prevent
  21 # pedantic complaints about package files, and enable various distribution
  22 # targets.
  23 AM_INIT_AUTOMAKE([1.9 dist-bzip2 dist-zip foreign subdir-objects])
  24
  25 # Check for programs used in building Google Test.
  26 AC_PROG_CC
  27 AC_PROG_CXX
  28 AC_LANG([C++])
  29 AC_PROG_LIBTOOL
  30
  31 # TODO(chandlerc@google.com): Currently we aren't running the Python tests
  32 # against the interpreter detected by AM_PATH_PYTHON, and so we condition
  33 # HAVE_PYTHON by requiring "python" to be in the PATH, and that interpreter's
  34 # version to be >= 2.3. This will allow the scripts to use a "/usr/bin/env"
  35 # hashbang.
  36 PYTHON=  # We *do not* allow the user to specify a python interpreter
  37 AC_PATH_PROG([PYTHON],[python],[:])
  38 AS_IF([test "$PYTHON" != ":"],
  39       [AM_PYTHON_CHECK_VERSION([$PYTHON],[2.3],[:],[PYTHON=":"])])
  40 AM_CONDITIONAL([HAVE_PYTHON],[test "$PYTHON" != ":"])
  41
  42 # Configure pthreads.
  43 AC_ARG_WITH([pthreads],
  44             [AS_HELP_STRING([--with-pthreads],
  45                [use pthreads (default is yes)])],
  46             [with_pthreads=$withval],
  47             [with_pthreads=check])
  48
  49 have_pthreads=no
  50 AS_IF([test "x$with_pthreads" != "xno"],
  51       [ACX_PTHREAD(
  52         [],
  53         [AS_IF([test "x$with_pthreads" != "xcheck"],
  54                [AC_MSG_FAILURE(
  55                  [--with-pthreads was specified, but unable to be used])])])
  56        have_pthreads="$acx_pthread_ok"])
  57 AM_CONDITIONAL([HAVE_PTHREADS],[test "x$have_pthreads" == "xyes"])
  58 AC_SUBST(PTHREAD_CFLAGS)
  59 AC_SUBST(PTHREAD_LIBS)
  60
  61 # TODO(chandlerc@google.com) Check for the necessary system headers.
  62
  63 # TODO(chandlerc@google.com) Check the types, structures, and other compiler
  64 # and architecture characteristics.
  65
  66 # Output the generated files. No further autoconf macros may be used.
  67 AC_OUTPUT