code.vuplus.com Git - vuplus_openembedded/blob - recipes/xscreensaver/xscreensaver_4.22.bb

   1 # xscreensaver OE build file
   2 # Copyright (C) 2004, Advanced Micro Devices, Inc.  All Rights Reserved
   3 # Released under the MIT license (see packages/COPYING)
   4
   5 DESCRIPTION = "*The* screensaver package for X11"
   6 HOMEPAGE = "http://www.jwz.org/xscreensaver/"
   7 SECTION = "x11-misc"
   8 LICENSE = "BSD"
   9 DEPENDS = "intltool virtual/libx11 gtk+ libxml2 libglade"
  10
  11 PR = "${INC_PR}.0"
  12
  13 SRC_URI = "http://www.jwz.org/xscreensaver/xscreensaver-${PV}.tar.gz \
  14            file://fixes.patch;patch=1 \
  15            file://configure.in.patch;patch=1 \
  16            file://configure.in-includedir.patch;patch=1 \
  17            file://XScreenSaver"
  18
  19 # xscreensaver-demo is a glade app
  20 LDFLAGS_append = " -Wl,--export-dynamic"
  21
  22 inherit autotools
  23
  24 export INTLTOOL_PERL="/usr/bin/env perl"
  25
  26 EXTRA_OECONF="--with-xml --with-gtk --disable-locking --without-pixbuf \
  27         --with-jpeg --with-xpm"
  28
  29 PACKAGES =+  " xscreensaver-demo xscreensaver-extra"
  30
  31 FILES_${PN}= "${bindir}/xscreensaver ${bindir}/xscreensaver-command \
  32         /usr/X11R6/lib/X11/app-defaults"
  33
  34 FILES_xscreensaver-demo="${bindir}/xscreensaver-demo ${datadir}/xscreensaver \
  35         ${datadir}/pixmaps/"
  36
  37 FILES_xscreensaver-extra="${bindir}/xscreensaver-getimage*"
  38
  39 do_configure_prepend() {
  40         sed -i 's:GTK_DATADIR="$GTK_DATADIR/share":GTK_DATADIR="${datadir}":' ${S}/configure.in
  41
  42         export includedir="/lib"
  43 }
  44
  45 do_compile() {
  46         oe_runmake GNOME_DATADIR=${datadir} all
  47 }
  48
  49 do_install() {
  50         unset KDEDIR
  51         oe_runmake -C ${S}/driver GNOME_DATADIR=${datadir} \
  52         install_prefix=${D} install
  53
  54         oe_runmake -C ${S}/hacks install_prefix=${D} install-program
  55
  56         # Install the defaults file
  57         install -d ${D}/usr/X11R6/lib/X11/app-defaults
  58         install -m 0644 ${WORKDIR}/XScreenSaver ${D}/usr/X11R6/lib/X11/app-defaults
  59 }
  60
  61 PACKAGES_DYNAMIC = "xscreensaver-hack-*"
  62
  63 python populate_packages_prepend () {
  64         hackdir = bb.data.expand('${libexecdir}/xscreensaver', d)
  65         do_split_packages(d, hackdir, '^(.*)', 'xscreensaver-hack-%s', 'XScreensaver hack %s')
  66 }