code.vuplus.com Git - vuplus_webkit/blob - Source/JavaScriptCore/JavaScriptCore.vcproj/JavaScriptCore/copy-files.cmd

   1 @echo off
   2
   3 set PublicHeadersDirectory=%CONFIGURATIONBUILDDIR%\include\JavaScriptCore
   4 set PrivateHeadersDirectory=%CONFIGURATIONBUILDDIR%\include\private\JavaScriptCore
   5 set ResourcesDirectory=%CONFIGURATIONBUILDDIR%\bin\JavaScriptCore.resources
   6
   7 if "%1" EQU "clean" goto :clean
   8 if "%1" EQU "rebuild" call :clean
   9
  10 echo Copying public headers...
  11 mkdir "%PublicHeadersDirectory%" 2>NUL
  12 for %%f in (
  13     APICast.h
  14     APIShims.h
  15     JSBase.h
  16     JSContextRef.h
  17     JSContextRefPrivate.h
  18     JSObjectRef.h
  19     JSObjectRefPrivate.h
  20     JSRetainPtr.h
  21     JSRetainPtr.h
  22     JSStringRef.h
  23     JSStringRefBSTR.h
  24     JSStringRefCF.h
  25     JSValueRef.h
  26     JSWeakObjectMapRefInternal.h
  27     JSWeakObjectMapRefPrivate.h
  28     JavaScript.h
  29     JavaScriptCore.h
  30     OpaqueJSString.h
  31     WebKitAvailability.h
  32 ) do (
  33     xcopy /y /d ..\..\API\%%f "%PublicHeadersDirectory%" >NUL
  34 )
  35
  36 echo Copying private headers...
  37 mkdir "%PrivateHeadersDirectory%" 2>NUL
  38 for %%d in (
  39     assembler
  40     bytecode
  41     dfg
  42     heap
  43     debugger
  44     interpreter
  45     jit
  46     parser
  47     profiler
  48     runtime
  49     wtf
  50     wtf\dtoa
  51     wtf\text
  52     wtf\threads
  53     wtf\unicode
  54     wtf\unicode\icu
  55     yarr
  56 ) do (
  57     xcopy /y /d ..\..\%%d\*.h "%PrivateHeadersDirectory%" >NUL
  58 )
  59
  60 echo Copying resources...
  61 mkdir "%ResourcesDirectory%" 2>NUL
  62 xcopy /y /d ..\JavaScriptCore.resources\* "%ResourcesDirectory%" >NUL
  63
  64 echo Copying other files...
  65 for %%f in (
  66     create_hash_table
  67     wtf\text\AtomicString.cpp
  68     wtf\text\StringBuilder.cpp
  69     wtf\text\StringImpl.cpp
  70     wtf\text\WTFString.cpp
  71 ) do (
  72     xcopy /y /d ..\..\%%f "%PrivateHeadersDirectory%" >NUL
  73 )
  74
  75 goto :EOF
  76
  77 :clean
  78
  79 echo Deleting copied files...
  80 if exist "%PublicHeadersDirectory%" rmdir /s /q "%PublicHeadersDirectory%" >NUL
  81 if exist "%PrivateHeadersDirectory%" rmdir /s /q "%PrivateHeadersDirectory%" >NUL
  82 if exist "%ResourcesDirectory%" rmdir /s /q "%ResourcesDirectory%" >NUL