code.vuplus.com Git - vuplus_openembedded/blob - recipes/wireless-tools/wireless-tools.inc

   1 DESCRIPTION = "Tools for the Linux Standard Wireless Extension Subsystem"
   2 HOMEPAGE = "http://www.hpl.hp.com/personal/Jean_Tourrilhes/Linux/Tools.html"
   3 SECTION = "base"
   4 PRIORITY = "optional"
   5 LICENSE = "GPL"
   6
   7 SRC_URI += "\
   8   http://www.hpl.hp.com/personal/Jean_Tourrilhes/Linux/wireless_tools.${PV}.tar.gz \
   9   file://man.patch;patch=1 \
  10   file://shared_lib_ldflags.patch;patch=1 \
  11   file://wireless-tools.if-pre-up \
  12   file://zzz-wireless.if-pre-up"
  13 S = "${WORKDIR}/wireless_tools.${PV}"
  14
  15 CFLAGS =+ "-I${S}"
  16
  17 EXTRA_OEMAKE = "-e 'BUILD_SHARED=y' \
  18                 'INSTALL_DIR=${D}${base_sbindir}' \
  19                 'INSTALL_LIB=${D}${libdir}' \
  20                 'INSTALL_INC=${D}${includedir}' \
  21                 'INSTALL_MAN=${D}${mandir}'"
  22
  23 do_compile() {
  24         oe_runmake all libiw.a
  25 }
  26
  27 do_stage() {
  28         install -m 0644 wireless.h ${STAGING_INCDIR}/
  29         install -m 0644 iwlib.h ${STAGING_INCDIR}/
  30         oe_libinstall -a -so libiw ${STAGING_LIBDIR}/
  31 }
  32
  33 do_install() {
  34     oe_runmake PREFIX=${D} install-iwmulticall install-dynamic install-man install-hdr
  35     install -d ${D}${sbindir}
  36     install -m 0755 ifrename ${D}${sbindir}/ifrename
  37     install -d ${D}${sysconfdir}/network/if-pre-up.d
  38     install ${WORKDIR}/wireless-tools.if-pre-up ${D}${sysconfdir}/network/if-pre-up.d/wireless-tools
  39     install ${WORKDIR}/zzz-wireless.if-pre-up ${D}${sysconfdir}/network/if-pre-up.d/zzz-wireless
  40 }
  41
  42 PACKAGES += "libiw libiw-dev libiw-doc libiw-dbg ifrename ifrename-dbg ifrename-doc"
  43 FILES_libiw += "${libdir}/*.so.*"
  44 FILES_libiw-dbg += "${libdir}/.debug/*.so.*"
  45 FILES_libiw-dev += "${libdir}/*.a ${libdir}/*.so ${includedir}"
  46 FILES_libiw-doc += "${mandir}/man7"
  47 FILES_ifrename += "${sbindir}/ifrename"
  48 FILES_ifrename-dbg += "${sbindir}/.debug/ifrename"
  49 FILES_ifrename-doc += "${mandir}/man8/ifrename.8 ${mandir}/man5/iftab.5"
  50 FILES_${PN} += "${bindir} ${sbindir}/iw* ${base_sbindir} ${base_bindir} ${sysconfdir}/network"
  51 FILES_${PN}-doc += "${mandir}/man8"