code.vuplus.com Git - vuplus_webkit/blob - Source/JavaScriptCore/wtf/mac/MainThreadMac.mm

   1 /*
   2  * Copyright (C) 2007, 2008 Apple Inc. All rights reserved.
   3  *
   4  * Redistribution and use in source and binary forms, with or without
   5  * modification, are permitted provided that the following conditions
   6  * are met:
   7  *
   8  * 1.  Redistributions of source code must retain the above copyright
   9  *     notice, this list of conditions and the following disclaimer.
  10  * 2.  Redistributions in binary form must reproduce the above copyright
  11  *     notice, this list of conditions and the following disclaimer in the
  12  *     documentation and/or other materials provided with the distribution.
  13  * 3.  Neither the name of Apple Computer, Inc. ("Apple") nor the names of
  14  *     its contributors may be used to endorse or promote products derived
  15  *     from this software without specific prior written permission.
  16  *
  17  * THIS SOFTWARE IS PROVIDED BY APPLE AND ITS CONTRIBUTORS "AS IS" AND ANY
  18  * EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
  19  * WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE
  20  * DISCLAIMED. IN NO EVENT SHALL APPLE OR ITS CONTRIBUTORS BE LIABLE FOR ANY
  21  * DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
  22  * (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
  23  * LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND
  24  * ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  25  * (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
  26  * THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  27  */
  28
  29 #import "config.h"
  30 #import "MainThread.h"
  31
  32 #import <CoreFoundation/CoreFoundation.h>
  33 #import <Foundation/NSThread.h>
  34 #import <stdio.h>
  35 #import <wtf/Assertions.h>
  36 #import <wtf/Threading.h>
  37
  38 @interface WTFMainThreadCaller : NSObject {
  39 }
  40 - (void)call;
  41 @end
  42
  43 @implementation WTFMainThreadCaller
  44
  45 - (void)call
  46 {
  47     WTF::dispatchFunctionsFromMainThread();
  48 }
  49
  50 @end // implementation WTFMainThreadCaller
  51
  52 namespace WTF {
  53
  54 static WTFMainThreadCaller* staticMainThreadCaller;
  55 static bool isTimerPosted; // This is only accessed on the 'main' thread.
  56 static bool mainThreadEstablishedAsPthreadMain;
  57 static pthread_t mainThreadPthread;
  58 static NSThread* mainThreadNSThread;
  59
  60 void initializeMainThreadPlatform()
  61 {
  62     ASSERT(!staticMainThreadCaller);
  63     staticMainThreadCaller = [[WTFMainThreadCaller alloc] init];
  64
  65     mainThreadEstablishedAsPthreadMain = false;
  66     mainThreadPthread = pthread_self();
  67     mainThreadNSThread = [[NSThread currentThread] retain];
  68 }
  69
  70 void initializeMainThreadToProcessMainThreadPlatform()
  71 {
  72     if (!pthread_main_np())
  73         NSLog(@"WebKit Threading Violation - initial use of WebKit from a secondary thread.");
  74
  75     ASSERT(!staticMainThreadCaller);
  76     staticMainThreadCaller = [[WTFMainThreadCaller alloc] init];
  77
  78     mainThreadEstablishedAsPthreadMain = true;
  79     mainThreadPthread = 0;
  80     mainThreadNSThread = nil;
  81 }
  82
  83 static void timerFired(CFRunLoopTimerRef timer, void*)
  84 {
  85     CFRelease(timer);
  86     isTimerPosted = false;
  87     WTF::dispatchFunctionsFromMainThread();
  88 }
  89
  90 static void postTimer()
  91 {
  92     ASSERT(isMainThread());
  93
  94     if (isTimerPosted)
  95         return;
  96
  97     isTimerPosted = true;
  98     CFRunLoopAddTimer(CFRunLoopGetCurrent(), CFRunLoopTimerCreate(0, 0, 0, 0, 0, timerFired, 0), kCFRunLoopCommonModes);
  99 }
 100
 101 void scheduleDispatchFunctionsOnMainThread()
 102 {
 103     ASSERT(staticMainThreadCaller);
 104
 105     if (isMainThread()) {
 106         postTimer();
 107         return;
 108     }
 109
 110     if (mainThreadEstablishedAsPthreadMain) {
 111         ASSERT(!mainThreadNSThread);
 112         [staticMainThreadCaller performSelectorOnMainThread:@selector(call) withObject:nil waitUntilDone:NO];
 113         return;
 114     }
 115
 116     ASSERT(mainThreadNSThread);
 117     [staticMainThreadCaller performSelector:@selector(call) onThread:mainThreadNSThread withObject:nil waitUntilDone:NO];
 118 }
 119
 120 bool isMainThread()
 121 {
 122     if (mainThreadEstablishedAsPthreadMain) {
 123         ASSERT(!mainThreadPthread);
 124         return pthread_main_np();
 125     }
 126
 127     ASSERT(mainThreadPthread);
 128     return pthread_equal(pthread_self(), mainThreadPthread);
 129 }
 130
 131 } // namespace WTF