code.vuplus.com Git - vuplus_openembedded/blob - recipes/qt4/qt4-tools-native.inc

   1 DESCRIPTION = "Native tools for Qt/[X11|Mac|Embedded] version 4.x"
   2 DEPENDS = "zlib-native"
   3 SECTION = "libs"
   4 HOMEPAGE = "http://www.trolltech.com"
   5 PRIORITY = "optional"
   6 LICENSE = "GPL"
   7
   8 inherit native
   9
  10 SRC_URI = "ftp://ftp.trolltech.com/qt/source/qt-embedded-linux-opensource-src-${PV}.tar.bz2 \
  11            file://configure-lflags.patch;patch=1 \
  12            file://qt-config.patch;patch=1 \
  13            file://g++.conf \
  14            file://linux.conf"
  15 S = "${WORKDIR}/qt-embedded-linux-opensource-src-${PV}"
  16
  17 EXTRA_OECONF = "-prefix ${prefix} \
  18                 -qt-libjpeg -qt-gif -system-zlib \
  19                 -no-libjpeg -no-libpng \
  20                 -no-accessibility \
  21                 -no-cups \
  22                 -no-exceptions  \
  23                 -no-nas-sound \
  24                 -no-nis \
  25                 -verbose -release  -fast -static \
  26                 -qt3support "
  27
  28 # yank default -e, otherwise we get the following error:
  29 # moc_qbuffer.cpp: No such file or directory
  30 EXTRA_OEMAKE = " "
  31
  32 do_configure() {
  33     echo yes | LFLAGS="-L${STAGING_LIBDIR_NATIVE}" ./configure ${EXTRA_OECONF} || die "Configuring qt failed. EXTRA_OECONF was ${EXTRA_OECONF}"
  34 }
  35
  36 TOBUILD = "\
  37   src/tools/moc \
  38   src/corelib \
  39   src/sql \
  40   src/qt3support \
  41   src/xml \
  42   src/tools/uic \
  43   src/tools/rcc \
  44   src/network \
  45   src/gui \
  46   src/tools/uic3 \
  47   tools/linguist/lrelease \
  48   tools/linguist/lupdate \
  49 "
  50
  51 do_compile() {
  52     for i in ${TOBUILD}; do
  53         cd ${S}/$i && oe_runmake CC="${CC}" CXX="${CXX}"
  54     done
  55 }
  56
  57 do_stage() {
  58         install -d ${STAGING_BINDIR_NATIVE}/
  59     install -m 0755 bin/qmake ${STAGING_BINDIR_NATIVE}/qmake2
  60     for i in moc uic uic3 rcc lrelease lupdate; do
  61         install -m 0755 bin/${i} ${STAGING_BINDIR_NATIVE}/${i}4
  62     done
  63
  64     install -d ${STAGING_DATADIR_NATIVE}/qt4/
  65     cp -PfR mkspecs ${STAGING_DATADIR_NATIVE}/qt4/
  66     ln -sf linux-g++ ${STAGING_DATADIR_NATIVE}/qt4/mkspecs/${BUILD_OS}-oe-g++
  67     cp -f ${WORKDIR}/g++.conf ${WORKDIR}/linux.conf ${STAGING_DATADIR_NATIVE}/qt4/mkspecs/common/
  68
  69     install -m 0644 tools/porting/src/q3porting.xml ${STAGING_DATADIR_NATIVE}/qt4/
  70 }
  71