code.vuplus.com Git - vuplus_openembedded/blob - recipes/ppp/ppp_2.4.4.bb

   1 SECTION = "console/network"
   2 DESCRIPTION = "Point-to-Point Protocol (PPP) daemon"
   3 HOMEPAGE = "http://samba.org/ppp/"
   4 DEPENDS = "libpcap"
   5 LICENSE = "BSD GPLv2"
   6
   7 # Not well tested
   8 DEFAULT_PREFERENCE = "-1"
   9
  10 SRC_URI = "http://ppp.samba.org/ftp/ppp/ppp-${PV}.tar.gz \
  11         file://ppp-2.4.4-mppe-mppc.1.1.patch;patch=1 \
  12         file://makefile.patch;patch=1 \
  13         file://cifdefroute.patch;patch=1 \
  14         file://pppd-resolv-varrun.patch;patch=1 \
  15         file://plugins-fix-CC.patch;patch=1 \
  16         file://pppoatm-makefile.patch;patch=1 \
  17         file://enable-ipv6.patch;patch=1 \
  18         file://makefile-remove-hard-usr-reference.patch;patch=1 \
  19         file://ldflags.patch;patch=1 \
  20         file://pon \
  21         file://poff \
  22         file://init \
  23         file://ip-up \
  24         file://ip-down \
  25         file://08setupdns \
  26         file://92removedns"
  27
  28 SRC_URI_append_nylon = " file://ppp-tdbread.patch;patch=1"
  29
  30 inherit autotools
  31
  32 EXTRA_OEMAKE = "STRIPPROG=${STRIP} MANDIR=${D}${datadir}/man/man8 INCDIR=${D}${includedir} LIBDIR=${D}${libdir}/pppd/${PV} BINDIR=${D}${sbindir}"
  33 EXTRA_OECONF = "--disable-strip"
  34
  35 do_stage () {
  36          make INCDIR=${STAGING_INCDIR} install-devel
  37 }
  38
  39 do_install_append () {
  40         make install-etcppp ETCDIR=${D}/${sysconfdir}/ppp
  41         mkdir -p ${D}${bindir}/ ${D}${sysconfdir}/init.d
  42         mkdir -p ${D}${sysconfdir}/ppp/ip-up.d/
  43         mkdir -p ${D}${sysconfdir}/ppp/ip-down.d/
  44         mkdir -p ${D}${sysconfdir}/ppp/peers/
  45         install -m 0755 ${WORKDIR}/pon ${D}${bindir}/pon
  46         install -m 0755 ${WORKDIR}/poff ${D}${bindir}/poff
  47         install -m 0755 ${WORKDIR}/init ${D}${sysconfdir}/init.d/ppp
  48         install -m 0755 ${WORKDIR}/ip-up ${D}${sysconfdir}/ppp/
  49         install -m 0755 ${WORKDIR}/ip-down ${D}${sysconfdir}/ppp/
  50         install -m 0755 ${WORKDIR}/08setupdns ${D}${sysconfdir}/ppp/ip-up.d/
  51         install -m 0755 ${WORKDIR}/92removedns ${D}${sysconfdir}/ppp/ip-down.d/
  52         rm -rf ${D}/${mandir}/man8/man8
  53 }
  54
  55 CONFFILES_${PN} = "${sysconfdir}/ppp/pap-secrets ${sysconfdir}/ppp/chap-secrets ${sysconfdir}/ppp/options"
  56 PACKAGES =+ "ppp-oa ppp-oe ppp-radius ppp-winbind ppp-minconn ppp-password ppp-tools"
  57 FILES_${PN}        = "${sysconfdir} ${bindir} ${sbindir}/chat ${sbindir}/pppd"
  58 FILES_${PN}_nylon  = "${sysconfdir} ${bindir} ${sbindir}/chat ${sbindir}/pppd ${sbindir}/tdbread"
  59 FILES_${PN}-dbg += "${libdir}/pppd/${PV}/.debug"
  60 FILES_${PN}-oa       = "${libdir}/pppd/${PV}/pppoatm.so"
  61 FILES_${PN}-oe       = "${sbindir}/pppoe-discovery ${libdir}/pppd/${PV}/rp-pppoe.so"
  62 FILES_${PN}-radius   = "${libdir}/pppd/${PV}/radius.so ${libdir}/pppd/${PV}/radattr.so ${libdir}/pppd/${PV}/radrealms.so"
  63 FILES_${PN}-winbind  = "${libdir}/pppd/${PV}/winbind.so"
  64 FILES_${PN}-minconn  = "${libdir}/pppd/${PV}/minconn.so"
  65 FILES_${PN}-password = "${libdir}/pppd/${PV}/pass*.so"
  66 FILES_${PN}-tools    = "${sbindir}/pppstats ${sbindir}/pppdump"
  67 DESCRIPTION_ppp-oa       = "Plugin for PPP needed for PPP-over-ATM"
  68 DESCRIPTION_ppp-oe       = "Plugin for PPP needed for PPP-over-Ethernet"
  69 DESCRIPTION_ppp-radius   = "Plugin for PPP that are related to RADIUS"
  70 DESCRIPTION_ppp-winbind  = "Plugin for PPP to authenticate against Samba or Windows"
  71 DESCRIPTION_ppp-minconn  = "Plugin for PPP to specify a minimum connect time before the idle timeout applies"
  72 DESCRIPTION_ppp-password = "Plugin for PPP to get passwords via a pipe"
  73 DESCRIPTION_ppp-tools    = "The pppdump and pppstats utitilities"
  74 RDEPENDS_ppp_minconn    += "libpcap0.8"
  75
  76 pkg_postinst_${PN}() {
  77 if test "x$D" != "x"; then
  78         exit 1
  79 else
  80         chmod u+s ${sbindir}/pppd
  81 fi
  82 }