code.vuplus.com Git - vuplus_openembedded/blob - recipes/perl/perl.inc

   1 DESCRIPTION = "Perl is a popular scripting language."
   2 HOMEPAGE = "http://www.perl.org/"
   3 LICENSE = "Artistic|GPL"
   4 SECTION = "devel"
   5 PRIORITY = "optional"
   6 DEPENDS = "virtual/db perl-native"
   7
   8 SRC_URI = "ftp://ftp.funet.fi/pub/CPAN/src/perl-${PV}.tar.gz \
   9         file://Makefile.patch;patch=1 \
  10         file://config.sh-arm-linux.patch;patch=1 \
  11         file://libperl-5.8.3-create-libperl-soname.patch;patch=1;pnum=0 \
  12         file://Makefile.SH.patch"
  13
  14 HOSTPERL="${STAGING_BINDIR_NATIVE}/perl${PV}"
  15
  16 do_compile() {
  17         sed -i -e 's|/usr/include|${STAGING_INCDIR}|g' ext/Errno/Errno_pm.PL
  18         cd Cross
  19         # You must use gcc to link on sh
  20         OPTIONS=""
  21         if test ${TARGET_ARCH} = "sh3" -o ${TARGET_ARCH} = "sh4"; then
  22                 OPTIONS="LD=${TARGET_SYS}-gcc"
  23         fi
  24         # You must use gcc to link on powerpc also
  25         if test ${TARGET_ARCH} = "powerpc" ; then
  26                 OPTIONS="LD=${TARGET_SYS}-gcc"
  27         fi
  28
  29         oe_runmake perl $OPTIONS
  30 }
  31
  32 do_install() {
  33         oe_runmake install
  34         mv ${D}/${libdir}/perl5/${PV}/${TARGET_ARCH}-${TARGET_OS}/CORE/libperl.so ${D}/${libdir}/libperl.so.${PV}
  35         ( cd ${D}/usr/bin/; rm -f perl; ln -s perl${PV} perl )
  36 }
  37
  38 do_stage() {
  39         install -d ${STAGING_LIBDIR}/perl/
  40         install config.sh ${STAGING_LIBDIR}/perl/
  41 }
  42
  43 PACKAGES_DYNAMIC = "perl-module-*"
  44
  45 python populate_packages_prepend () {
  46         libdir = bb.data.expand('${libdir}/perl5/${PV}', d)
  47         archlibdir =  bb.data.expand('${libdir}/perl5/${PV}/${TARGET_ARCH}-${TARGET_OS}', d)
  48         do_split_packages(d, archlibdir, 'auto/(.*)(?!\.debug)/', 'perl-module-%s', 'perl module %s', recursive=True, allow_dirs=False, match_path=True)
  49         do_split_packages(d, archlibdir, '(.*)\.(pm|pl)', 'perl-module-%s', 'perl module %s', recursive=True, allow_dirs=False, match_path=True)
  50         do_split_packages(d, libdir, '(.*)\.(pm|pl)', 'perl-module-%s', 'perl module %s', recursive=True, allow_dirs=False, match_path=True)
  51 }
  52
  53 PACKAGES = "perl-dbg perl perl-misc perl-lib perl-dev perl-pod"
  54 FILES_${PN} = "/usr/bin/perl /usr/bin/perl${PV}"
  55 FILES_${PN}-lib = "/usr/lib/libperl.so*"
  56 FILES_${PN}-dev = "/usr/lib/perl5/${PV}/${TARGET_ARCH}-${TARGET_OS}/CORE/"
  57 FILES_${PN}-pod = "/usr/lib/perl5/${PV}/pod"
  58 FILES_perl-misc = "/usr/bin/*"
  59 FILES_${PN}-dbg += " \
  60         ${libdir}/perl5/${PV}/${TARGET_ARCH}-${TARGET_OS}/auto/*/.debug \
  61         ${libdir}/perl5/${PV}/${TARGET_ARCH}-${TARGET_OS}/auto/*/*/.debug \
  62         ${libdir}/perl5/${PV}/${TARGET_ARCH}-${TARGET_OS}/auto/*/*/*/.debug"
  63