code.vuplus.com Git - vuplus_openembedded/blob - recipes/wpa-supplicant/wpa-supplicant-0.6.inc

   1 DESCRIPTION = "A Client for Wi-Fi Protected Access (WPA)."
   2 SECTION = "network"
   3 LICENSE = "GPL"
   4 HOMEPAGE = "http://hostap.epitest.fi/wpa_supplicant/"
   5 DEPENDS = "dbus gnutls ${@base_contains("COMBINED_FEATURES", "pci", "madwifi-ng", "",d)}"
   6
   7 #we introduce MY_ARCH to get 'armv5te' as arch instead of the misleading 'arm' on armv5te builds
   8 MY_ARCH := "${PACKAGE_ARCH}"
   9 PACKAGE_ARCH = "${@base_contains('COMBINED_FEATURES', 'pci', '${MACHINE_ARCH}', '${MY_ARCH}', d)}"
  10
  11 DEFAULT_PREFERENCE = "-2"
  12
  13 SRC_URI = "http://hostap.epitest.fi/releases/wpa_supplicant-${PV}.tar.gz \
  14         file://defconfig-0.6.0-gnutls \
  15         file://ifupdown.sh \
  16         file://functions.sh"
  17
  18 #       file://gnutlsfix.patch;patch=1 \
  19
  20 S = "${WORKDIR}/wpa_supplicant-${PV}/wpa_supplicant"
  21
  22 PACKAGES_prepend = "wpa-supplicant-passphrase "
  23 FILES_wpa-supplicant-passphrase = "/usr/sbin/wpa_passphrase"
  24
  25 RREPLACES = "wpa-supplicant-cli"
  26
  27 RRECOMMENDS_${PN} = "wpa-supplicant-passphrase"
  28
  29 export HAS_PCI = "${@base_contains('COMBINED_FEATURES', 'pci', 1, 0,d)}"
  30
  31 do_configure () {
  32         install -m 0755 ${WORKDIR}/defconfig-0.6.0-gnutls  .config
  33
  34         if [ "x$HAS_PCI" == "x1" ] ; then
  35                 echo "CONFIG_DRIVER_MADWIFI=y" >> .config
  36                 echo "CFLAGS += -I${STAGING_INCDIR}/madwifi-ng" >> .config
  37         fi
  38 }
  39
  40 do_compile () {
  41         make
  42 }
  43
  44 do_install () {
  45         install -d ${D}${sbindir}
  46         install -m 755 wpa_supplicant ${D}${sbindir}
  47         install -m 755 wpa_passphrase ${D}${sbindir}
  48         install -m 755 wpa_cli        ${D}${sbindir}
  49
  50         install -d ${D}${localstatedir}/run/wpa_supplicant
  51
  52         install -d ${D}${docdir}/wpa_supplicant
  53         install -m 644 README ${D}${docdir}/wpa_supplicant
  54
  55         install -d ${D}${sysconfdir}/network/if-pre-up.d/
  56         install -d ${D}${sysconfdir}/network/if-post-down.d/
  57         install -d ${D}${sysconfdir}/network/if-down.d/
  58
  59         install -d ${D}${sysconfdir}/wpa_supplicant
  60         install -m 755 ${WORKDIR}/ifupdown.sh ${D}${sysconfdir}/wpa_supplicant/
  61         install -m 755 ${WORKDIR}/functions.sh ${D}${sysconfdir}/wpa_supplicant
  62
  63         install -d ${D}/${sysconfdir}/dbus-1/system.d
  64         install -m 644 ${S}/dbus-wpa_supplicant.conf ${D}/${sysconfdir}/dbus-1/system.d
  65         install -d ${D}/${datadir}/dbus-1/system-services
  66         sed -i -e s:${base_sbindir}:${sbindir}:g ${S}/dbus-wpa_supplicant.service
  67         install -m 644 ${S}/dbus-wpa_supplicant.service ${D}/${datadir}/dbus-1/system-services/fi.epitest.hostap.WPASupplicant.service
  68
  69         ln -s /etc/wpa_supplicant/ifupdown.sh ${D}${sysconfdir}/network/if-pre-up.d/wpasupplicant
  70         ln -s /etc/wpa_supplicant/ifupdown.sh ${D}${sysconfdir}/network/if-post-down.d/wpasupplicant
  71 }
  72
  73 FILES_${PN} += "${datadir}/dbus-1/system-services/*"