code.vuplus.com Git - vuplus_openembedded/blob - recipes/opencv/opencv_svn.bb

   1 DESCRIPTION = "Opencv : The Open Computer Vision Library"
   2 HOMEPAGE = "http://sourceforge.net/projects/opencvlibrary"
   3 SECTION = "libs"
   4 PRIORITY = "optional"
   5 LICENSE = "GPLv2"
   6
   7 ARM_INSTRUCTION_SET = "arm"
   8
   9 DEPENDS = "ffmpeg gtk+ libtool swig swig-native python jpeg zlib libpng tiff glib-2.0"
  10
  11 SRC_URI = "svn://opencvlibrary.svn.sourceforge.net/svnroot/opencvlibrary/trunk;module=opencv;proto=https \
  12            file://acinclude.m4"
  13
  14 SRCREV = "2219"
  15 PV = "2.0.0+svnr${SRCPV}"
  16
  17 S = "${WORKDIR}/opencv"
  18
  19 inherit distutils-base autotools_stage pkgconfig cmake
  20
  21 EXTRA_OECONF = " \
  22                 --disable-debug \
  23                 --with-gtk \
  24                 --without-quicktime \
  25                 --with-ffmpeg \
  26                 --with-gthread \
  27                 --without-gstreamer \
  28                 --with-v4l \
  29                 --enable-apps \
  30                 --enable-optimization \
  31                 --disable-sse \
  32                 --with-swig \
  33                 --with-python az_python_cspec=${STAGING_INCDIR}/${PYTHON_DIR} \
  34                 "
  35
  36 export BUILD_SYS
  37 export HOST_SYS
  38 export PYTHON_CSPEC="-I${STAGING_INCDIR}/${PYTHON_DIR}"
  39 export PYTHON=${STAGING_BINDIR_NATIVE}/python
  40
  41 do_configure_prepend() {
  42         cp ${WORKDIR}/acinclude.m4 ${S}
  43         sed -i -e /AC_CONFIG_MACRO_DIR/d -e /AZ_PYTHON_CSPEC/d ${S}/configure.in
  44         sed -i -e s:samples::g -e 's: doc::g' ${S}/Makefile.am
  45 }
  46
  47 TARGET_CC_ARCH += "-I${S}/include "
  48
  49 PACKAGES += "${PN}-apps python-opencv"
  50
  51 python populate_packages_prepend () {
  52         cv_libdir = bb.data.expand('${libdir}', d)
  53         cv_libdir_dbg = bb.data.expand('${libdir}/.debug', d)
  54         do_split_packages(d, cv_libdir, '^lib(.*)\.so$', 'lib%s-dev', 'OpenCV %s development package', extra_depends='${PN}-dev', allow_links=True)
  55         do_split_packages(d, cv_libdir, '^lib(.*)\.la$', 'lib%s-dev', 'OpenCV %s development package', extra_depends='${PN}-dev')
  56         do_split_packages(d, cv_libdir, '^lib(.*)\.a$', 'lib%s-dev', 'OpenCV %s development package', extra_depends='${PN}-dev')
  57         do_split_packages(d, cv_libdir, '^lib(.*)\.so\.*', 'lib%s', 'OpenCV %s library', extra_depends='', allow_links=True)
  58 }
  59
  60 FILES_${PN} = ""
  61 FILES_${PN}-apps = "${bindir}/* ${datadir}/opencv/"
  62 FILES_${PN}-dbg += "${libdir}/.debug"
  63 FILES_${PN}-dev = "${includedir} ${libdir}/pkgconfig"
  64
  65 INSANE_SKIP_python-opencv = True
  66 DESCRIPTION_python-opencv = "Python bindings to opencv"
  67 FILES_python-opencv = "${libdir}/*/site-packages/*"
  68 RDEPENDS_python-opencv = "python-core"
  69
  70 do_stage_append() {
  71         cp ${S}/include/opencv/*.h ${STAGING_INCDIR}/opencv/
  72 }