code.vuplus.com Git - vuplus_openembedded/blob - recipes/rp-pppoe/rp-pppoe_3.8.bb

   1 DESCRIPTION = "A user-mode PPPoE client and server suite for Linux"
   2 HOMEPAGE = "http://www.roaringpenguin.com/en/penguin/openSourceProducts/rpPppoe"
   3 SECTION = "console/network"
   4 LICENSE = "GPLv2"
   5 RDEPENDS_${PN} = "ppp"
   6 RDEPENDS_${PN}-server = "${PN}"
   7 RRECOMMENDS_${PN} = "ppp-oe"
   8 PR = "r6"
   9
  10 SRC_URI = "http://www.roaringpenguin.com/files/download/${P}.tar.gz \
  11            file://top-autoconf.patch;patch=1 \
  12            file://configure_in_cross.patch;patch=1 \
  13            file://pppoe-src-restrictions.patch;patch=1 \
  14            file://update-config.patch;patch=1 \
  15            file://dont-swallow-errors.patch;patch=1 \
  16            file://pppoe-server.default \
  17            file://pppoe-server.init"
  18
  19 inherit autotools update-rc.d
  20
  21 do_install() {
  22         # Install init script and default settings
  23         install -m 0755 -d ${D}${sysconfdir}/default ${D}${sysconfdir}/init.d
  24         install -m 0644 ${WORKDIR}/pppoe-server.default ${D}${sysconfdir}/default/pppoe-server
  25         install -m 0755 ${WORKDIR}/pppoe-server.init ${D}${sysconfdir}/init.d/pppoe-server
  26         # Install
  27         oe_runmake -C ${S} RPM_INSTALL_ROOT=${D} docdir=${docdir} install
  28 }
  29
  30 # Insert server package before main package
  31 PACKAGES = "${PN}-dbg ${PN}-server ${PN}-relay ${PN}-sniff ${PN} ${PN}-doc"
  32
  33 FILES_${PN}-server = "${sysconfdir}/default/pppoe-server \
  34                       ${sysconfdir}/init.d/pppoe-server \
  35                       ${sbindir}/pppoe-server \
  36                       ${sysconfdir}/ppp/pppoe-server-options"
  37 FILES_${PN}-relay = "${sbindir}/pppoe-relay"
  38 FILES_${PN}-sniff = "${sbindir}/pppoe-sniff"
  39
  40 pkg_postinst_${PN} () {
  41     if [ x"$D" != "x" ]; then
  42         exit 1
  43     fi
  44     chmod 4755 ${sbindir}/pppoe
  45 }
  46
  47 CONFFILES_${PN} = "${sysconfdir}/ppp/pppoe.conf \
  48                    ${sysconfdir}/ppp/firewall-standalone \
  49                    ${sysconfdir}/ppp/firewall-masq"
  50 CONFFILES_${PN}-server = "${sysconfdir}/ppp/pppoe-server-options \
  51                           ${sysconfdir}/default/pppoe-server"
  52
  53 INITSCRIPT_PACKAGES            = "${PN}-server"
  54 INITSCRIPT_NAME_${PN}-server   = "pppoe-server"
  55 INITSCRIPT_PARAMS_${PN}-server = "defaults 92 8"
  56