code.vuplus.com Git - vuplus_openembedded/blob - recipes/mythtv/mythtv_svn.bb

   1 require mythtv.inc
   2
   3 inherit qmake2 qt4x11
   4
   5 DEFAULT_PREFERENCE = "-1"
   6
   7 PV = "0.21+0.22rc+svnr${SRCPV}"
   8 PR = "r0"
   9 REALPV = "0.22"
  10
  11 SRCREV = "20947"
  12 SRC_URI = "svn://svn.mythtv.org/svn/trunk;module=mythtv;proto=http"
  13
  14 S = "${WORKDIR}/mythtv"
  15
  16 QMAKE_PROFILES = "mythtv.pro"
  17
  18 mythlibs = "mythdb mythavutil mythavcodec mythavformat mythswscale mythhdhomerun myth mythtv mythui mythfreemheg mythupnp mythlivemedia"
  19 PACKAGES =+ "mythtv-backend mythtv-frontend mythtv-bin mythtv-filters mythtv-data"
  20
  21 FILES_${PN}-dbg += "${libdir}/mythtv/filters/.debug"
  22 FILES_mythtv-backend = "${bindir}/mythbackend ${bindir}/mythcommflag ${bindir}/mythfilldatabase ${bindir}/mythtranscode"
  23 FILES_mythtv-frontend = "${bindir}/mythfrontend ${datadir}/mythtv/i18n/mythfrontend_* ${datadir}/mythtv/*.ttf"
  24 FILES_mythtv-bin = "${bindir}/*"
  25 FILES_mythtv-filters = "${libdir}/mythtv/filters/*"
  26 FILES_mythtv-data = "${datadir}"
  27 RDEPENDS_${PN} = "mythtv-backend mythtv-frontend mythtv-bin mythtv-filters mythtv-data"
  28 ALLOW_EMPTY_${PN} = "1"
  29
  30 PACKAGES_DYNAMIC = "mythtv-theme-*"
  31
  32 python __anonymous () {
  33     import bb
  34
  35     mythlibs = bb.data.getVar('mythlibs', d).split()
  36     pv = bb.data.expand(bb.data.getVar("REALPV", d), d)
  37
  38     for m in mythlibs:
  39         bb.data.setVar("FILES_lib%s%s" % (m, pv), "${libdir}/lib%s-%s.so.*" % (m, pv), d)
  40         bb.data.setVar("FILES_lib%s%s-dev" % (m, pv), "${libdir}/lib%s-%s.*" % (m, pv), d)
  41
  42     packages = " ".join(map(lambda x: "lib%s%s lib%s%s-dev" % (x, pv, x, pv), mythlibs) + bb.data.getVar("PACKAGES", d).split())
  43
  44     bb.data.setVar("PACKAGES", packages, d)
  45 }
  46
  47 EXTRA_MYTHTVCONF_armv7a  = "--cpu=cortex-a8"
  48 EXTRA_MYTHTVCONF ?= ""
  49
  50 EXTRA_OECONF = " \
  51         --cross-prefix=${TARGET_PREFIX} \
  52         --sysroot=${STAGING_DIR_HOST} \
  53         --prefix=${prefix} \
  54         \
  55         --arch=${TARGET_ARCH} \
  56         --extra-cflags="${TARGET_CFLAGS} ${HOST_CC_ARCH}${TOOLCHAIN_OPTIONS}" \
  57         --extra-cxxflags="${TARGET_CXXFLAGS} ${HOST_CC_ARCH}${TOOLCHAIN_OPTIONS}" \
  58         --extra-ldflags="${TARGET_LDFLAGS}" \
  59         ${EXTRA_MYTHTVCONF} \
  60 "
  61
  62 do_configure_prepend() {
  63 # it's not autotools anyway, so we call ./configure directly
  64         find . -name "Makefile"|xargs rm -f
  65
  66         ./configure     --qmake=qmake2          \
  67                         --disable-altivec       \
  68                         --disable-opengl        \
  69                         --disable-stripping     \
  70                         --disable-xvmc          \
  71                         --enable-v4l            \
  72                         --enable-audio-oss      \
  73                         --enable-dvb            \
  74                         --enable-libmp3lame \
  75             --dvb-path=${STAGING_INCDIR} \
  76                         --without-bindings=perl,python \
  77                         ${EXTRA_OECONF}
  78 }
  79
  80 python populate_packages_prepend () {
  81         new_packages = []
  82
  83         def the_hook(file, pkg, pattern, format, basename):
  84                 new_packages.append(pkg)
  85
  86         do_split_packages(d, root=bb.data.expand('${datadir}/mythtv/themes', d), file_regex='(.*)', output_pattern='mythtv-theme-%s', description='MythTV theme %s', allow_dirs=True, hook=the_hook, prepend=True)
  87
  88         bb.data.setVar("RDEPENDS_${PN}", "%s %s" % (bb.data.getVar("RDEPENDS_${PN}", d), " ".join(new_packages)), d)
  89 }