code.vuplus.com Git - vuplus_openembedded/blob - recipes/p3scan/p3scan_2.9.05d.bb

   1 DESCRIPTION = "A transparent proxy-server for email clients. It is designed \
   2 to enable scanning of incoming/outgoing email messages (POP3, POPSS and \
   3 SMTP) for Virus's, Worms, Trojans, Spam and harmfull attachments."
   4 HOMEPAGE = "http://p3scan.sourceforge.net/"
   5 SECTION = "network"
   6 LICENSE = "GPLv2"
   7 DEPENDS = "gmp bzip2 zlib clamav openssl"
   8 RDEPENDS_${PN} = "${PN}-templates-en"
   9 PR = "r4"
  10
  11 SRC_URI = "${SOURCEFORGE_MIRROR}/p3scan/p3scan-2.9.05d.tar.gz \
  12            file://libtool-fix.patch;patch=1 \
  13            file://dont-search-use-include.patch;patch=1 \
  14            file://configure.in-add-newline.patch;patch=1 \
  15            file://p3scan.init \
  16            file://p3scan.conf \
  17            file://doc.configure.txt \
  18            file://volatiles.05_p3scan"
  19
  20 inherit autotools update-rc.d
  21
  22 EXTRA_OECONF = "--with-clamav=${STAGING_LIBDIR}/.. \
  23                 --with-openssl=${STAGING_LIBDIR}/.. \
  24                 --disable-ripmime"
  25
  26 # Full manual install because the autoconf installer puts in lots of
  27 # stuff we don't want and in lots of odd directories.
  28 do_install () {
  29         install -m 0755 -d ${D}${sysconfdir}/init.d \
  30                            ${D}${docdir}/p3scan \
  31                            ${D}${mandir}/man8 \
  32                            ${D}${sysconfdir}/p3scan \
  33                            ${D}${sysconfdir}/default/volatiles \
  34                            ${D}${sbindir}
  35         install -m 755 ${WORKDIR}/p3scan.init ${D}${sysconfdir}/init.d/p3scan
  36         install -m 755 ${WORKDIR}/p3scan.conf ${D}${sysconfdir}/p3scan/p3scan.conf
  37         install -m 644 ${WORKDIR}/doc.configure.txt ${D}${docdir}/p3scan/configure.txt
  38         install -m 755 src/.libs/p3scan ${D}${sbindir}
  39         for i in etc/p3scan-*.mail \
  40                  etc/p3scan.whitelist \
  41                  etc/p3scan.blacklist; do
  42           install -m 644 $i ${D}${sysconfdir}/p3scan/`basename $i`
  43         done
  44         for i in README ChangeLog README-ripmime README-emergency \
  45                  spamfaq.html etc/p3scan.conf.sample p3scan.sh \
  46                  AUTHORS CONTRIBUTERS; do
  47           install -m 644 $i ${D}${docdir}/p3scan/`basename $i`
  48         done
  49         install -m 644 man/p3scan.man ${D}${mandir}/man8/p3scan.8
  50         # We need some /var directories
  51         for i in 05_p3scan; do
  52           install -m 0644 ${WORKDIR}/volatiles.$i ${D}${sysconfdir}/default/volatiles/$i
  53         done
  54 }
  55
  56 PACKAGES = "${PN}-dbg ${PN}-doc \
  57             ${PN}-templates-ru ${PN}-templates-en ${PN}-templates-pt-br \
  58             ${PN}-templates-sp ${PN}-templates-ge ${PN}-templates-fr \
  59             ${PN}-templates-nl ${PN}-templates-pl ${PN}-templates-it \
  60             ${PN}"
  61
  62 FILES_${PN} = "${sysconfdir}/p3scan/* \
  63                ${sysconfdir}/init.d ${sysconfdir}/default ${sbindir}/*"
  64 FILES_${PN}-templates-ru = "${sysconfdir}/p3scan/p3scan-ru.mail"
  65 FILES_${PN}-templates-en = "${sysconfdir}/p3scan/p3scan-en.mail"
  66 FILES_${PN}-templates-pt-br = "${sysconfdir}/p3scan/p3scan-pt-br.mail"
  67 FILES_${PN}-templates-sp = "${sysconfdir}/p3scan/p3scan-sp.mail"
  68 FILES_${PN}-templates-ge = "${sysconfdir}/p3scan/p3scan-ge.mail"
  69 FILES_${PN}-templates-fr = "${sysconfdir}/p3scan/p3scan-fr.mail"
  70 FILES_${PN}-templates-nl = "${sysconfdir}/p3scan/p3scan-nl.mail"
  71 FILES_${PN}-templates-pl = "${sysconfdir}/p3scan/p3scan-pl.mail"
  72 FILES_${PN}-templates-it = "${sysconfdir}/p3scan/p3scan-it.mail"
  73
  74 # Add havp's user and groups
  75 pkg_postinst_${PN} () {
  76         grep -q mail: /etc/group || addgroup --system havp
  77         grep -q mail: /etc/passwd || \
  78             adduser --disabled-password --home=${localstatedir}/mail --system \
  79                     --ingroup mail --no-create-home -g "Mail" mail
  80         /etc/init.d/populate-volatile.sh update
  81 }
  82
  83 CONFFILES_${PN} = "${sysconfdir}/p3scan/p3scan.conf"
  84
  85 INITSCRIPT_NAME = "p3scan"
  86 INITSCRIPT_PARAMS = "defaults 65 35"