code.vuplus.com Git - vuplus_openembedded/blob - recipes/pam/libpam_1.0.2.bb

   1 DESCRIPTION = "\
   2 PAM authentication library for Linux.  \
   3 Linux-PAM (Pluggable Authentication Modules for Linux) is a \
   4 library that enables the local system administrator to choose \
   5 how individual applications authenticate users. For an \
   6 overview of the Linux-PAM library see the Linux-PAM System \
   7 Administrators' Guide."
   8 HOMEPAGE = "http://kernel.org/pub/linux/libs/pam"
   9 SECTION = "libs"
  10 PRIORITY = "optional"
  11 LICENSE = "GPLv2"
  12
  13 DEPENDS = "flex flex-native"
  14
  15 # PAM is not a lot of use without configuration files and the plugins
  16 RRECOMMENDS_${PN} = "libpam-meta libpam-base-files"
  17
  18 PR = "r5"
  19
  20 # The project is actually called Linux-PAM but that gives
  21 # a bad OE package name because of the upper case characters
  22 pn = "Linux-PAM"
  23 p = "${pn}-${PV}"
  24 S = "${WORKDIR}/${p}"
  25
  26 SRC_URI = "${KERNELORG_MIRROR}/pub/linux/libs/pam/library/${p}.tar.bz2 \
  27            file://pam-nodocs.patch;patch=1 "
  28
  29 SRC_URI_append_linux-uclibc = " file://pam-disable-nis-on-uclibc.patch;patch=1"
  30 SRC_URI_append_linux-uclibceabi = " file://pam-disable-nis-on-uclibc.patch;patch=1"
  31
  32 inherit autotools
  33
  34 LEAD_SONAME = "libpam.so.*"
  35
  36 # maintain the pam default layout
  37 EXTRA_OECONF += " --includedir=${includedir}/security"
  38
  39 EXTRA_OECONF_linux-uclibc += "--disable-nls"
  40 EXTRA_OECONF_linux-uclibceabi += "--disable-nls"
  41
  42 PACKAGES_DYNAMIC += " libpam-meta pam-plugin-*"
  43
  44 python populate_packages_prepend () {
  45         import os.path
  46
  47         pam_libdir = bb.data.expand('${libdir}/security', d)
  48         pam_libdirdebug = bb.data.expand('${libdir}/security/.debug', d)
  49         pam_filterdir = bb.data.expand('${libdir}/security/pam_filter', d)
  50         do_split_packages(d, pam_libdir, '^pam(.*)\.so$', 'pam-plugin%s', 'PAM plugin for %s', extra_depends='')
  51         do_split_packages(d, pam_libdir, '^pam(.*)\.la$', 'pam-plugin%s-dev', 'PAM plugin for %s dev', extra_depends='')
  52         if os.path.exists(pam_libdirdebug):
  53                 do_split_packages(d, pam_libdirdebug, '^pam(.*)\.so$', 'pam-plugin%s-dbg', 'PAM plugin for %s debugging symbols', extra_depends='')
  54         do_split_packages(d, pam_filterdir, '^(.*)$', 'pam-filter-%s', 'PAM filter for %s', extra_depends='')
  55
  56         pn = bb.data.getVar('PN', d, 1)
  57         metapkg =  pn + '-meta'
  58         bb.data.setVar('ALLOW_EMPTY_' + metapkg, "1", d)
  59         bb.data.setVar('FILES_' + metapkg, "", d)
  60         blacklist = [ pn + '-locale', pn + '-dev', pn + '-dbg', pn + '-doc' ]
  61         metapkg_rdepends = []
  62         packages = bb.data.getVar('PACKAGES', d, 1).split()
  63         for pkg in packages[1:]:
  64                 if not pkg in blacklist and not pkg in metapkg_rdepends and not pkg.endswith('-dev') and not pkg.count('locale') and pkg.count('plugin'):
  65                         metapkg_rdepends.append(pkg)
  66         bb.data.setVar('RDEPENDS_' + metapkg, ' '.join(metapkg_rdepends), d)
  67         bb.data.setVar('DESCRIPTION_' + metapkg, pn + ' meta package', d)
  68         packages.append(metapkg)
  69         bb.data.setVar('PACKAGES', ' '.join(packages), d)
  70 }
  71
  72 do_stage() {
  73         autotools_stage_all
  74 }