code.vuplus.com Git - vuplus_openembedded/blob - recipes/uclibc++/uclibc++_0.1.9.bb

   1 DESCRIPTION = "A C++ standard library targeted towards the embedded \
   2 systems/software market."
   3 HOMEPAGE = "http://cxx.uclibc.org/"
   4 LICENSE = "LGPL"
   5 PRIORITY = "optional"
   6 SECTION = "libs"
   7
   8 PR = "r1"
   9
  10 SRC_URI = "http://cxx.uclibc.org/src/uClibc++-${PV}.tbz2 \
  11            file://nobash.patch;patch=1 \
  12            file://defconfig"
  13 S = "${WORKDIR}/uClibc++"
  14
  15 # uClibc++ runtime prefix directory (UCLIBCXX_RUNTIME_PREFIX) [/usr/$(TARGET_ARCH)-linux-uclibc] (NEW)
  16 # uClibc++ header file subdirectory (UCLIBCXX_RUNTIME_INCLUDE_SUBDIR) [/include] (NEW)
  17 # uClibc++ library subdirectory (UCLIBCXX_RUNTIME_LIB_SUBDIR) [/lib] (NEW)
  18 # uClibc++ application file subdirectory (UCLIBCXX_RUNTIME_BIN_SUBDIR) [/bin] (NEW)
  19
  20 do_unpack_real () {
  21         bzcat uClibc++-${PV}.tbz2 | tar -xvf -
  22 }
  23 do_unpack_real[dirs] = "${WORKDIR}"
  24 addtask unpack_real before do_patch after do_unpack
  25
  26 EXTRA_OEMAKE = "'OPTIMIZATION=' 'XWARNINGS=' 'XARCH_CFLAGS=${CFLAGS}' \
  27                 'CPU_FLAGS=' 'STRIPTOOL=true' 'LD=${LD}'"
  28 configmangle = 's,^UCLIBCXX_RUNTIME_PREFIX=.*,UCLIBCXX_RUNTIME_PREFIX="${exec_prefix}",; \
  29                 s,^UCLIBCXX_RUNTIME_INCLUDE_SUBDIR=.*,UCLIBCXX_RUNTIME_INCLUDE_SUBDIR="/include/c++-uc",; \
  30                 s,^UCLIBCXX_RUNTIME_LIB_SUBDIR=.*,UCLIBCXX_RUNTIME_LIB_SUBDIR="/lib",; \
  31                 s,^UCLIBCXX_RUNTIME_BIN_SUBDIR=.*,UCLIBCXX_RUNTIME_BIN_SUBDIR="/bin",;'
  32 PARALLEL_MAKE = ""
  33
  34 do_configure () {
  35         cp ${WORKDIR}/defconfig ${S}/.config
  36
  37         perl -i -p -e 's,^CROSS=.*,TARGET_ARCH=${TARGET_ARCH}\nCROSS=${TARGET_PREFIX},g' ${S}/Rules.mak
  38         perl -i -p -e '${configmangle}' ${S}/.config
  39
  40         oe_runmake oldconfig
  41 }
  42
  43 do_stage () {
  44         oe_runmake 'UCLIBCXX_RUNTIME_PREFIX=${STAGING_LIBDIR}/../' \
  45                    install
  46         chmod +x ${STAGING_LIBDIR}/libuClibc++.so.*
  47 }
  48
  49 do_install () {
  50         oe_runmake 'DESTDIR=${D}' install
  51         chmod +x ${D}${libdir}/libuClibc++.so.*
  52 }
  53
  54 PACKAGES = "g++-uc libuclibc++ libuclibc++-dev"
  55 FILES_g++-uc = "${bindir}/g++-uc"
  56 FILES_libuclibc++ = "${libdir}/*.so.*"
  57 FILES_libuclibc++-dev = "${FILES_uclibc++-dev}"