code.vuplus.com Git - vuplus_openembedded/blob - recipes/ti/ti-linuxutils.inc

   1 DESCRIPTION = "MFP Linux utils for TI ARM/DSP processors"
   2
   3 BASE_SRC_URI = "http://software-dl.ti.com/dsps/dsps_public_sw/sdo_sb/targetcontent/linuxutils/${PV}/exports"
   4 SRC_URI = "${BASE_SRC_URI}/linuxutils_${PV}.tar.gz "
   5
   6 S = "${WORKDIR}/linuxutils_${PV}"
   7
   8 require ti-multimedia-common.inc
   9
  10 #This is a kernel module, don't set PR directly
  11 MACHINE_KERNEL_PR_append = "a"
  12
  13 inherit module
  14
  15 do_compile() {
  16     unset CFLAGS CPPFLAGS CXXFLAGS LDFLAGS
  17
  18     case ${SOC_FAMILY} in
  19     dm365)
  20             modules="cmem edma";;
  21     omap3)
  22             modules="cmem sdma";;
  23     *)
  24             modules="cmem"
  25     esac
  26
  27     for module in $modules ; do
  28     cd ${S}/packages/ti/sdo/linuxutils/$module
  29     make \
  30       LINUXKERNEL_INSTALL_DIR="${STAGING_KERNEL_DIR}" \
  31       MVTOOL_PREFIX="${TARGET_PREFIX}" \
  32       UCTOOL_PREFIX="${TARGET_PREFIX}" \
  33       clean debug release
  34     done
  35 }
  36
  37 do_install () {
  38     install -d ${D}/lib/modules/${KERNEL_VERSION}/kernel/drivers/dsp
  39     # Install CMEM
  40     for module in $(find ${S}/packages/ti/sdo/linuxutils/ -name "*.ko") ; do
  41         install -m 0755 $module ${D}/lib/modules/${KERNEL_VERSION}/kernel/drivers/dsp
  42     done
  43     cd ${S}/packages/ti/sdo/linuxutils/cmem/apps
  44     make \
  45       LINUXKERNEL_INSTALL_DIR="${STAGING_KERNEL_DIR}" \
  46       MVTOOL_PREFIX="${TARGET_PREFIX}" \
  47       UCTOOL_PREFIX="${TARGET_PREFIX}" \
  48       EXEC_DIR="${D}${installdir}/ti-linuxutils-app/cmem-app" \
  49       install
  50     # Install EDMA
  51     if [ ${SOC_FAMILY} == "dm365" ] ; then
  52         cd ${S}/packages/ti/sdo/linuxutils/edma/apps
  53         make \
  54          LINUXKERNEL_INSTALL_DIR="${STAGING_KERNEL_DIR}" \
  55          MVTOOL_PREFIX="${TARGET_PREFIX}" \
  56          UCTOOL_PREFIX="${TARGET_PREFIX}" \
  57          EXEC_DIR="${D}${installdir}/ti-linuxutils-app/edma-app" \
  58          install
  59     fi
  60 }
  61
  62 # stage tree - other packages may need this
  63 do_stage() {
  64     install -d ${STAGING_DIR}/${MULTIMACH_TARGET_SYS}/${PN}
  65     cp -pPrf ${S}/* ${STAGING_DIR}/${MULTIMACH_TARGET_SYS}/${PN}/
  66 }
  67
  68 PACKAGES =+ " ti-cmem-module \
  69               ti-sdma-module \
  70               ti-edma-module \
  71               ti-irq-module \
  72               ti-linuxutils-app"
  73
  74 FILES_ti-cmem-module = "/lib/modules/${KERNEL_VERSION}/kernel/drivers/dsp/cmem*.ko"
  75 FILES_ti-sdma-module = "/lib/modules/${KERNEL_VERSION}/kernel/drivers/dsp/sdma*.ko"
  76 FILES_ti-edma-module = "/lib/modules/${KERNEL_VERSION}/kernel/drivers/dsp/edma*.ko"
  77 FILES_ti-irq-module = "/lib/modules/${KERNEL_VERSION}/kernel/drivers/dsp/irq*.ko"
  78
  79 FILES_ti-linuxutils-app = "${installdir}/ti-linuxutils-app/*/*"
  80
  81 INSANE_SKIP_ti-linuxutils-app = "True"
  82 INHIBIT_PACKAGE_STRIP = "1"