code.vuplus.com Git - vuplus_openembedded/blob - recipes/postgresql/postgresql.inc

   1 DESCRIPTION = "PostgreSQL is a powerful, open source relational database system."
   2 HOMEPAGE = "http://www.postgresql.com"
   3 LICENSE = "BSD"
   4 DEPENDS = "zlib readline"
   5
   6 ARM_INSTRUCTION_SET = "arm"
   7
   8 #WARNING: this recipe assumes you have the timezone compiler present in /usr/sbin/zic
   9
  10 SRC_URI = "ftp://ftp-archives.postgresql.org/pub/source/v${PV}/${P}.tar.bz2"
  11
  12 LEAD_SONAME = "libpq.so"
  13
  14 # LDFLAGS for shared libraries
  15 export LDFLAGS_SL = "${LDFLAGS}"
  16
  17 inherit autotools pkgconfig
  18
  19 do_compile_append() {
  20          cp /usr/sbin/zic ${S}/src/timezone/
  21 }
  22
  23 do_stage() {
  24          autotools_stage_includes
  25
  26          oe_libinstall -a -so -C src/interfaces/libpq libpq ${STAGING_LIBDIR}
  27          oe_libinstall -a -so -C src/interfaces/ecpg/ecpglib libecpg ${STAGING_LIBDIR}
  28          oe_libinstall -a -so -C src/interfaces/ecpg/compatlib libecpg_compat ${STAGING_LIBDIR}
  29          oe_libinstall -a -so -C src/interfaces/ecpg/pgtypeslib libpgtypes ${STAGING_LIBDIR}
  30 }
  31
  32 PACKAGES =+ "${PN}-client ${PN}-server-dev ${PN}-timezone \
  33              libecpg-compat-dbg libecpg-compat \
  34              libecpg-dbg libecpg libecpg-dev \
  35              libpq-dbg libpq libpq-dev \
  36              libpgtypes-dbg libpgtypes "
  37
  38 FILES_${PN}-client = "${bindir}/clusterdb \
  39                 ${bindir}/createdb \
  40                 ${bindir}/createlang \
  41                 ${bindir}/createuser \
  42                 ${bindir}/dropdb \
  43                 ${bindir}/droplang \
  44                 ${bindir}/dropuser \
  45                 ${bindir}/pg_dump \
  46                 ${bindir}/pg_dumpall \
  47                 ${bindir}/pg_restore \
  48                 ${bindir}/psql \
  49                 ${bindir}/reindexdb \
  50                 ${bindir}/vacuumdb \
  51                 ${bindir}/vacuumlo \
  52                 ${datadir}/${PN}/psqlrc.sample"
  53
  54 FILES_${PN}-doc += "${prefix}/doc/"
  55 FILES_${PN}-timezone = "${datadir}/${PN}/timezone"
  56 FILES_${PN}-server-dev = "${includedir}/${PN}/server"
  57
  58 FILES_libecpg = "${libdir}/libecpg*.so.*"
  59 FILES_libecpg-dbg = "${libdir}/.debug/libecpg*"
  60 FILES_libecpg-dev = "${libdir}/libecpg*.a ${libdir}/libecpg*.so \
  61                      ${libdir}/libpgtypes*.a ${libdir}/libpgtypes*.so \
  62                      ${includedir}/ecpg*.h ${includedir}/${PN}/ecpg*.h \
  63                      ${includedir}/pgtypes*.h ${includedir}/${PN}/informix \
  64                      ${includedir}/sql3types.h ${includedir}/sqlca.h"
  65
  66 FILES_libpq = "${libdir}/libpq*.so.*"
  67 FILES_libpq-dbg = "${libdir}/.debug/libpq*"
  68 FILES_libpq-dev = "${libdir}/libpq*.a ${libdir}/libpq*.so ${libdir}/libpgport.a \
  69                    ${includedir}"
  70
  71 FILES_libecpg-compat = "${libdir}/libecpg_compat*.so.*"
  72 FILES_libecpg-compat-dbg = "${libdir}/.debug/libecpg_compat*"
  73 FILES_libpgtypes = "${libdir}/libpgtypes*.so.*"
  74 FILES_libpgtypes-dbg = "${libdir}/.debug/libpgtypes*"