code.vuplus.com Git - vuplus_openembedded/blob - recipes/udev/udev_124.bb

   1 DESCRIPTION = "udev is a daemon which dynamically creates and removes device nodes from \
   2 /dev/, handles hotplug events and loads drivers at boot time. It replaces \
   3 the hotplug package and requires a kernel not older than 2.6.12."
   4 RPROVIDES_${PN} = "hotplug"
   5 PR = "r19"
   6 PR_dm8000 = "r19"
   7
   8 SRC_URI = "http://kernel.org/pub/linux/utils/kernel/hotplug/udev-${PV}.tar.gz \
   9            file://noasmlinkage.patch;patch=1 \
  10            file://flags.patch;patch=1 \
  11            file://vol_id_ld.patch;patch=1 \
  12            file://udevtrigger_add_devname_filtering.patch;patch=1 \
  13            file://libvolume-id-soname.patch;patch=1 \
  14            file://mtd-exclude-persistent.patch;patch=1 \
  15            file://mount.blacklist \
  16            file://run.rules \
  17            file://default \
  18            file://local.rules \
  19            "
  20
  21 SRC_URI_append_bm750 = " file://50-udev-default.rules "
  22 SRC_URI_append_vusolo = " file://50-udev-default.rules "
  23 SRC_URI_append_h2200 = " file://50-hostap_cs.rules "
  24 PACKAGE_ARCH_h2200 = "h2200"
  25
  26 SRC_URI_append_opendreambox = " file://40-od-devfs-compatibility.rules \
  27            file://42-od-oled-compatibility.rules"
  28
  29 SRC_URI_append_dm8000 = " ${@base_contains('PREFERRED_VERSION_linux-dm8000', '2.6.18', 'file://41-od-linux-2.6.18-misc.rules', '', d)}"
  30 SRC_URI_append_dm800 = " ${@base_contains('PREFERRED_VERSION_linux-dm800', '2.6.18', 'file://41-od-linux-2.6.18-misc.rules', '', d)}"
  31 SRC_URI_append_dm800se = " ${@base_contains('PREFERRED_VERSION_linux-dm800se', '2.6.18', 'file://41-od-linux-2.6.18-misc.rules', '', d)}"
  32 SRC_URI_append_dm7020hd = " ${@base_contains('PREFERRED_VERSION_linux-dm7020hd', '2.6.18', 'file://41-od-linux-2.6.18-misc.rules', '', d)}"
  33 SRC_URI_append_dm500hd = " ${@base_contains('PREFERRED_VERSION_linux-dm500hd', '2.6.18', 'file://41-od-linux-2.6.18-misc.rules', '', d)}"
  34
  35 require udev.inc
  36
  37 INITSCRIPT_PARAMS = "start 03 S ."
  38
  39 FILES_${PN} += "${base_libdir}/udev/*"
  40 FILES_${PN}-dbg += "${base_libdir}/udev/.debug"
  41 UDEV_EXTRAS = "extras/firmware/ extras/scsi_id/ extras/volume_id/"
  42 EXTRA_OEMAKE += "libudevdir=/lib/udev libdir=${base_libdir} prefix="
  43
  44 do_install () {
  45         install -d ${D}${usrsbindir} \
  46                    ${D}${sbindir}
  47         oe_runmake 'DESTDIR=${D}' INSTALL=install install
  48         install -d ${D}${sysconfdir}/init.d
  49         install -m 0755 ${WORKDIR}/init ${D}${sysconfdir}/init.d/udev
  50
  51         install -d ${D}${sysconfdir}/default
  52         install -m 0755 ${WORKDIR}/default ${D}${sysconfdir}/default/udev
  53
  54         install -d ${D}${sysconfdir}/udev/rules.d/
  55
  56         install -m 0644 ${WORKDIR}/mount.blacklist     ${D}${sysconfdir}/udev/
  57         install -m 0644 ${WORKDIR}/local.rules         ${D}${sysconfdir}/udev/rules.d/local.rules
  58         install -m 0644 ${WORKDIR}/permissions.rules   ${D}${sysconfdir}/udev/rules.d/permissions.rules
  59         install -m 0644 ${WORKDIR}/run.rules          ${D}${sysconfdir}/udev/rules.d/run.rules
  60         install -m 0644 ${WORKDIR}/udev.rules          ${D}${sysconfdir}/udev/rules.d/udev.rules
  61         install -m 0644 ${WORKDIR}/links.conf          ${D}${sysconfdir}/udev/links.conf
  62         if [ "${UDEV_DEVFS_RULES}" = "1" ]; then
  63                 install -m 0644 ${WORKDIR}/devfs-udev.rules ${D}${sysconfdir}/udev/rules.d/devfs-udev.rules
  64         fi
  65
  66         touch ${D}${sysconfdir}/udev/saved.uname
  67         touch ${D}${sysconfdir}/udev/saved.cmdline
  68         touch ${D}${sysconfdir}/udev/saved.atags
  69
  70         install -d ${D}${sysconfdir}/udev/scripts/
  71
  72         install -m 0755 ${WORKDIR}/mount.sh ${D}${sysconfdir}/udev/scripts/mount.sh
  73         install -m 0755 ${WORKDIR}/network.sh ${D}${sysconfdir}/udev/scripts
  74
  75         install -d ${D}${base_libdir}/udev/
  76 }
  77
  78 do_install_append_h2200() {
  79         install -m 0644 ${WORKDIR}/50-hostap_cs.rules         ${D}${sysconfdir}/udev/rules.d/50-hostap_cs.rules
  80 }
  81
  82 do_install_append_opendreambox() {
  83         install -m 0644 ${WORKDIR}/??-od-*.rules ${D}${sysconfdir}/udev/rules.d/
  84 }
  85
  86 do_install_append_vuplus() {
  87         install -m 0644 ${WORKDIR}/50-udev-default.rules         ${D}${sysconfdir}/udev/rules.d/50-udev-default.rules
  88 }
  89