code.vuplus.com Git - vuplus_openembedded/blob - recipes/qi/qi.inc

   1 DESCRIPTION = "Qi bootloader w/ Openmoko GTA01, GTA02, and GTA03 support"
   2 LICENSE = "GPL"
   3 SECTION = "bootloader"
   4 PROVIDES = "virtual/bootloader"
   5 PV = "1.0.2"
   6
   7 EXTRA_OEMAKE = ""
   8 PARALLEL_MAKE = ""
   9
  10 do_configure() {
  11         echo >config.mk
  12         # uncomment to debug
  13         sed -i s,@,, Makefile
  14         cat >config.mk <<EOF
  15
  16 BUILD_HOST=\$(shell hostname)
  17 BUILD_VERSION=${PV}-${PR}
  18 BUILD_DATE=\$(shell date --iso-8601=seconds)
  19
  20 # NOTE: The following depends on the fact that only one version of the cross-compiler
  21 # has been built. If it bails out with something like: "| arm-linux-ld: 4.3.3: No such file or directory"
  22 # then you need to remove all previously built toolchain directories out of the cross library path.
  23 GCCV="`${CC} -dumpversion`"
  24 COMPILER_LIB_PATH_PRE=${CROSS_DIR}/lib/gcc/${TARGET_SYS}/$(GCCV)
  25 COMPILER_LIB_PATH=\$(COMPILER_LIB_PATH_PRE)/\$(shell ls \$(COMPILER_LIB_PATH_PRE))
  26
  27 AS=${AS}
  28 LD=${LD}
  29 CC=${HOST_PREFIX}gcc
  30 OBJCOPY=${OBJCOPY}
  31 OBJDUMP=${OBJDUMP}
  32 HOSTCC=${BUILD_CC}
  33
  34 export HOSTCC BUILD_HOST BUILD_VERSION BUILD_DATE CROSS_COMPILE AD LD CC OBJCOPY OBJDUMP MKUDFU
  35 EOF
  36 }
  37
  38 do_compile() {
  39         make clean && \
  40         make CPU=s3c2442 && \
  41         make CPU=s3c2410 && \
  42         make CPU=s3c6410
  43 }
  44
  45 do_deploy () {
  46         install -d ${DEPLOY_DIR_IMAGE}
  47         cp -f image/qi-*.udfu ${DEPLOY_DIR_IMAGE}
  48 }
  49
  50 PACKAGE_ARCH = "${MACHINE_ARCH}"
  51
  52 do_deploy[dirs] = "${S}"
  53 addtask deploy before do_build after do_package
  54 addtask quilt before do_patch after do_unpack
  55 addtask svnrev before do_patch after do_quilt