code.vuplus.com Git - vuplus_openembedded/blob - recipes/gstreamer/gst-plugins.inc

   1 require gst-common.inc
   2 DESCRIPTION = "Plugins for GStreamer"
   3 DEPENDS = "gstreamer libmikmod liboil libogg tremor libvorbis"
   4 DEPENDS += "${@base_conditional('ENTERPRISE_DISTRO', '1', '', 'libmad libid3tag', d)}"
   5 DEPENDS += "${@base_conditional('DISTRO', 'opendreambox', 'libmad libsoup-2.4 flac libmatroska libcdio libid3tag', '', d)}"
   6
   7 INC_PR = "r9"
   8
   9 PACKAGES_DYNAMIC = "gst-plugin-*"
  10
  11 SRC_URI = "http://gstreamer.freedesktop.org/src/${PN}/${PN}-${PV}.tar.bz2"
  12
  13 EXTRA_OECONF = "--enable-introspection=no --disable-aalib --disable-shout2 --disable-sdl --disable-cdaudio --x-includes=${STAGING_INCDIR} --x-libraries=${STAGING_LIBDIR} "
  14 EXTRA_OECONF_append_shr = " --disable-dvdnav "
  15 EXTRA_OECONF_opendreambox = "--disable-x --disable-aalib --disable-esd --disable-shout2 --disable-sdl --with-check=no --enable-neon "
  16
  17 acpaths = "-I ${S}/common/m4 -I ${S}/m4"
  18
  19 OE_LT_RPATH_ALLOW = "any"
  20 OE_LT_RPATH_ALLOW[export]="1"
  21
  22 LIBV = "0.10"
  23
  24 python populate_packages_prepend () {
  25         gst_libdir = bb.data.expand('${libdir}/gstreamer-${LIBV}', d)
  26         postinst = bb.data.getVar('plugin_postinst', d, 1)
  27         glibdir = bb.data.expand('${libdir}', d)
  28
  29         do_split_packages(d, glibdir, '^lib(.*)\.so\.*', 'lib%s', 'gstreamer %s library', extra_depends='', allow_links=True)
  30         do_split_packages(d, gst_libdir, '^libgst(.*)\.so$', 'gst-plugin-%s', 'GStreamer plugin for %s', postinst=postinst, extra_depends='')
  31         do_split_packages(d, gst_libdir, '^libgst(.*)\.l?a$', 'gst-plugin-%s-dev', 'GStreamer plugin for %s (development files)', extra_depends='')
  32
  33         pn = bb.data.getVar('PN', d, 1)
  34         metapkg =  pn + '-meta'
  35         bb.data.setVar('ALLOW_EMPTY_' + metapkg, "1", d)
  36         bb.data.setVar('FILES_' + metapkg, "", d)
  37         blacklist = [ pn + '-locale', pn + '-dev', pn + '-dbg', pn + '-doc' ]
  38         metapkg_rdepends = []
  39         packages = bb.data.getVar('PACKAGES', d, 1).split()
  40         for pkg in packages[1:]:
  41                 if not pkg in blacklist and not pkg in metapkg_rdepends and not pkg.endswith('-dev') and not pkg.count('locale') and not pkg.count('-static'):
  42                         metapkg_rdepends.append(pkg)
  43         bb.data.setVar('RDEPENDS_' + metapkg, ' '.join(metapkg_rdepends), d)
  44         bb.data.setVar('DESCRIPTION_' + metapkg, pn + ' meta package', d)
  45         packages.append(metapkg)
  46         bb.data.setVar('PACKAGES', ' '.join(packages), d)
  47
  48 }
  49
  50 ALLOW_EMPTY = "1"
  51
  52 PACKAGES += "${PN}-apps"
  53 FILES_${PN}-apps = "${bindir}"
  54
  55 FILES_${PN} = "${datadir}/gstreamer-0.10"
  56 FILES_${PN}-dbg += "${libdir}/gstreamer-${LIBV}/.debug"
  57
  58