code.vuplus.com Git - vuplus_openembedded/blob - recipes/pulseaudio/pulseaudio.inc

   1 DESCRIPTION = "Pulseaudio is a sound server for Linux and Unix-like operating systems."
   2 HOMEPAGE = "http://www.pulseaudio.org"
   3 AUTHOR = "Lennart Poettering"
   4 SECTION = "libs/multimedia"
   5 LICENSE = "LGPL"
   6 DEPENDS = "bluez4 libatomics-ops liboil avahi libsamplerate0 libsndfile1 libtool hal virtual/libx11"
   7 # optional
   8 DEPENDS += "alsa-lib glib-2.0 dbus consolekit hal openssl"
   9 INC_PR = "r8"
  10
  11 SRC_URI = "http://0pointer.de/lennart/projects/pulseaudio/pulseaudio-${PV}.tar.gz \
  12            file://gcc4-compile-fix.patch;patch=1 \
  13            file://volatiles.04_pulse"
  14
  15 inherit autotools pkgconfig
  16
  17 EXTRA_OECONF = "\
  18                 --disable-lynx \
  19                 --enable-bluez \
  20                 --disable-polkit \
  21                 --with-x \
  22                 --without-jack \
  23                 --with-glib \
  24                 --with-alsa \
  25                 --with-oss \
  26                 --with-hal \
  27 "
  28
  29 PARALLEL_MAKE = ""
  30
  31 export TARGET_PFPU = "${TARGET_FPU}"
  32
  33 # TODO: Use more fine granular version
  34 #OE_LT_RPATH_ALLOW=":${libdir}/pulse-0.9:"
  35 OE_LT_RPATH_ALLOW = "any"
  36 OE_LT_RPATH_ALLOW[export]="1"
  37
  38 do_stage() {
  39         autotools_stage_all
  40 }
  41
  42 do_install_append() {
  43         install -d ${D}${sysconfdir}/default/volatiles
  44         install -m 0644 ${WORKDIR}/volatiles.04_pulse  ${D}${sysconfdir}/default/volatiles/04_pulse
  45
  46         if [ "x${TARGET_PFPU}" == "xsoft" ] ; then
  47              sed -i -e s:\;\ resample-method\ =\ sinc-fastest:resample-method\ =\ trivial: ${D}${sysconfdir}/pulse/daemon.conf
  48         fi
  49 }
  50
  51 PACKAGES =+ "libpulsecore libpulsecommon libpulsedsp libpulse libpulse-simple libpulse-browse libpulse-mainloop-glib \
  52              pulseaudio-server pulseaudio-misc pulseaudio-gconf-helper"
  53
  54 #upgrade path:
  55 RREPLACES_pulseaudio-server = "libpulse-bin libpulse-conf"
  56
  57 PACKAGES_DYNAMIC = "pulseaudio-lib* pulseaudio-module* libpulse-lib* libpulse-module* "
  58
  59 FILES_libpulsecore = "${libdir}/libpulsecore*.so"
  60 FILES_libpulsecommon = "${libdir}/libpulsecommon*.so"
  61 FILES_libpulsedsp = "${libdir}/libpulsedsp*.so"
  62 FILES_libpulse = "${libdir}/libpulse.so.*"
  63 FILES_libpulse-simple = "${libdir}/libpulse-simple.so.*"
  64 FILES_libpulse-browse = "${libdir}/libpulse-browse.so.*"
  65 FILES_libpulse-mainloop-glib = "${libdir}/libpulse-mainloop-glib.so.*"
  66
  67 FILES_${PN}-dbg += "${libexecdir}/pulse/.debug \
  68                     ${libdir}/pulse-${PV}/modules/.debug"
  69 FILES_${PN}-dev += "${libdir}/pulse-${PV}/modules/*.la"
  70 FILES_${PN}-conf = "${sysconfdir}"
  71 FILES_${PN}-bin = "${bindir}/* \
  72                    ${sysconfdir}/default/volatiles/volatiles.04_pulse"
  73 FILES_${PN}-server = "${bindir}/pulseaudio ${bindir}/start-* ${sysconfdir} ${bindir}/pactl"
  74 FILES_${PN}-gconf-helper = "${libexecdir}/pulse/gconf-helper"
  75 FILES_${PN}-misc = "${bindir}/*"
  76
  77 # Allow the pulseaudio package to be created empty as a placeholder (-dbg and -dev depend on it)
  78 ALLOW_EMPTY_${PN} = "1"
  79
  80 CONFFILES_pulseaudio-server = "\
  81   ${sysconfdir}/pulse/default.pa \
  82   ${sysconfdir}/pulse/daemon.conf \
  83   ${sysconfdir}/pulse/client.conf \
  84   "
  85
  86 pkg_postinst_${PN}-server() {
  87         # can't do this offline
  88         if [ "x$D" != "x" ]; then
  89                 exit 1
  90         fi
  91         grep -q pulse: /etc/group || addgroup pulse
  92         grep -q pulse: /etc/passwd || \
  93             adduser --disabled-password --home=/var/run/pulse --system \
  94                     --ingroup pulse --no-create-home -g "Pulse audio daemon" pulse
  95         addgroup pulse audio
  96         /etc/init.d/populate-volatile.sh update
  97 }
  98
  99 pkg_postrm_${PN}-server() {
 100         deluser pulse || true
 101 }
 102
 103 python populate_packages_prepend() {
 104         #bb.data.setVar('PKG_pulseaudio', 'pulseaudio', d)
 105
 106         plugindir = bb.data.expand('${libdir}/pulse-${PV}/modules/', d)
 107         do_split_packages(d, plugindir, '^module-(.*)\.so$', 'pulseaudio-module-%s', 'PulseAudio module for %s', extra_depends='' )
 108         do_split_packages(d, plugindir, '^lib(.*)\.so$', 'pulseaudio-lib-%s', 'PulseAudio library for %s', extra_depends='' )
 109 }
 110
 111 RDEPENDS_pulseaudio-module-console-kit =+ "consolekit"
 112 RDEPENDS_pulseaudio-module-hal_detect =+ "hal"
 113 RDEPENDS_pulseaudio-server = " \
 114     pulseaudio-module-device-restore \
 115     pulseaudio-module-stream-restore \
 116     pulseaudio-module-card-restore \
 117     pulseaudio-module-augment-properties \
 118     pulseaudio-module-detect \
 119     pulseaudio-module-alsa-sink \
 120     pulseaudio-module-alsa-source \
 121     pulseaudio-module-alsa-card \
 122     pulseaudio-module-native-protocol-unix \
 123     pulseaudio-module-hal-detect \
 124     pulseaudio-module-default-device-restore \
 125     pulseaudio-module-rescue-streams \
 126     pulseaudio-module-always-sink \
 127     pulseaudio-module-suspend-on-idle \
 128     pulseaudio-module-console-kit \
 129     pulseaudio-module-position-event-sounds \
 130     pulseaudio-module-cork-music-on-phone "
 131