code.vuplus.com Git - vuplus_openembedded/blob - recipes/webkit/webkit-gtk_svn.bb

   1 DESCRIPTION = "WebKit browser engine, GTK+ edition"
   2 DEPENDS = "enchant gtk-doc-native gtk-doc gnome-keyring libsoup-2.4 curl icu libxml2 cairo libxslt libxt libidn gnutls gtk+ gstreamer gst-plugins-base gnome-vfs bison-native flex-native gperf-native perl-native sqlite3"
   3
   4 SRCREV_FORMAT = "webcore-rwebkit"
   5
   6 SRCREV = "53071"
   7 PV = "1.1.18+svnr${SRCPV}"
   8
   9 SRC_URI = "\
  10   svn://svn.webkit.org/repository/webkit/trunk/;module=JavaScriptCore;proto=http \
  11   svn://svn.webkit.org/repository/webkit/trunk/;module=JavaScriptGlue;proto=http \
  12   svn://svn.webkit.org/repository/webkit/trunk/;module=WebCore;proto=http;name=webcore \
  13   svn://svn.webkit.org/repository/webkit/trunk/;module=WebKit;proto=http;name=webkit \
  14   svn://svn.webkit.org/repository/webkit/trunk/;module=WebKitLibraries;proto=http \
  15   svn://svn.webkit.org/repository/webkit/trunk/;module=WebKitTools;proto=http \
  16   svn://svn.webkit.org/repository/webkit/trunk/;module=autotools;proto=http \
  17   file://Makefile \
  18   file://Makefile.shared \
  19   file://autogen.sh \
  20   file://configure.ac \
  21   file://GNUmakefile.am \
  22   file://gtk-doc.make \
  23  "
  24
  25 S = "${WORKDIR}/"
  26
  27 inherit autotools lib_package
  28
  29 export BISON="${STAGING_BINDIR_NATIVE}/bison"
  30 ARM_INSTRUCTION_SET = "arm"
  31 EXTRA_OECONF = "\
  32                 --enable-debug=no \
  33                 --enable-svg \
  34                 --enable-icon-database=yes \
  35 #                --with-unicode-backend=glib \
  36 "
  37
  38 EXTRA_AUTORECONF = " -I autotools "
  39
  40 # Dolt gets used on x86 and ppc and hardcodes 'libtool'
  41 do_configure_append() {
  42         cp ${TARGET_PREFIX}libtool libtool || true
  43 }
  44
  45 do_compile_prepend() {
  46         mkdir -p ${S}/WebKitBuilds/Debug/JavaScriptCore/pcre/tmp/
  47         mkdir -p ${S}/Programs/
  48         cd ${S}/JavaScriptCore/pcre
  49         if test -e dftables.c
  50         then
  51             ${BUILD_CC} dftables.c -o dftables -I. -I../wtf
  52         elif test -e dftables.cpp
  53         then
  54             ${BUILD_CXX} dftables.cpp -o dftables -I. -I../wtf
  55         fi
  56         cp dftables ${S}/WebKitBuilds/Debug/JavaScriptCore/pcre/tmp/
  57         cp dftables ${S}/Programs/
  58         cd ${S}
  59 }
  60
  61 PACKAGES =+ "${PN}-webinspector ${PN}launcher-dbg ${PN}launcher libjavascriptcore"
  62 FILES_${PN}launcher = "${bindir}/GtkLauncher"
  63 FILES_${PN}launcher-dbg = "${bindir}/.debug/GtkLauncher"
  64 FILES_libjavascriptcore = "${libdir}/libJavaScriptCore.so.*"
  65 FILES_${PN}-webinspector = "${datadir}/webkit-1.0/webinspector/"
  66 FILES_${PN} += "${datadir}/webkit-1.0/resources/error.html ${datadir}/webkit-1.0/images"
  67