code.vuplus.com Git - vuplus_openembedded/blob - packages/samba/samba_3.0.23c.bb

   1 require samba.inc
   2 inherit update-rc.d
   3
   4 PR = "r2"
   5
   6 SRC_URI += "file://config-lfs.patch;patch=1 \
   7            file://init \
   8            file://quota.patch;patch=1;pnum=0 \
   9            file://cifs.patch;patch=1 \
  10            "
  11
  12 INITSCRIPT_NAME = "samba"
  13 # No dependencies, goes in at level 20 (NOTE: take care with the
  14 # level, later levels put the shutdown later too - see the links
  15 # in rc6.d, the shutdown must precede network shutdown).
  16 INITSCRIPT_PARAMS = "defaults"
  17 CONFFILES_${PN} = "${sysconfdir}/samba/smb.conf"
  18
  19 # The file system settings --foodir=dirfoo and overridden unconditionally
  20 # in the samba config by --with-foodir=dirfoo - even if the --with is not
  21 # specified!  Fix that here.  Set the privatedir to /etc/samba/private.
  22 EXTRA_OECONF += "\
  23         samba_cv_struct_timespec=yes \
  24         --with-configdir=${sysconfdir}/samba \
  25         --with-privatedir=${sysconfdir}/samba/private \
  26         --with-lockdir=${localstatedir}/lock \
  27         --with-piddir=${localstatedir}/run \
  28         --with-logfilebase=${localstatedir}/log \
  29         --with-libdir=${libdir} \
  30         --with-mandir=${mandir} \
  31         --with-swatdir=${datadir}/swat \
  32         "
  33
  34 do_install_append() {
  35         install -d "${D}${localstatedir}/log"
  36         rm -f ${D}/sbin/mount.smbfs
  37         ln -sf smbmount ${D}${sbindir}/mount.smbfs
  38         install -d "${D}${sysconfdir}/init.d"
  39         install -c -m 755 ${WORKDIR}/init ${D}${sysconfdir}/init.d/samba
  40         install -d "${D}${sysconfdir}/samba"
  41         install -c -m 644 ../examples/smb.conf.default ${D}${sysconfdir}/samba/smb.conf
  42 }
  43
  44 PACKAGES =+ "swat"
  45
  46 FILES_swat = "${sbindir}/swat ${datadir}/swat ${libdir}/*.msg"
  47 FILES_${PN} += "${libdir}/vfs/*.so ${libdir}/charset/*.so ${libdir}/*.dat ${libdir}/auth/*.so"
  48 #
  49 # bug fix for samba.inc:
  50 FILES_cifs-doc += "${mandir}/man8/mount.cifs.8"